How do I change the color of a solid in a multibodied part?
Below is some VBA code that accomplishes what you want. You had some confusion between a body and a component occurrence. Another thing not obvious is that to assign an appearance to a body, the appearance needs to exist in the document, which means first copying it from the library into the document. This happens automatically through the UI but in the API you need to take care of it.
Public Sub TestAppearanceChange()
Dim partDoc As PartDocument
Set partDoc = ThisApplication.ActiveDocument
Dim oBody As SurfaceBody
Set oBody = partDoc.ComponentDefinition.SurfaceBodies.Item(1)
Call ChangeSBColor(oBody, "Gold")
End Sub
Public Sub ChangeSBColor(body As SurfaceBody, strColor As String)
Dim appAsset As Asset
Dim oLib As AssetLibrary
Dim assAssets As Assets
' Get the parent part document.
Dim partDoc As PartDocument
Set partDoc = body.Parent.Document
' Get a spsecific appearance in a library.
Set oLib = ThisApplication.AssetLibraries("Inventor Material Library")
Set appAsset = oLib.AppearanceAssets(strColor)
' Copy the library into the document.
Dim docAsset As Asset
Set docAsset = appAsset.CopyTo(partDoc, False)
' Set the appeareance on the body.
body.Appearance = docAsset
End Sub
This code helps and I think it does go back to the statement I made before about some confusion about the difference between an occurrence and a body. Here's a quick overview.
Body - The result of creating surfaces or solids in a part. Solids are shown in the "Solid Bodies" folder in the browser and surfaces are shown in the "Surface Bodies" folder in the browser. In the API both solids and surfaces are represented by the SurfaceBody object. There is an IsSolid property on the object that indicates if it's representing a surface or solid. Within a part you can assign a color to a body which overrides the part color. You can also assign colors to individual features and faces.
ComponentOccurrence - An occurrence represents an instance of a part or assembly within an assembly. Each time you place a part or an assembly into an assemblyl you're creating a new ComponentOccurrence. An occurrence doesn't have any geometry on it's own but displays the geometry in the part or assembly that it references. In an assembly you can change the color of an occurrence, which overrides the color as defined in the referenced part or assembly. This is an override in the assembly and doesn't affect the original part or assembly. Inventor also supports changing the color of a body within an occurrence which is also an override of the color defined in the original part. Overriding the colors of features or faces is not supported in an assembly but can only be changed in the original part.
For example, let's say there is a part (cubes.ipt) that contains two cubes, each one being a unique body in the part. Now, if we insert this part two times into an assembly we'll have two occurrences that both reference cubes.ipt. If you make any changes to cubes.ipt and then open the assembly you'll see thouse changes reflected in both occurrences because they're referencing cubes.ipt.
Proxy - A proxy is an object that represents another object within a assembly. For the example above there are two bodies; the two cubes in cubes.ipt. However, when we look at the assembly we see four cubes because we have to occurrences of cubes.ipt. These four cubes don't actually exist in the assembly Inventor makes it appear that they do. It does this through proxies. There is a unique proxy object for each of the four cubes. If you change the color of one of the cubes you're actually overriding the color on the SurfaceBodyProxy that represents that specific cube.
In your code you're starting off by selecting three different occurrences, not bodies. The ComponentOccurrence object has a SurfaceBodies property which returns the SurfaceBodyProxy objects associated with that occurrence. You can set the appearance of these and it will change the color for that specific body proxy in the assembly. Since the color is being assigned to something in the assembly, the appearance must be copied to the AssemblyDocument before it can be used.
The ComponentOccurrence object also supports the Definition property which you are using. If the occurrence represents a part, this returns the PartComponentDefinition of the part being referenced. This means you've completely left the context of the assembly and are working only within the part. You can do anything you would usually do with a part. Changing colors here will change the colors in the part and you'll see it in all instances in the assembly. For example, if I change the color of one of the cubes, in the assembly two cubes will change color because two of the cubes represent the same cube in the part.
I know this can all be a bit confusing and I'm happy to try and explain more if you need it.
I think a small code sample might be the best but before I write something I want to be clear about the specifics of what you're trying to do. In the example I gave below where we have a part with two bodies and that part is inserted into an assembly, there are two possibilities when looking at changing the color of bodies. We can change the color of a body in the context of the assembly (SurfaceBodyProxy) which will result in just one of the four bodies seen in the assembly changing color. Or we can change the color of the body in the part which will result in two of the bodies in the assembly changing color.
Here's some code that will do both; if a body is selected in an assembly it will change the color of the body proxy so only that single body will change color. If a body is selected in a part it will change the color of the body in the part. There's also some code that's commented out so that even if you select the body in an assembly it will change the color of the body in the part, thus affecting all bodies in the assembly that reference that part body. Hopefully this helps and gets you past this challenge.
Public Sub TestColor()
Dim body As SurfaceBody
Set body = ThisApplication.CommandManager.Pick(kPartBodyFilter, "Select a body")
' If you always want to change it at the part level, get the real body from the proxy
' and pass that it.
' If TypeOf body Is SurfaceBodyProxy Then
' Set body = body.NativeObject
' End If
' Change the color of the body.
Call ChangeSBColor(body, "Canary")
End Sub
Public Sub ChangeSBColor(body As SurfaceBody, strColor As String)
' Get the parent document. If the body is a proxy this will be an
' assembly document. If not, it will be a part document.
Dim parentDoc As Document
If TypeOf body Is SurfaceBodyProxy Then
Set parentDoc = body.Parent.Parent.Document
Else
Set parentDoc = body.Parent.Document
End If
' Get the specified asset from the library.
Dim oLib As AssetLibrary
Set oLib = ThisApplication.AssetLibraries("Inventor Material Library")
Dim appAsset As Asset
Set appAsset = oLib.AppearanceAssets(strColor)
' Copy the assett into the document.
Dim docAsset As Asset
Set docAsset = appAsset.CopyTo(parentDoc, True)
' Change the appearance of the body.
body.Appearance = docAsset
' Force a view update to see the results.
ThisApplication.ActiveView.Update
End Sub
