Change point elevations to match projected points elevation

[mike_tomasurvey]

So I created points along an alignment with the elevations to a particular profile. Then I projected the points to the profile view and inserted them with "elevation option" set to a different profile. For example, I calc. the water services and used the invert of the waterline profile as my elevations. I need them to be on the Top back of walk elevation profile. So now my projected points have the correct elevations. Is there an easy way or a lisp command that can give my plan view points the same elevation as the projected points? Right now I am choosing each individual point on the profile view and manually changing the properties in the properties box. I have to thing that there is a more streamlined way of changing the point elevations to the projected elevations. Any help is appreciated. 

[_Hathaway]

Answering a question with a question: Why wouldn't you add points at the TBC profile elevation? When we stake TBC we simply export the alignment and profile and stake off that. Why the need for individual points on your end?

[mike_tomasurvey]

I was actually calc'ing water services and 5' offsets to water services. Normally, the company doesn't need or want elevations on the water services so I use the "Manual" point creation and just snap to the service. Well, this time after I had calc'ed the points the company wanted grades to Back of walk. Well, I have a back of walk profile in my profile view. So I projected all the water service points to that profile in the profile view. So the projected points hit the profile perfectly, obviously, but the projected elevation didn't change the elevations of the actual points in plan view. So now, I need a lisp or an answer on how to get the elevations of the projected points in the profile view to update the actual points in plan view. I hope that makes sense. 

[tcorey · Accepted solution]

This should help:

;This routine:
;asks for a selection set of COGO Points
;asks for a Profile
;Calculates the elevation along that profile, based on Station/Offset of point re the alignment
;replaces current COGO Point elevation value with elevation calculated along selected profile.
(defun c:DES_ProjectPoints ( / pts len ctr pro aln sta off)
(vl-load-com)
(prompt "\nSelect COGO Points: ")
(setq pts (ssget)
	  len (sslength pts)
	  ctr 0)
(setq pro (vlax-ename->vla-object (car (entsel "\nSelect refererence Profile: "))))
(while (not (= (vlax-get pro 'ObjectName) "AeccDbVAlignment"))
		(setq pro (car (entsel "\nObject must be a Civil 3D Profile. Try again: ")))
		)
	(setq aln (vlax-get pro 'Alignment))

		(while (< ctr len)
			(setq pt (vlax-ename->vla-object (ssname pts ctr)))
			(if (= (vlax-get pt 'ObjectName) "AeccDbCogoPoint")
				(progn
               (vlax-invoke-method aln 'StationOffset
				(vlax-get pt 'Easting)
				(vlax-get pt 'Northing)
				'Sta
				'Off
				)
				(setq newZ (vlax-invoke-method pro 'ElevationAt sta))
				(vlax-put pt 'Elevation newZ)
				)
				)
				(setq ctr (1+ ctr))
				)



				(princ)
)

[mike_tomasurvey]

That worked perfectly! Thanks so much!