Moving an existing revision table to the bottom left corner on the border

[Anonymous]

On using VBA to update some drawings I have found that the revision table is not always in the correct place once they've been updated.

I would like it to be sat against the border in the bottom left corner of the drawing but can't work out how. I assumed that the MinPoint of the border and revision table would be the same but cannot get the code to work.

Any advice?

Sub AlignRevBox()

    Set invDoc = ThisApplication.ActiveDocument
    Set oRevTable = invDoc.ActiveSheet.RevisionTables.Item(1)

    Dim RevPt As Point2d
    Dim BorderPt As Point2d
    Dim oTG As TransientGeometry

    Set BorderPt = invDoc.ActiveSheet.Border.RangeBox.MinPoint
    Debug.Print BorderPt.X, BorderPt.Y
    oTG = ThisApplication.TransientGeometry
    RevPt = oTG.CreatePoint2d(BorderPt.X, BorderPt.Y)
    
    oRevTable.RangeBox.MinPoint = RevPt


End Sub

[bshbsh]

replace last line with this:

oRevTable.Position = RevPt

[Anonymous]

I tried that and it aligned the top of the table with the bottom of the border meaning the table was outside the border. I would like the bottom left corner of the table aligned with the bottom left corner of the border.

[salariua · Accepted solution]

how about this? works for me

Sub AlignRevBox()

    Set invDoc = ThisApplication.ActiveDocument
    Set oRevTable = invDoc.ActiveSheet.RevisionTables.Item(1)

    Dim RevPt As Point2d
    Dim BorderPt As Point2d
    Dim oTG As TransientGeometry

    Set BorderPt = invDoc.ActiveSheet.Border.RangeBox.MinPoint

    'Debug.Print BorderPt.X, BorderPt.Y
    Set oTG = ThisApplication.TransientGeometry
    Set RevPt = oTG.CreatePoint2d(BorderPt.X, BorderPt.Y + (oRevTable.RangeBox.MaxPoint.Y - oRevTable.RangeBox.MinPoint.Y))

    oRevTable.Position = RevPt

End Sub

[Anonymous]

Ah yes thank you, that does make sense.