Is it possible to get the user's name and surname (profile), and maybe other details, from Account details, VBA/iLogic code?

[engilic]

Hi,

Is it possible to get the user's name and surname (profile), and maybe other details, from Account details, VBA/iLogic code?

Just to have personalized messages, (would be nice).

I attached a screenshot with my details to specify what I want.

Thank you

[JhoelForshav]

Hi @engilic 

Seems like you want to get the info from a360. There's a lot of information you can get using the entitlement API.

See this iLogic example for first and last name 🙂

AddReference "AddinNETFramework.AdWebServicesWrapper.dll"
Imports Autodesk.WebServices

Sub Main
	Dim firstName As String = ""
	Dim lastName As String = ""

	If GetUserName(firstName, lastName) Then
		MessageBox.Show("Hello, " & firstName & " " & lastName, _
		"Personal message")
	Else
		MessageBox.Show("Failed to get user info.", "Fail")
	End If

End Sub
Public Function GetUserName(ByRef firstName As String, ByRef lastName As String) As Boolean
	Try
		Dim webServiceMgr As New CWebServicesManager()
		If webServiceMgr.Initialize() Then
			webServiceMgr.GetUserFirstName(firstName)
			webServiceMgr.GetUserLastName(lastName)
			If firstName = "" Or lastName = "" Then
				firstName = ""
				lastName = ""
				Return False
			Else
				Return True
			End If
		Else
			firstName = ""
			lastName = ""
			Return False
		End If

		Return True
	Catch ex As Exception
		firstName = ""
		lastName = ""
		Return False
	End Try
End Function

[JhoelForshav · Accepted solution]

I tried this in Inventor 2021 now and there it failed. So I added the line:

ThisApplication.Login()

before

webServiceMgr.Initialize()

and then it worked. So the complete code should look like this 🙂

AddReference "AddinNETFramework.AdWebServicesWrapper.dll"
Imports Autodesk.WebServices

Sub Main
	Dim firstName As String = ""
	Dim lastName As String = ""

	If GetUserName(firstName, lastName) Then
		MessageBox.Show("Hello, " & firstName & " " & lastName, _
		"Personal message")
	Else
		MessageBox.Show("Failed to get user info.", "Fail")
	End If

End Sub
Public Function GetUserName(ByRef firstName As String, ByRef lastName As String) As Boolean
	Try
		Dim webServiceMgr As New CWebServicesManager()
		ThisApplication.Login()
		If webServiceMgr.Initialize() Then
			webServiceMgr.GetUserFirstName(firstName)
			webServiceMgr.GetUserLastName(lastName)
			If firstName = "" Or lastName = "" Then
				firstName = ""
				lastName = ""
				Return False
			Else
				Return True
			End If
		Else
			firstName = ""
			lastName = ""
			Return False
		End If

		Return True
	Catch ex As Exception
		firstName = ""
		lastName = ""
		Return False
	End Try
End Function

[engilic]

Thank you very much @JhoelForshav ,

This is great, works like a charm.

Is it difficult to transfer it to VBA or not?

Just not sure about the first two lines, AddReference, and Imports.

Also webServiceMgr function.

Thank you

[engilic]

Can anyone make this code work in VBA?

Thx

[engilic]

Please @JhoelForshav ,

Is it possible to get VBA code for macro, I cannot do it.

Thank you.

[jake_egley]

In VBA it's much easier:

Dim UserName As String
UserName = Environ("USERNAME")
MsgBox (UserName)