Hide a part in the Assembley idw with i logic
Perhaps this will work better for you then. It loops through all sheets, and all views on each sheet, gets the model (assembly) within the view, loops through all its components looking for any who's name starts with the text you supply in the InputBox. When found, it turns their visibility off for that view.
If ThisApplication.ActiveDocumentType <> DocumentTypeEnum.kDrawingDocumentObject Then
MsgBox("A Drawing Document must be active for this rule to work. Exiting.",vbOKOnly+vbCritical, "WRONG DOCUMENT TYPE")
Exit Sub
End If
Dim oDDoc As DrawingDocument = ThisApplication.ActiveDocument
Dim oStr As String = InputBox("Enter text to search for.")
For Each oSheet As Inventor.Sheet In oDDoc.Sheets
For Each oView As DrawingView In oSheet.DrawingViews
If oView.ReferencedDocumentDescriptor.ReferencedDocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
Dim oADoc As AssemblyDocument = oView.ReferencedDocumentDescriptor.ReferencedDocument
Dim oADef As AssemblyComponentDefinition = oADoc.ComponentDefinition
For Each oOcc As ComponentOccurrence In oADef.Occurrences
If oOcc.Name.StartsWith(oStr) Then
oView.SetVisibility(oOcc, False)
End If
Next
End If
Next
Next
oDDoc.UpdateIf this solved your problem, or answered your question, please click ACCEPT SOLUTION.
Or, if this helped you, please click (LIKE or KUDOS) 👍.
If you have time, please... Vote For My IDEAS 💡or you can Explore My CONTRIBUTIONS
Inventor 2021 Help | Inventor Forum | Inventor Customization Forum | Inventor Ideas Forum
Wesley Crihfield
(Not an Autodesk Employee)
OK. I think I may have a solution that will dig deeper in its search for you.
It uses a 'recursive' Sub routine, which:
- checks the document type of the input component
- If it's a Part, it proceeds to the component name check, and if true switches the visibility setting
- If it's an Assembly, it goes into a deeper loop of that assembly's components
- It then calls this same Sub routine again on each sub-component
This should be able to dig as deep as needed. But be careful and save your documents before running this, because recursive routines can be taxing on your System and may cause Inventor to crash unexpectedly. If this causes Inventor to crash, we may have to try it in a different way.
Also, when attempting to change visibility of stuff in drawing views, there are a number of factors to be aware of, that may cause something like this not to work. If the DrawingView is set to a specific 'View Representation', 'Positional Representation', or 'Level of Detail Representation', those may or may not interfere with this. Especially if you have a custom View Representation set, and you have the checkbox next to the 'Associative' setting. That means it is live-linked to that view representation within the model, and therefore will always show exactly as the model shows, while it is in that representation. When that 'Associative' setting is turned on, you most likely won't be able to modify the visibility of things in the view. To do this while maintaining the Associative setting, you would have to make the changes at the model level, while that view rep is active, then save the model, then update the drawing, so the view will match the model again.
Anyways, here's the code:
Sub Main
If ThisApplication.ActiveDocumentType <> DocumentTypeEnum.kDrawingDocumentObject Then
MsgBox("A Drawing Document must be active for this rule to work. Exiting.",vbOKOnly+vbCritical, "WRONG DOCUMENT TYPE")
Exit Sub
End If
Dim oDDoc As DrawingDocument = ThisApplication.ActiveDocument
Dim oStr As String = InputBox("Enter text to search for.")
For Each oSheet As Inventor.Sheet In oDDoc.Sheets
For Each oView As DrawingView In oSheet.DrawingViews
If oView.ReferencedDocumentDescriptor.ReferencedDocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
Dim oADoc As AssemblyDocument = oView.ReferencedDocumentDescriptor.ReferencedDocument
Dim oADef As AssemblyComponentDefinition = oADoc.ComponentDefinition
For Each oOcc As ComponentOccurrence In oADef.Occurrences
'run recursive Sub here
'checks this component, and checks any sub-components
ProcessAndIterate(oOcc, oStr, oView)
Next
End If
Next
Next
oDDoc.Update
End Sub
Sub ProcessAndIterate(oCom As ComponentOccurrence, oSt As String, oDView As DrawingView)
'just creating new variables here to enable 'Intellisense' recognition
'and so that recursive calls are using different input variables
Dim oComp As ComponentOccurrence = oCom
Dim oStr As String = oSt
Dim oView As DrawingView = oDView
If oComp.DefinitionDocumentType = DocumentTypeEnum.kPartDocumentObject Then
If oComp.Name.StartsWith(oSt) Then
Try
oView.SetVisibility(oComp, False)
Catch
MsgBox("Failed to turn off visibility to component [" & oComp.Name & "] within the view named [" & oView.Name, , "")
End Try
End If
ElseIf oComp.DefinitionDocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
For Each oOcc As ComponentOccurrence In oComp.Definition.Document.ComponentDefinition.Occurrences
ProcessAndIterate(oOcc, oStr, oView)
Next
End If
End Sub
If this solved your problem, or answered your question, please click ACCEPT SOLUTION.
Or, if this helped you, please click (LIKE or KUDOS) 👍.
Wesley Crihfield
(Not an Autodesk Employee)
OK. I guess I just assumed you were only targeting part documents within the various levels to 'hide', and not any assembly documents themselves. This can be adjusted for. Within the 'iteration' sub, we can move the 'name check' to above the document type check, then after checking document type, if it is a Part, don't try to dig deeper, but if it's an assembly, do try to dig deeper. I'm also suspicious that we may need to create a ComponentOccurrenceProxy object (at the top level) to represent any ComponentOccurrence objects that are any deeper than the top level, for use within the View.SetVisibility() call. Either that, or we may need to go the longer route of getting each DrawingCurve/DrawingCurveSegment belonging to the target sub-components within the view, and turn them off individually, which is usually is very time and system resources consuming.
Here is a modified version of the 'ProcessAndIterate' Sub code that checks all document types (without trying the Proxy thing yet):
Sub ProcessAndIterate(oCom As ComponentOccurrence, oSt As String, oDView As DrawingView)
'just creating new variables here to enable 'Intellisense' recognition
'and so that recursive calls are using different input variables
Dim oComp As ComponentOccurrence = oCom
Dim oStr As String = oSt
Dim oView As DrawingView = oDView
If oComp.Name.StartsWith(oSt) Then
Try
oView.SetVisibility(oComp, False)
Catch
MsgBox("Failed to turn off visibility to component [" & oComp.Name & "] within the view named [" & oView.Name, , "")
End Try
End If
If oComp.DefinitionDocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
For Each oOcc As ComponentOccurrence In oComp.Definition.Document.ComponentDefinition.Occurrences
ProcessAndIterate(oOcc, oStr, oView)
Next
End If
End Sub
Wesley Crihfield
(Not an Autodesk Employee)
I did do a little more work on your project, but I still don't think I have a working solution, so I've pretty much given up on it. This time I attempted to create a ComponentOccurrenceProxy of any components that are below top level, and tried using that within the oView.SetVisibility() call, but something is still not working correctly when trying it out on my test assembly.
I'm thinking that if you want your drawing view to only be showing certain components, then you should just do it the normal way. Create new (custom) design view representations within each assembly (and sub-assembly) document, then adjust which components you want visible within those representations. Then within any parent assembly's, set the design view representations, of those sub-assemblies the way you want them. Then in the drawing view, set the design view representation to the custom one that is set-up right.
Here's the further modified (but still not perfect) code that I ended up with. Hopefully either you or someone else here on the forum can pick it up from here and fix it the way you want it, if it's possible.
Sub Main
If ThisApplication.ActiveDocumentType <> DocumentTypeEnum.kDrawingDocumentObject Then
MsgBox("A Drawing Document must be active for this rule to work. Exiting.",vbOKOnly+vbCritical, "WRONG DOCUMENT TYPE")
Exit Sub
End If
Dim oDDoc As DrawingDocument = ThisApplication.ActiveDocument
Dim oStr As String = InputBox("Enter text to search for.")
For Each oSheet As Inventor.Sheet In oDDoc.Sheets
For Each oView As DrawingView In oSheet.DrawingViews
If oView.ReferencedDocumentDescriptor.ReferencedDocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
Dim oADoc As AssemblyDocument = oView.ReferencedDocumentDescriptor.ReferencedDocument
Dim oADef As AssemblyComponentDefinition = oADoc.ComponentDefinition
For Each oOcc As ComponentOccurrence In oADef.Occurrences
'run recursive Sub here
'checks this component, and checks any sub-components
ProcessAndIterate(oADef, oOcc, oStr, oView)
Next
End If
Next
Next
oDDoc.Update
End Sub
Sub ProcessAndIterate(oTopAsmDef As AssemblyComponentDefinition, oCom As ComponentOccurrence, oSt As String, oDView As DrawingView)
'just creating new variables here to enable 'Intellisense' recognition
'and so that recursive calls are using different input variables
Dim oADef As AssemblyComponentDefinition = oTopAsmDef
Dim oComp As ComponentOccurrence = oCom
Dim oStr As String = oSt
Dim oView As DrawingView = oDView
If oComp.Name.StartsWith(oSt) Then
'call other Function here to get top level component occurrence proxy to work with, if applicable
Dim oTopLevelOccProxy As ComponentOccurrenceProxy = MakeTopLevelProxy(oTopAsmDef, oComp)
If oTopLevelOccProxy Is Nothing Then
Try
oView.SetVisibility(oComp, False)
Catch
MsgBox("Failed to turn off visibility to component [" & oComp.Name & "] within the view named [" & oView.Name, , "")
End Try
ElseIf oTopLevelOccProxy IsNot Nothing Then
Try
oView.SetVisibility(oTopLevelOccProxy, False)
Catch
MsgBox("Failed to turn off visibility to component [" & oComp.Name & "] within the view named [" & oView.Name, , "")
End Try
End If
End If
If oComp.DefinitionDocumentType = DocumentTypeEnum.kAssemblyDocumentObject Then
For Each oOcc As ComponentOccurrence In oComp.Definition.Document.ComponentDefinition.Occurrences
ProcessAndIterate(oADef, oOcc, oStr, oView)
Next
End If
End Sub
Function MakeTopLevelProxy(oTopADef As AssemblyComponentDefinition, oOcc As ComponentOccurrence) As ComponentOccurrenceProxy
Dim oADef As AssemblyComponentDefinition = oTopADef
Dim oComp As ComponentOccurrence = oOcc
Dim oPComp As ComponentOccurrence 'parent component, if there is one
Dim oCompProxy As ComponentOccurrenceProxy 'mid-level proxy object
If oComp.Parent Is oADef Then
'This is a top level component, so no proxy is needed
'maybe return Nothing, then in the calling Sub, check for Nothing
Return Nothing
Exit Function
ElseIf oComp.ParentOccurrence IsNot Nothing Then
oPComp = oComp.ParentOccurrence
oPComp.CreateGeometryProxy(oComp, oCompProxy)
Dim oTopLevelCompProxy As ComponentOccurrenceProxy
'attempt to create a ComponentOccurrenceProxy within the top assembly
oTopLevelCompProxy = oADef.AdjustProxyContext(oCompProxy)
Return oTopLevelCompProxy
End If
End FunctionWesley Crihfield
(Not an Autodesk Employee)
Yes, that code does allow you to select a single drawing view curve segment, then turns off visibility of all other geometry in the same view belonging to the same component as the selected geometry. I've used similar code before too when working with multi-body part drawings, to turn off visibility of specific solid bodies.
Since it is very efficient and combines many things in few lines, it can be a bit difficult for others to follow, so I had a variation of that 'assembly' version of the code, that includes some very helpful comments to help understand how it all works, that you (and others) might find helpful.
Sub Main
Dim oSeg As DrawingCurveSegment = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kDrawingCurveSegmentFilter, "Seleziona Componente")
'get view
'DrawingCurveSegment.Parent is a DrawingCurve
'DrawingCurve.Parent is a DrawingView
Dim oView As DrawingView = oSeg.Parent.Parent
'get the component
'DrawingCurve.ModelGeometry is either an 'Edge' or an 'EdgeProxy'
'Edge.Parent & EdgeProxy.Parent are both a SurfaceBody
'SurfaceBody.Parent is either a ComponentOccurrence or ComponentOccurrenceProxy (in an assembly drawing)
Dim oComp As Object = oSeg.Parent.ModelGeometry.Parent.Parent
'turn it off
Try
oView.SetVisibility(oComp, False)
Catch
End Try
End Sub If this solved your problem, or answered your question, please click ACCEPT SOLUTION.
Or, if this helped you, please click (LIKE or KUDOS) 👍.
Wesley Crihfield
(Not an Autodesk Employee)
Here is the Multi-Body Part version of that code. It allows you to select a drawing curve segment in a view, then gets the 'SurfaceBody' it belongs to, and turns off all geometry for that body. Nearly identical to the assembly version, but one step simpler.
Sub Main
Dim oSeg As DrawingCurveSegment = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kDrawingCurveSegmentFilter, "Seleziona Componente")
'get view
'DrawingCurveSegment.Parent is a DrawingCurve
'DrawingCurve.Parent is a DrawingView
Dim oView As DrawingView = oSeg.Parent.Parent
'get the body
'DrawingCurve.ModelGeometry is an 'Edge'
'Edge.Parent is a SurfaceBody
Dim oBody As Object = oSeg.Parent.ModelGeometry.Parent
'turn it off
Try
oView.SetVisibility(oBody, False)
Catch
End Try
End Sub
If this solved your problem, or answered your question, please click ACCEPT SOLUTION.
Or, if this helped you, please click (LIKE or KUDOS) 👍.
Wesley Crihfield
(Not an Autodesk Employee)