Need iLogic code for rename component name in model browser
Tip: If you set a component's name to an empty string (""), it will attempt to revert back to its original/default component name. And if that name is already being used, it will add an incremental Integer to the end of its name as usual.
If you simply want to change the component name of all components within your assembly, you can use a code like above, but just add a counting integer that increases +1 within each loop.
Similar to this:
If ThisApplication.ActiveDocumentType <> DocumentTypeEnum.kAssemblyDocumentObject Then
MsgBox("An Assembly Document must be active for this rule (" & iLogicVb.RuleName & ") to work. Exiting.",vbOKOnly+vbCritical, "WRONG DOCUMENT TYPE")
Exit Sub
End If
Dim oADoc As AssemblyDocument = ThisAssembly.Document
Dim oADef As AssemblyComponentDefinition = oADoc.ComponentDefinition
For i As Integer = 1 To oADef.Occurrences.Count - 1
For Each oOcc As ComponentOccurrence In oADef.Occurrences
oOcc.Name = "Item " & i
i = i + 1
Next
NextIf this solved your problem, or answered your question, please click ACCEPT SOLUTION.
Or, if this helped you, please click (LIKE or KUDOS) 👍.
If you have time, please... Vote For My IDEAS 💡or you can Explore My CONTRIBUTIONS
Inventor 2021 Help | Inventor Forum | Inventor Customization Forum | Inventor Ideas Forum
Wesley Crihfield
(Not an Autodesk Employee)
Accepted solution
Within the first If...Then block in the code I posted, there is a MsgBox with a statement in it. Within that statement is [ (" & iLogicVb.RuleName & ") ]. Just get rid of the whole section of the message, and that will get rid of the first error you are seeing. Some folks seem to have trouble with that bit of code, and some folks don't. It is simply meant to include the name of the current iLogic rule within the message, when shown, and is totally not necessary (just a bonus).
As for the second error...try changing this:
Dim oADoc As AssemblyDocument = ThisAssembly.Documentto this:
Dim oADoc As AssemblyDocument = ThisApplication.ActiveDocumentand see if that works better for you. It is possible, but not common, for the two to not be pointing to the same document.
Just checking though, since you said something about an add-in in your first post...you are trying to run this within Inventor as a regular iLogic rule, right (not from within Visual Studio or some other platform)? If you're attempting to run it from another platform, you may need to get the assembly document in a slightly different way, because terms like "ThisDoc", "ThisDrawing", & "ThisAssembly" are defined within the iLogic Add-in, and not available outside that setting unless specifically declared/defined.
If this solved your problem, or answered your question, please click ACCEPT SOLUTION.
Or, if this helped you, please click (LIKE or KUDOS) 👍.
Wesley Crihfield
(Not an Autodesk Employee)
Hi @ladderman. Are you just wanting this code to effect the top level components within your assembly, or do you want it to also go down into all levels of sub assemblies too? I'm assuming for now that you just want to target top level components, because that is all that was covered here in this post so far.
You can give this iLogic/vb.net code a try if you want. It first gets the documents being directly referenced by the top level components. Then it gets the collection of components that are representing each of those documents, because that's how you want to group the naming convention. Then pairs that group with the document that they represent within a Dictionary collection object, for convenience later. Then it loops through those pairs in the dictionary, getting the document name as the base part of component's name, then uses the classic incrementing Integer method to add the ".", then the Integer to the ends of each component in the group that are representing that document. And before it actually makes any changes, it bundles all the changes into a 'Transaction', which makes 'undoing' this potentially large number of changes into one item in the UNDO list for you.
Sub Main
If ThisApplication.ActiveDocumentType <> DocumentTypeEnum.kAssemblyDocumentObject Then
MsgBox("An Assembly Document must be active for this rule to work. Exiting.",vbOKOnly+vbCritical, "WRONG DOCUMENT TYPE")
Exit Sub
End If
Dim oADoc As AssemblyDocument = ThisApplication.ActiveDocument
Dim oRefDocs As DocumentsEnumerator = oADoc.ReferencedDocuments
Dim oOccs As ComponentOccurrences = oADoc.ComponentDefinition.Occurrences
'the document will be input as the 'Key' of each pair
Dim oCompsByDoc As New Dictionary(Of Inventor.Document, ComponentOccurrencesEnumerator)
For Each oRefDoc As Document In oRefDocs
Dim oCompsForThisDoc As ComponentOccurrencesEnumerator = Nothing
oCompsForThisDoc = oOccs.AllReferencedOccurrences(oRefDoc)
If IsNothing(oCompsForThisDoc) OrElse oCompsForThisDoc.Count = 0 Then Continue For
oCompsByDoc.Add(oRefDoc, oCompsForThisDoc)
Next
'Start a Transaction to bundle all the name changes into a single item in the 'Undo' menu.
Dim oTransaction As Transaction = ThisApplication.TransactionManager.StartTransaction(oADoc, "Rename Components")
Dim oOcc As ComponentOccurrence
For Each oPair In oCompsByDoc
Dim oInt As Integer = 0
'get the name of the document that these components represent from this oPair's Key
Dim oDocName As String = System.IO.Path.GetFileNameWithoutExtension(oPair.Key.FullFileName)
For Each oOcc In oPair.Value
oInt = oInt + 1
Dim oNewName As String = oDocName & "." & oInt
Try
oOcc.Name = oNewName
Catch oEx As Exception
MsgBox("Renaming component from '" & oOcc.Name & "' to '" & oNewName & "' failed." _
& vbCrLf & oEx.Message & vbCrLf & oEx.StackTrace, vbExclamation, "Rename Failed")
Logger.Error("Renaming component from '" & oOcc.Name & "' to '" & oNewName & "' failed.")
End Try
Next 'oOcc
Next 'oPair
'end the Transaction
oTransaction.End
End SubIf this solved your problem, or answered your question, please click ACCEPT SOLUTION.
Or, if this helped you, please click (LIKE or KUDOS) 👍.
If you want and have time, I would appreciate your Vote(s) for My IDEAS :bulb: or you can Explore My CONTRIBUTIONS
Wesley Crihfield
(Not an Autodesk Employee)
Yeah, I noticed just shortly after posting yesterday, after some more testing that my code was affecting lower level components names, when I did not intend for that to happen. On line 7 of my code I used 'ReferencedDocuments', instead of 'AllReferencedDocuments' to just get the top level referenced documents. But then down on line 14 of my code, I did not immediately realize that by using the 'AllReferencedOccurrences' method to get all the components that represent that document, that it was digging down into all sub levels too. That was one mistake. Then neither of our codes really deals with the possibility of suppressed components, 'virtual' components, or components representing welds within a weldment type assembly...all of which would stump up my code as it was.
So, I decided to update my earlier code to correct those issues, and it seems to be functioning better. However, there may still be a chance for failure to rename certain components in certain odd situations. For instance, there were a couple of component in my test assembly that both represent the same part document, but the two components are set to different ModelStates (one is set to its Master ModelState, while the other was set to a member ModelState). When set to the Master ModelState, there are two separate solid bodies in the part, while the other ModelState, here is just one, and it is a larger size. Due to the difference in the two components, the symbol for one appears as a multi-body part, while the other appears like a normal part. For some reason, it would not rename either of those two components, while working just fine on all other components. Just an FYI.
Sub Main
If ThisApplication.ActiveDocumentType <> DocumentTypeEnum.kAssemblyDocumentObject Then
MsgBox("An Assembly Document must be active for this rule to work. Exiting.", vbCritical, "WRONG DOCUMENT TYPE")
Exit Sub
End If
Dim oADoc As AssemblyDocument = ThisApplication.ActiveDocument
Dim oRefDocs As DocumentsEnumerator = oADoc.ReferencedDocuments
Dim oRefDoc As Document
Dim oOccs As ComponentOccurrences = oADoc.ComponentDefinition.Occurrences
Dim oOcc As ComponentOccurrence
'the document will be input as the 'Key' of each pair
Dim oListOfCompsByRefDoc As New Dictionary(Of Inventor.Document, List(Of ComponentOccurrence))
For Each oRefDoc In oRefDocs
Dim oListOfOccs As New List(Of ComponentOccurrence)
For Each oOcc In oOccs
If oOcc.Suppressed Then Continue For
If TypeOf oOcc.Definition Is VirtualComponentDefinition Or _
TypeOf oOcc.Definition Is WeldsComponentDefinition Then
Continue For
End If
Dim oRefDocA As Document = Nothing
Try
oRefDocA = oOcc.ReferencedDocumentDescriptor.ReferencedDocument
Catch oEx As Exception
Logger.Error("Failed to get the referenced document from component named '" & oOcc.Name & "'.")
End Try
If (oRefDocA IsNot Nothing) AndAlso (oRefDocA Is oRefDoc) Then
oListOfOccs.Add(oOcc)
End If
Next
If oListOfOccs.Count > 0 Then
oListOfCompsByRefDoc.Add(oRefDoc, oListOfOccs)
End If
Next
Dim oTransaction As Transaction = ThisApplication.TransactionManager.StartTransaction(oADoc, "Rename Components")
For Each oPair In oListOfCompsByRefDoc
Dim oInt As Integer = 1
'get the name of the document that these components represent from this oPair's Key
Dim oDocName As String = System.IO.Path.GetFileNameWithoutExtension(oPair.Key.FullFileName)
For Each oOcc In oPair.Value
Dim oNewName As String = oDocName & "." & oInt
Try
oOcc.Name = oNewName
oInt = oInt + 1
Catch oEx As Exception
Logger.Error("Renaming component from '" & oOcc.Name & "' to '" & oNewName & "' failed.")
End Try
Next 'oOcc
Next 'oPair
oTransaction.End
End Sub
Wesley Crihfield
(Not an Autodesk Employee)