How to change the Origin Indicator position

[Crstiano]

Hi guys,

How to change the Origin Indicator position on drawing view?

how do I attach a new Intent ?

[JhoelForshav · Accepted solution]

Hi @Crstiano 

I wrote this example ilogic code for you.

I made a simple part with a workpoint in it named "TestPoint". Then i created a drawingview from this part.

the code includes the workpoint, finds it centermark in the view and creates geometryintent from it.

Then if there already is an origin indicator it moves it to the point, else it creates it on the point.

Hope it helps 🙂

Dim oDoc As DrawingDocument = ThisDoc.Document
Dim oSheet As Sheet = oDoc.ActiveSheet
Dim oView As DrawingView = oSheet.DrawingViews.Item(1)
Dim oPartDoc As PartDocument = oView.ReferencedDocumentDescriptor.ReferencedDocument
Dim oWP As WorkPoint = oPartDoc.ComponentDefinition.WorkPoints.Item("TestPoint")

oView.SetIncludeStatus(oWP, True)

Dim oWPCenterMark As Centermark
Dim oCenterMark As Centermark
For Each oCenterMark In oSheet.Centermarks
	If oCenterMark.AttachedEntity Is oWP Then
		oWPCenterMark = oCenterMark
		oWPCenterMark.Visible = True
	End If
Next

Dim oGeometryIntent As Inventor.GeometryIntent
oGeometryIntent = oSheet.CreateGeometryIntent(oWPCenterMark, kPoint2dIntent)

If oView.HasOriginIndicator
oView.OriginIndicator.Intent = oGeometryIntent
Else
oView.CreateOriginIndicator(oGeometryIntent)
End If

oCenterMark.Visible = False

[JhoelForshav]

I edited the code so it doesnt include a point over and over again if you use it to toggle the origin indicator back and forth between two points:

Dim oDoc As DrawingDocument = ThisDoc.Document
Dim oSheet As Sheet = oDoc.ActiveSheet
Dim oView As DrawingView = oSheet.DrawingViews.Item(1)
Dim oPartDoc As PartDocument = oView.ReferencedDocumentDescriptor.ReferencedDocument
Dim oWP As WorkPoint = oPartDoc.ComponentDefinition.WorkPoints.Item("Center Point")
If oView.GetIncludeStatus(oWP) = False Then oView.SetIncludeStatus(oWP, True)
Dim oWPCenterMark As Centermark
Dim oCenterMark As Centermark
For Each oCenterMark In oSheet.Centermarks
	If oCenterMark.AttachedEntity Is oWP Then
		oWPCenterMark = oCenterMark
	End If
Next
Dim oGeometryIntent As Inventor.GeometryIntent
oGeometryIntent = oSheet.CreateGeometryIntent(oWPCenterMark, kPoint2dIntent)

If oView.HasOriginIndicator
	oView.OriginIndicator.Intent = oGeometryIntent
Else
	oView.CreateOriginIndicator(oGeometryIntent)
End If

oCenterMark.Visible = False

[Crstiano]

It so simple... and I tried many another ways 🙂

oView.OriginIndicator.Intent = NewIntent

Thanks @JhoelForshav 

[tecnico]

Unfortunately the rule gives errors, I would need to create a point in the center of my part. and make it invisible in 3D but include it inside my 2D table, I can't find the rule to create a point nor the way to position it in the center, it is clear not at the center of gravity, but at the center of the maximums of the figure.