Verifying drilling toolpaths with capped hole surfaces?

[johnc4668]

Guys,

How does one verify a drilling toolpath with holes that are capped? My verification keeps going red saying that my tool is colliding when i know its not. I think that the capped surface is interfering with collision checking. Any ideas how to get around this? thanks!

[mark.sully]

Try using the Component Thickness dialog accessed from the toolpath form to set the capping surfaces to be ignored.

The following link gives more information

https://knowledge.autodesk.com/support/powermill/learn-explore/caas/CloudHelp/cloudhelp/2020/ENU/PWR...

HTH

Mark

[Anonymous]

 For computed toolpaths:

STRING LIST ModelList=INPUT ENTITY MULTIPLE MODEL 'Please select excluding models'
IF size($ModelList) != 0 {
  FOREACH M IN $ModelList {
    DELETE MODEL $M
  }
}
//
// Insert toolpath cheking code here
//
IF size($ModelList) != 0 {
  FOREACH M IN $ModelList {
    EDIT RECYCLER RECOVER Model $M
  }
}

[johnc4668]

@mark.sully  thanks for your response. How would i create one "component thickness" and use that for all my drilling programs? Or do i need to do each toolpath?

[mark.sully · Accepted solution]

There is a "Default" tab on that form that you can use for all toolpaths (it will not change the settings on toolpaths already created).

Or only for certain toolpaths there is a "Clone" option on the form where you can copy previously defined component thickness sets from another toolpath.

Attached is a macro I have that will clone the thickness sets from the active toolpath to those you select from a list the macro gives you, use at your discretion with no liability taken on the results.

Text of the macro is below for reference.

HTH,

Mark

Humph, won't allow me to attach the macro 😞

//macro to copy thickness sets from active toolpath to selected toolpaths
//WHO           WHEN        VER    WHAT
//Mark Sully    01/07/20    1.0    Initial version

//declare variables
STRING $active_tp = ""
INT LIST $selected_tps = {}
BOOL $recalculate = 0

//is there an active toolpath?
IF entity_exists(entity('toolpath','')) {
  //if yes, then save the name
  $active_tp = $entity('toolpath','').Name
} ELSE {
  //if no, then raise an error and exit
  MESSAGE ERROR "No active toolpath, exiting macro."
  RETURN
}

//get a list of toolpaths that are not the active toolpath
STRING LIST tps = {}
FOREACH tp IN folder('Toolpath') {
  IF $tp.Name != $active_tp {
    INT size = add_last(tps, entity('toolpath', $tp.Name).Name)
  }
} 

//exit if there are no toolpaths
IF is_empty($tps) {
  MESSAGE ERROR "No toolpaths in project except active toolpath, exiting."
  RETURN
} 

//sort the list by name
$tps = sort(tps)

//get a list of which toolpaths to copy the thickness set too
WHILE is_empty($selected_tps) {
  $selected_tps = INPUT CHOICE MULTIPLE $tps "Select toolpaths to update thickness sets."
}

//ask the user if they want to recalculate the toolpaths that have changed
$recalculate = QUERY "Do you want to recalculate any modified toolpaths?"

//lock graphics and loop through the selected toolpaths updating the thickness sets
GRAPHICS LOCK
FOREACH i IN $selected_tps {
  ACTIVATE TOOLPATH $tps[i]
  EDIT THICKNESS COMPONENT CLONETYPE TOOLPATH
  EDIT THICKNESS COMPONENT CLONESOURCE $active_tp
  EDIT TOOLPATH ; THICKNESS CLONE
  THICKNESS APPLY YES
  EDIT TOOLPATH ; REAPPLYFROMGUI YES
  IF $recalculate {
    EDIT TOOLPATH ; CALCULATE
  }
}

//reactivate the original toolpath and unlock graphics
ACTIVATE TOOLPATH $active_tp
GRAPHICS UNLOCK