Gestion des d'affichages des pieces et assemblages

[julien.avril]

Bonjour

Dans mon entreprise , nous avons un assemblage qui contient beaucoup d'assemblages et de Pieces.

Il est très compliqué de sélectionner les pièces car trop nombreuses.

J'aimerais afficher un ensemble de pièces et pas d'autre.

Exemple:

J'ai un ensemble de 5 modules qui porte un noms différent module1, module2 ....

Dans chaque module, il y a des pièces que je souhaite afficher comme luminaire et poteau qui ne sont pas unique.

Je n'arrive pas à a faire afficher la pièce qui contient le nom "luminaire" et "Poteau".

Peux-être je devrais mettre une ipropriété dans chaque pièces et afficher la pièce si l'ipropriéré est présente

Mais je ne sais pas comment réaliser cette fonction car il y a un gestion d'affichage par le nom.

Merci pour vos idée

[ThomasB44]

Salut @julien.avril 

Sélectionne une pièce ou plusieurs (exemple : un luminaire et un poteau) puis clic droit, sélectionner toutes les occurrences :

Et enfin clic droit, isoler :

[julien.avril]

est-ce que l'on peut traduire ca en ilogic?

[ThomasB44]

Oui, il suffit de boucler sur l'ensemble des occurrences de l'assemblage.

Si le nom de la pièce ou de l'ensemble = "poteau" alors : visible

Sinon : Invisible

Et ainsi de suite.

[julien.avril]

oui j'y ai bien pensé mais le problème est que Inventor crée des pièces unique donc le poteau , il le nomme "poteau1" , "poteau 2" ... et je n'arrive pas a rechercher un nom qui contient "poteau)

[ThomasB44]

Non il créé :

Poteau:1

Poteau:2

Il suffit de faire un split pour retirer le ":" et ce qui se trouve derrière.

Ou d'aller chercher le nom de fichier, qui est toujours le même quel que soit l'occurrence.

Sinon il y a aussi les vues de représentations, qui sont très utiles dans ce genre de cas.

[julien.avril]

Peux-tu me donner le code pour remplacer ca avec la

fonction split que je ne connais pas

[ThomasB44]

Voici le principe de la fonction Split :

Dim NomOccurrence, NomUnique As String
NomOccurrence = "Poteau:1865446546"
Words = Split(NomOccurrence, ":")
NomUnique = Words(0)
MessageBox.Show(NomUnique, "Title")

[julien.avril]

Comment je peux avoir la liste de toutes les occurrences de poteau

[ThomasB44]

En voici un exemple :

Sub Main TraverseAssemblySample()
'Get the active assembly.
Dim oAsmDoc As AssemblyDocument
oAsmDoc = ThisApplication.ActiveDocument

Call TraverseAssembly(oAsmDoc.ComponentDefinition.Occurrences)

End Sub

Private Sub TraverseAssembly(ByVal Occurrences As ComponentOccurrences)
'Iterate through all of the occurrence in this collection. This
'represents the occurrences at the top level of an assembly.
For Each oOcc As ComponentOccurrence In Occurrences

'Get the document file for this occurrence
Dim oDoc As Document
oDoc = oOcc.Definition.Document
*******************
'Do some stuff here
*******************

'Check to see if this occurrence represents a subassembly
'and recursively call this function to traverse through it.
If oOcc.DefinitionDocumentType = kAssemblyDocumentObject Then
Call TraverseAssembly(oOcc.SubOccurrences)
End If
Next
End Sub

[julien.avril]

désolé mais la ca dépasse mes compétences et je ne comprend pas ce code.

Je ne vois pas ou indiquer "poteau" dans ce code

[ThomasB44 · Accepted solution]

Tu vas comprendre en lançant ce code dans un petit ensemble.

Ce n'est pas du purement du iLogic (les commandes qui apparaissent violet), mais du VB.NET, c'est presque comme du VBA, et beaucoup plus complet.

Sub Main
    'Get the active assembly.
    Dim oAsmDoc As AssemblyDocument
    oAsmDoc = ThisApplication.ActiveDocument

    Call TraverseAssembly(oAsmDoc.ComponentDefinition.Occurrences)

