Countersunk Holes W/ Depth

[Cadmanto]

Has anyone ever been able to use the Hole command to create the hole shown below?

I am not seeing an option to do this.

I know I can just create a sketch and revolve a cut feature, but when there are multiple holes in a block of wood, there is nothing convenient about that method. 🙁

Windows 10 x64 -16GB Ram
Intel i7-6700 @ 3.41ghz
nVidia GTS 250 - 1 GB
Inventor Pro 2020

[Cadmanto · Accepted solution]

I did figure out another method.  Create the counter bored hole then added a chamfer splitting the difference between the OD and ID.  This works and is not too painful.  It just would be a whole lot simpler if it was all under the hole command umbrella. 

Windows 10 x64 -16GB Ram
Intel i7-6700 @ 3.41ghz
nVidia GTS 250 - 1 GB
Inventor Pro 2020

[Curtis_Waguespack]

Hi Scott, this has been requested in the past, you better go vote... I think your vote is going to be the one to make it happen! 😉 

https://forums.autodesk.com/t5/inventor-ideas/add-hole-type-counterbored-countersunk/idi-p/5497777

[Cadmanto]

Hi Curtis,

As it stands, I already voted for it.  I guess this is what happens when an idea is in the pipe line for too long. 😴  Like 5 years for this one.  Should I add an English version of the idea to the station seeing this one is in Greek? 😁

I will add a comment with a link to this thread though.

Windows 10 x64 -16GB Ram
Intel i7-6700 @ 3.41ghz
nVidia GTS 250 - 1 GB
Inventor Pro 2020

[JDMather]

I have a similar type need where I created a Punch tool, so that this works just like the Hole feature.

I simply:

Environments>Convert to Sheet Metal (even if it is absolutely nothing like a sheet metal part).

Create sketch with center point locations.

Place Punch (entering appropriate dimensions).

Environments>Convert to Standard Part.

[johnsonshiue]

Hi Scott,

This requires two hole features. You can create a spotface hole and then add a C'sink hole.

Many thanks!

[Curtis_Waguespack]

@Cadmanto  (and anyone else that might be interested)

Here's a quick ilogic rule that will add a chamfer to a counterbore to do this... I didn't test it that much so it you might find issues with it, but it worked for my limited testing.

Just create an ilogic rule and add this code, then run the rule and select the counter bore hole

Dim oDoc As Document
oDoc = ThisApplication.ActiveDocument

							
Dim oFeature As Object
oFeature = ThisApplication.CommandManager.Pick(
  SelectionFilterEnum.kPartFeatureFilter, 
  "Select Hole Features (press ESC to continue)") 
	
	
If not TypeOf oFeature is HoleFeature Then 
	MessageBox.Show("Hole feature not selected", "iLogic")
	Return 'exit rule
End If	

Dim oHole As HoleFeature
oHole = oDoc.ComponentDefinition.Features.HoleFeatures.Item(oFeature.name)

Dim oDiamParam As Parameter
Dim oHDiam As Double
oDiamParam = oHole.HoleDiameter
oHDiam = oDiamParam.Value


Dim CBoreDiameter As Parameter
Dim oDCBore As Double
CBoreDiameter = oHole.CBoreDiameter
oDCBore = CBoreDiameter.Value


Dim oEdgeCol As EdgeCollection
oEdgeCol = ThisApplication.TransientObjects.CreateEdgeCollection()
 
Dim oFace As Face 
Dim oEdge As Edge
'Dim CurveEval As CurveEvaluator
Dim oDia As Double

For Each oFace In oHole.Faces
	If oFace.SurfaceType = SurfaceTypeEnum.kCylinderSurface Then 
		oDia = oFace.Geometry.radius*2
		Logger.Info(oDia)
		Logger.Info(oHDiam)
		If oDia = oHDiam Then
			oEdgeCol.Add(oFace.Edges.Item(2))
		End If

	End If

	oChamferLength = oDCBore-oHDiam
	Try
		oDoc.ComponentDefinition.Features.ChamferFeatures.AddUsingDistanceAndAngle _
				(oEdgeCol, oFace, oChamferLength/2, 45 * PI/180)
	Catch
	End Try
Next

	
	

I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com

[Cadmanto]

Hi Johnson,

That is kind of what I am doing as per my second post in this thread.

Windows 10 x64 -16GB Ram
Intel i7-6700 @ 3.41ghz
nVidia GTS 250 - 1 GB
Inventor Pro 2020

[Cadmanto]

JD,

That sounds like a lot of work.  No offense, buy I like my second suggestion better and even maybe @Curtis_Waguespack  iLogic rule (which I am going to try).

Windows 10 x64 -16GB Ram
Intel i7-6700 @ 3.41ghz
nVidia GTS 250 - 1 GB
Inventor Pro 2020

[Cadmanto]

Hi @Curtis_Waguespack ,

