Announcements
Attention for Customers without Multi-Factor Authentication or Single Sign-On - OTP Verification rolls out April 2025. Read all about it here.

to put this all together for iLogic, here is an example 

 

Sub Main

	Dim oDoc As DrawingDocument
	oDoc = ThisApplication.ActiveDocument
	
	Dim oDrawingDimCollec1 As ObjectCollection
	oDrawingDimCollec1 = GetDrawingDimForView(oDoc.ActiveSheet, "VIEW1")

	For Each oDim As DrawingDimension In oDrawingDimCollec1
		If Round(oDim.ModelValue * 10, 1) -Round(oDim.ModelValue * 10, 0) = 0 Then
			oDim.Precision = 0
		Else
			oDim.Precision = 1
		End If
	Next

End Sub


Public Function GetDrawingDimForView(oSheet As Sheet, ViewName As String) As ObjectCollection
	Dim oDrawDimsForView As ObjectCollection
	oDrawDimsForView = ThisApplication.TransientObjects.CreateObjectCollection

	Dim oDrawDims As DrawingDimensions
	oDrawDims = oSheet.DrawingDimensions

	Dim oDrawDimIterator As DrawingDimension
	For Each oDrawDimIterator In oDrawDims
		Select Case oDrawDimIterator.Type
			Case kLinearGeneralDimensionObject
				Dim oLinearDim As LinearGeneralDimension
				oLinearDim = oDrawDimIterator
				If oLinearDim.IntentOne.Geometry.Parent.Name = ViewName Then
					oDrawDimsForView.Add(oDrawDimIterator)
				End If
			Case kRadiusGeneralDimensionObject
				Dim oRadiusDim As RadiusGeneralDimension
				oRadiusDim = oDrawDimIterator
				If oRadiusDim.Intent.Geometry.Parent.Name = ViewName Then
					oDrawDimsForView.Add(oDrawDimIterator)
				End If
			Case kDiameterGeneralDimensionObject
				Dim oDiameterDim As DiameterGeneralDimension
				oDiameterDim = oDrawDimIterator
				If oDiameterDim.Intent.Geometry.Parent.Name = ViewName Then
					oDrawDimsForView.Add(oDrawDimIterator)
				End If
			Case kAngularGeneralDimensionObject
				Dim oAngularDim As AngularGeneralDimension
				oAngularDim = oDrawDimIterator
				If oAngularDim.IntentOne.Geometry.Parent.Name = ViewName Then
					oDrawDimsForView.Add(oDrawDimIterator)
				End If
			Case Else
				'Case is not handled...
		End Select
	Next
	GetDrawingDimForView = oDrawDimsForView
End Function