End Sub

Private Sub TraverseAssembly(ByVal Occurrences As ComponentOccurrences)
    'Iterate through all of the occurrence in this collection.  This
    'represents the occurrences at the top level of an assembly.
    For Each oOcc As ComponentOccurrence In Occurrences

        'Get the document file for this occurrence
        Dim oDoc As Document
        oDoc = oOcc.Definition.Document
		
		'************************************
		Dim oFileName, oOccName As String
		Words = Split(oOcc.Name, ":")
		oOccName = Words(0)
		Words = Split(oDoc.DisplayName, ".")
		oFileName = Words(0)
		MessageBox.Show("FileName : " & oFileName & _
		vbNewLine & "DisplayName : " & oOccName, "iLogic")
		'***********************************

        'Check to see if this occurrence represents a subassembly
        'and recursively call this function to traverse through it.
        If oOcc.DefinitionDocumentType = kAssemblyDocumentObject Then
            Call TraverseAssembly(oOcc.SubOccurrences)
        End If
    Next
End Sub

[julien.avril]

dans ton code , je ne comprend pas a quoi sert les boites de dialogue.

A la fin il ne m'affiche pas les éléments demandés

[ThomasB44]

La boite de dialogue est juste un exemple qui te donne le nom du fichier et le nom d'affichage de l'occurrence.

Tu n'as plus qu'à faire tes conditions et changer l'état de visibilité du composant.

[patrick.emin]

Bonjour @julien.avril 

Si une des réponses résout votre problème ou vous a permis de mieux le comprendre, voulez vous avoir l'amabilité de cliquer sur le bouton  APPROUVER LA SOLUTION  en bas de la réponse qui apporte une solution?
Merci de ne pas accepter comme solution le message que vous êtes en train de lire.

[julien.avril]

J'ai presque réussi mais il me reste juste une petite variable que je n'arrive pas à faire.

Avec le code ci dessous, j'arrive à masquer tout les poteaux qui se trouvent dans mon premier module , mais pas les autres, il faudrait  que le code recherche dans tous les assemblage

Sub Main
    'Get the active assembly.
    Dim oAsmDoc As AssemblyDocument
    oAsmDoc = ThisApplication.ActiveDocument

    Call TraverseAssembly(oAsmDoc.ComponentDefinition.Occurrences)

End Sub

Private Sub TraverseAssembly(ByVal Occurrences As ComponentOccurrences)
    'Iterate through all of the occurrence in this collection.  This
    'represents the occurrences at the top level of an assembly.
    For Each oOcc As ComponentOccurrence In Occurrences

        'Get the document file for this occurrence
        Dim oDoc As Document
        oDoc = oOcc.Definition.Document
		
		'************************************
		Dim oFileName, oOccName As String
		Words = Split(oOcc.Name, ":")
		oOccName = Words(0)
		Words = Split(oDoc.DisplayName, ".")
		oFileName = Words(0)
		'MessageBox.Show("FileName : " & oFileName & _
		'vbNewLine & "DisplayName : " & oOccName, "iLogic")
		If oFileName = "poteau"
			Component.Visible(oOcc.Name) = False
		End If

		'***********************************

        'Check to see if this occurrence represents a subassembly
        'and recursively call this function to traverse through it.
        If oOcc.DefinitionDocumentType = kAssemblyDocumentObject Then
            Call TraverseAssembly(oOcc.SubOccurrences)
        End If
    Next
End Sub

[ThomasB44 · Accepted solution]

Ce n'est pas la bonne commande...

oOcc.Visible = False

[julien.avril]

super ca fonctionne

[julien.avril]

Bonjour

As-tu un code pour afficher toutes les pièces et assemblage de l'environnement?

Je souhaiterais l'intégrer au début pour être sur que tout fonctionne bien.

Merci

Merci d'avance 

[ThomasB44]

Salut,

Pas besoin de code pour cela.

Il suffit de revenir à la représentation de vue principale.