I tried this rule and it sort of worked.  Meaning, I had a hole feature that encompassed 4 holes.  The rule only worked on one of the four holes.  When I selected another hole within the same hole feature, it did not convert.

Windows 10 x64 -16GB Ram
Intel i7-6700 @ 3.41ghz
nVidia GTS 250 - 1 GB
Inventor Pro 2020

[blandb]

You could just offset a work plane to control the depth, then place the c'sink on that work plane, and utilize the extend start to generate the hole.

Counter drill

Hope that helps.

[Curtis_Waguespack]

---

@Cadmanto wrote:

Hi @Curtis_Waguespack ,

I tried this rule and it sort of worked.  Meaning, I had a hole feature that encompassed 4 holes.  The rule only worked on one of the four holes.  When I selected another hole within the same hole feature, it did not convert.

---

Ooops!, I didn't write it to look at a hole feature with multiple holes within it... I'll have a look later and see if that can be achieved too.

[doug.johnston]

---

@johnsonshiue wrote:

Hi Scott,

This requires two hole features. You can create a spotface hole and then add a C'sink hole.

Many thanks!

---

This is what I had to do yesterday.  The first time I've had to model this type of hole and was surprised it wasn't included in the Hole command.

[NigelHay]

 blandb, that works really well.

[Curtis_Waguespack · Accepted solution]

@Cadmanto 

Hi Scott, 

Here's a more robust version, it'll chamfer multiple holes within the same hole feature, and it'll allow you to select multiple hole features in a row.

I hope this helps.
Best of luck to you in all of your Inventor pursuits,
Curtis
http://inventortrenches.blogspot.com

Dim oDoc As Document
oDoc = ThisApplication.ActiveDocument
							
Dim oFeature As Object  
While True

	oFeature = ThisApplication.CommandManager.Pick(
	  SelectionFilterEnum.kPartFeatureFilter, 
	  "Select Counterbore Hole Features (press ESC to continue)")
		
		'if nothing then exit
		If IsNothing(oFeature) Then Exit While
	
	If Not TypeOf oFeature Is HoleFeature Then 
		MessageBox.Show("Hole feature not selected", "iLogic")
		Continue While
	End If	

	Dim oHole As HoleFeature
	oHole = oDoc.ComponentDefinition.Features.HoleFeatures.Item(oFeature.name)
	
	If Not oHole.HoleType = HoleTypeEnum.kCounterBoreHole Then 
		MessageBox.Show("Hole feature is not a Counterbore", "iLogic")	
		Continue While
	End If
		
	oHole.SetEndOfPart(False ) 

	'clean up existing chamfer (mostly for testing)
	Try
	sHole = oHole.Name & "_Chamfer" 
	oDoc.ComponentDefinition.Features.ChamferFeatures.Item(sHole).delete
	Catch
	End Try

	'get the hole diameter
	Dim oDiamParam As Parameter
	Dim oHDiam As Double	
	oDiamParam = oHole.HoleDiameter
	oHDiam = oDiamParam.Value

	'get the counter bore diameter
	Dim CBoreDiameter As Parameter
	Dim oDCBore As Double
	CBoreDiameter = oHole.CBoreDiameter
	oDCBore = CBoreDiameter.Value

	'create a collection hold the edges
	Dim oEdgeCol As EdgeCollection
	oEdgeCol = ThisApplication.TransientObjects.CreateEdgeCollection()
	 
	Dim oFace As Face 
	Dim oEdge As Edge
	Dim oDia As Double
	Dim oCir As Inventor.Circle

	'find the planer face in the hole
	For Each oFace In oHole.Faces
		If oFace.SurfaceType = SurfaceTypeEnum.kPlaneSurface Then			
			For Each oEdge In oFace.Edges
				'find the edge in the face that is the same as the diameter
				If oEdge.CurveType = CurveTypeEnum.kCircleCurve Then
					If TypeOf oEdge.Geometry Is Inventor.Circle Then		   			 
						 oCircle = oEdge.Geometry
						 If oCircle.radius * 2 = oHDiam Then
							 'add the edge to the collection
							oEdgeCol.Add(oEdge)							
						 End If
					End If
				End If				
			Next		
		End If
	Next

	'calc the chamfer distance
	oChamferLength = oDCBore - oHDiam
	'create the chamfer feature
	Try	
		oChamfer = oDoc.ComponentDefinition.Features.ChamferFeatures.AddUsingDistance _
				(oEdgeCol, oChamferLength / 2)
		oChamfer.name = oHole.Name & "_Chamfer" 
	Catch
	End Try

	oDoc.ComponentDefinition.SetEndOfPartToTopOrBottom(False) ' Set to bottom

End While

	
	

[Cadmanto]

@Curtis_Waguespack 

Worked like a charm Curtis!!!  Thank you!!

Saved the rule for future use locally.

Windows 10 x64 -16GB Ram
Intel i7-6700 @ 3.41ghz
nVidia GTS 250 - 1 GB
Inventor Pro 2020