Is there an easy way to export a list of user-defined parameter names?

[chris]

I'm looking for a way to export a list of all the user-defined parameter names. I need to be able to copy and paste them if possible

[Michael.Navara · Accepted solution]

Try this code.

Dim part As PartDocument = ThisDoc.Document
Dim userParams = part.ComponentDefinition.Parameters.UserParameters
Dim paramNames As New List(Of String)
For Each param As Parameter In userParams
    paramNames.Add(param.Name)
Next

Dim paramNamesAsLines As String = String.Join(vbCrLf, paramNames)
Logger.Debug("ParamNames{0}{1}", vbCrLf, paramNamesAsLines)

If MsgBox("Copy to clipboard?", MsgBoxStyle.YesNo) = MsgBoxResult.Yes Then
    System.Windows.Forms.Clipboard.SetText(paramNamesAsLines)
End If

[WCrihfield]

Not sure if you are familiar with this process, or if it would work for you, but you could mark all your UserParameters as 'Key', then export them to an external XML file.  Then, you can import them into another document.  The process of marking all user parameters as Key is relatively simple to do by code, and there is actually a simple iLogic API line of code for the export or import step.

Dim oDoc As Document = ThisDoc.Document
Dim oUParams As UserParameters = Nothing
If (TypeOf oDoc Is AssemblyDocument) OrElse (TypeOf oDoc Is PartDocument) Then
	oUParams = oDoc.ComponentDefinition.Parameters.UserParameters
ElseIf (TypeOf oDoc Is DrawingDocument) Then
	oUParams = oDoc.Parameters.UserParameters
Else
	Return
End If
For Each oUParam As UserParameter In oUParams
	Try : oUParam.IsKey = True : Catch : End Try
Next oUParam
Dim sXMLFile As String = ThisDoc.PathAndFileName(False) & ".xml"
iLogicVb.Automation.ParametersXmlSave(oDoc, sXMLFile, XmlSaveOption.KeysOnly)
'iLogicVb.Automation.ParametersXmlLoad(oDoc, sXMLFile)

This assumes that you have not marked any of your ModelParameters or other parameter types as Key.  If you have, then you may need to include a little more code to temporarily set those to not being Key, then export, then set them back as Key.  The last line of code in the example above would be the one used for importing (loading) parameters into a document from an already existing XML file, just for reference, but would not really be used in the example above.

If this solved your problem, or answered your question, please click ACCEPT SOLUTION .
Or, if this helped you, please click (LIKE or KUDOS) 👍.

[chris]

I tried the XML export last night, but it's not just a list of names, it's everything, messy to deal with unless I was doing something wrong... which is possible

[chris]

@Michael.Navara This worked great, exactly what I wanted/needed.!

[JBerns]

Both great solutions from @Michael.Navara and @WCrihfield.

In Michael's solution, if you would like the parameter list sorted alphabetically, add this code at Line 7:

paramNames.Sort()

Hope others find this useful.

Regards,

Jerry