Need a Lisp for Civil3d Pipes

[saqib_tipa]

Hello all,

Can someone make a lisp for Civil3d pipes, which can move invert levels of multiple selected pipes to surface level.

Thank you.

[hippe013]

Can you explain in a little more detail what you want the lisp to do? I can see why you'd want one invert to match the surface, but both? 

[Jeff_M]

@hippe013 I was actually asked recently (not by the OP here) to add a tool to do this to the Sincpac. It is for subdrains added to a grading plan. 

[hippe013]

@Jeff_M I'll bet that you get all sorts of requests to add to your software. Some ideas may be good, while others might make one wonder, "Why?"

I have code for pipes in my repository; however, it appears that working with pipes via Lisp, particularly structures, can be quite prone to bugs. It is rather easy to adjust a pipe to a surface, but then to adjust the structures to follow is where the bugs come in. At least in my experience. 

I should at-least be able to provide some example code, but making a Lisp command bullet-proof gets to be a bit of work. 

[Jeff_M]

---

@hippe013 wrote:

@Jeff_M I'll bet that you get all sorts of requests to add to your software. Some ideas may be good, while others might make one wonder, "Why?"

You got that right! 😀

I gave up using lisp to work with pipes long ago, .NET is so much easier...

[hippe013 · Accepted solution]

The code below is a quick example of setting pipe inverts to a Tin Surface. Note that this does not update the structures. It also prompts the user to select each pipe individually. Though this can be easily modified to satisfy   individual needs. Hope this helps!

(defun c:PipeToSurface ( / surfSS surf pipeSS pipe success)
  (princ "\nSelect Surface: ")
  (setq surfSS (ssget ":s+." '(( 0 . "AECC_TIN_SURFACE"))))
  (if surfSS
    (progn
      (setq surf (vlax-ename->vla-object (ssname surfSS 0)))
      (while (setq pipeSS (ssget ":s+." '(( 0 . "AECC_PIPE"))))
	(setq pipe (vlax-ename->vla-object (ssname pipeSS 0)))
	(setq success (SetPipeInvertsToSurface pipe surf 0.00))
	(if success
	  (princ "\nPipe Inverts have been set to surface.")
	  (princ "\nPipe does not fully lay on surface.")
	  )
	)
      )
    )
  (princ)
  )


    
  


;SetPipeInvertsToSurface - Sets Pipes Start & End Points onto a surface with a given vertical offset.
;Returns (T) if both points lay on the Surface                                              
;Returns (nil) if one or both of the end points do not lay on a surface.                    
;Example: (setq success (SetPipeInvertsToSurface pipeObject surfaceObject 0.00))            
(defun SetPipeInvertsToSurface (pipe surf vertOffset / p0 p1 halfdia args0 args1 elev0 elev1 output)
  (setq p0 (vlax-safearray->list (vlax-variant-value (vlax-get-property pipe 'PointAtParam 0))))
  (setq p1 (vlax-safearray->list (vlax-variant-value (vlax-get-property pipe 'PointAtParam 1))))
  (setq halfDia (/ (vlax-get-property pipe 'InnerDiameterOrWidth) 2.0))
  
  ;Try and get the Surface Elevation at the StartPoint
  (setq args0 (list surf 'FindElevationAtXY (car p0) (cadr p0)))
  (setq elev0 (vl-catch-all-apply 'vlax-invoke-method args0))

  ;Try and get the Surface Elevation at the EndPoint
  (setq args1 (list surf 'FindElevationAtXY (car p1) (cadr p1)))
  (setq elev1 (vl-catch-all-apply 'vlax-invoke-method args1))

  ;Proceed only if both ends lay on a surface
  (if (and (not(vl-catch-all-error-p elev0)) (not(vl-catch-all-error-p elev1)))
    (progn
      (setq np0 (list (car p0) (cadr p0) (+ elev0 halfdia vertOffset)))
      (setq np1 (list (car p1) (cadr p1) (+ elev1 halfdia vertOffset)))
      (vlax-invoke-method pipe 'SetStartAndEndPoints (vlax-3d-point np0) (vlax-3d-point np1))
      (setq output T)
      )
    (setq output nil)
    )
  output
  )
    

[saqib_tipa]

I want to add pipes (utilities) to show them in the sections and profile and move them down (z axis) to provided depth so that we can show labels of elevation and top of pipe. I just need middle of pipe to match surface elevation.
hope you understand.

[saqib_tipa]

---

@hippe013 wrote:

The code below is a quick example of setting pipe inverts to a Tin Surface. Note that this does not update the structures. It also prompts the user to select each pipe individually. Though this can be easily modified to satisfy   individual needs. Hope this helps!

(defun c:PipeToSurface ( / surfSS surf pipeSS pipe success)
  (princ "\nSelect Surface: ")
  (setq surfSS (ssget ":s+." '(( 0 . "AECC_TIN_SURFACE"))))
  (if surfSS
    (progn
      (setq surf (vlax-ename->vla-object (ssname surfSS 0)))
      (while (setq pipeSS (ssget ":s+." '(( 0 . "AECC_PIPE"))))
	(setq pipe (vlax-ename->vla-object (ssname pipeSS 0)))
	(setq success (SetPipeInvertsToSurface pipe surf 0.00))
	(if success
	  (princ "\nPipe Inverts have been set to surface.")
	  (princ "\nPipe does not fully lay on surface.")
	  )
	)
      )
    )
  (princ)
  )


    
  


;SetPipeInvertsToSurface - Sets Pipes Start & End Points onto a surface with a given vertical offset.
;Returns (T) if both points lay on the Surface                                              
;Returns (nil) if one or both of the end points do not lay on a surface.                    
;Example: (setq success (SetPipeInvertsToSurface pipeObject surfaceObject 0.00))            
(defun SetPipeInvertsToSurface (pipe surf vertOffset / p0 p1 halfdia args0 args1 elev0 elev1 output)
  (setq p0 (vlax-safearray->list (vlax-variant-value (vlax-get-property pipe 'PointAtParam 0))))
  (setq p1 (vlax-safearray->list (vlax-variant-value (vlax-get-property pipe 'PointAtParam 1))))
  (setq halfDia (/ (vlax-get-property pipe 'InnerDiameterOrWidth) 2.0))
  
  ;Try and get the Surface Elevation at the StartPoint
  (setq args0 (list surf 'FindElevationAtXY (car p0) (cadr p0)))
  (setq elev0 (vl-catch-all-apply 'vlax-invoke-method args0))

  ;Try and get the Surface Elevation at the EndPoint
  (setq args1 (list surf 'FindElevationAtXY (car p1) (cadr p1)))
  (setq elev1 (vl-catch-all-apply 'vlax-invoke-method args1))

  ;Proceed only if both ends lay on a surface
  (if (and (not(vl-catch-all-error-p elev0)) (not(vl-catch-all-error-p elev1)))
    (progn
      (setq np0 (list (car p0) (cadr p0) (+ elev0 halfdia vertOffset)))
      (setq np1 (list (car p1) (cadr p1) (+ elev1 halfdia vertOffset)))
      (vlax-invoke-method pipe 'SetStartAndEndPoints (vlax-3d-point np0) (vlax-3d-point np1))
      (setq output T)
      )
    (setq output nil)
    )
  output
  )
    

---

Thank you for your Lisp. This is a nice lisp to match both invert levels to surface levels.

Could you please make it to match only middle of pipe to surface level and if it can match top of pipe to surface level it will be more useful.

Thank you.

[hippe013 · Accepted solution]

@saqib_tipa I certainly can, however if you look at the code the changes required are rather non-trivial. 

Below I have added two additional subroutines. They work in the same fashion as the one I post above. 

One to match the center of pipe to surface and the other to match the top, outside of pipe to the surface. 

;SetPipeCenterToSurface - Sets Pipes Start & End Points onto a surface with a given vertical offset.
;Returns (T) if both points lay on the Surface                                              
;Returns (nil) if one or both of the end points do not lay on a surface.                    
;Example: (setq success (SetPipeCenterToSurface pipeObject surfaceObject 0.00))            
(defun SetPipeCenterToSurface (pipe surf vertOffset / p0 p1 halfdia args0 args1 elev0 elev1 output)
  (setq p0 (vlax-safearray->list (vlax-variant-value (vlax-get-property pipe 'PointAtParam 0))))
  (setq p1 (vlax-safearray->list (vlax-variant-value (vlax-get-property pipe 'PointAtParam 1))))
  
  ;Try and get the Surface Elevation at the StartPoint
  (setq args0 (list surf 'FindElevationAtXY (car p0) (cadr p0)))
  (setq elev0 (vl-catch-all-apply 'vlax-invoke-method args0))

  ;Try and get the Surface Elevation at the EndPoint
  (setq args1 (list surf 'FindElevationAtXY (car p1) (cadr p1)))
  (setq elev1 (vl-catch-all-apply 'vlax-invoke-method args1))

  ;Proceed only if both ends lay on a surface
  (if (and (not(vl-catch-all-error-p elev0)) (not(vl-catch-all-error-p elev1)))
    (progn
      (setq np0 (list (car p0) (cadr p0) (+ elev0 vertOffset)))
      (setq np1 (list (car p1) (cadr p1) (+ elev1 vertOffset)))
      (vlax-invoke-method pipe 'SetStartAndEndPoints (vlax-3d-point np0) (vlax-3d-point np1))
      (setq output T)
      )
    (setq output nil)
    )
  output
  )


;SetPipeTopToSurface - Sets Pipes Start & End Points onto a surface with a given vertical offset.
;Returns (T) if both points lay on the Surface                                              
;Returns (nil) if one or both of the end points do not lay on a surface.                    
;Example: (setq success (SetPipeTopToSurface pipeObject surfaceObject 0.00))            
(defun SetPipeTopToSurface (pipe surf vertOffset / p0 p1 halfdia args0 args1 elev0 elev1 output)
  (setq p0 (vlax-safearray->list (vlax-variant-value (vlax-get-property pipe 'PointAtParam 0))))
  (setq p1 (vlax-safearray->list (vlax-variant-value (vlax-get-property pipe 'PointAtParam 1))))
  (setq halfDia (/ (vlax-get-property pipe 'OuterDiameterOrWidth) 2.0))
  
  ;Try and get the Surface Elevation at the StartPoint
  (setq args0 (list surf 'FindElevationAtXY (car p0) (cadr p0)))
  (setq elev0 (vl-catch-all-apply 'vlax-invoke-method args0))

  ;Try and get the Surface Elevation at the EndPoint
  (setq args1 (list surf 'FindElevationAtXY (car p1) (cadr p1)))
  (setq elev1 (vl-catch-all-apply 'vlax-invoke-method args1))

  ;Proceed only if both ends lay on a surface
  (if (and (not(vl-catch-all-error-p elev0)) (not(vl-catch-all-error-p elev1)))
    (progn
      (setq np0 (list (car p0) (cadr p0) (- (+ elev0 vertOffset) halfdia)))
      (setq np1 (list (car p1) (cadr p1) (- (+ elev1 vertOffset) halfdia)))
      (vlax-invoke-method pipe 'SetStartAndEndPoints (vlax-3d-point np0) (vlax-3d-point np1))
      (setq output T)
      )
    (setq output nil)
    )
  output
  )

Are you able to modify the PipeToSurface command (see my original post) to use one of the subroutines that I post here? 

[saqib_tipa]

---

@hippe013 wrote:

@saqib_tipa I certainly can, however if you look at the code the changes required are rather non-trivial. 

Below I have added two additional subroutines. They work in the same fashion as the one I post above. 

One to match the center of pipe to surface and the other to match the top, outside of pipe to the surface. 

;SetPipeCenterToSurface - Sets Pipes Start & End Points onto a surface with a given vertical offset.
;Returns (T) if both points lay on the Surface                                              
;Returns (nil) if one or both of the end points do not lay on a surface.                    
;Example: (setq success (SetPipeCenterToSurface pipeObject surfaceObject 0.00))            
(defun SetPipeCenterToSurface (pipe surf vertOffset / p0 p1 halfdia args0 args1 elev0 elev1 output)
  (setq p0 (vlax-safearray->list (vlax-variant-value (vlax-get-property pipe 'PointAtParam 0))))
  (setq p1 (vlax-safearray->list (vlax-variant-value (vlax-get-property pipe 'PointAtParam 1))))
  
  ;Try and get the Surface Elevation at the StartPoint
  (setq args0 (list surf 'FindElevationAtXY (car p0) (cadr p0)))
  (setq elev0 (vl-catch-all-apply 'vlax-invoke-method args0))

  ;Try and get the Surface Elevation at the EndPoint
  (setq args1 (list surf 'FindElevationAtXY (car p1) (cadr p1)))
  (setq elev1 (vl-catch-all-apply 'vlax-invoke-method args1))

  ;Proceed only if both ends lay on a surface
  (if (and (not(vl-catch-all-error-p elev0)) (not(vl-catch-all-error-p elev1)))
    (progn
      (setq np0 (list (car p0) (cadr p0) (+ elev0 vertOffset)))
      (setq np1 (list (car p1) (cadr p1) (+ elev1 vertOffset)))
      (vlax-invoke-method pipe 'SetStartAndEndPoints (vlax-3d-point np0) (vlax-3d-point np1))
      (setq output T)
      )
    (setq output nil)
    )
  output
  )


;SetPipeTopToSurface - Sets Pipes Start & End Points onto a surface with a given vertical offset.
;Returns (T) if both points lay on the Surface                                              
;Returns (nil) if one or both of the end points do not lay on a surface.                    
;Example: (setq success (SetPipeTopToSurface pipeObject surfaceObject 0.00))            
(defun SetPipeTopToSurface (pipe surf vertOffset / p0 p1 halfdia args0 args1 elev0 elev1 output)
  (setq p0 (vlax-safearray->list (vlax-variant-value (vlax-get-property pipe 'PointAtParam 0))))
  (setq p1 (vlax-safearray->list (vlax-variant-value (vlax-get-property pipe 'PointAtParam 1))))
  (setq halfDia (/ (vlax-get-property pipe 'OuterDiameterOrWidth) 2.0))
  
  ;Try and get the Surface Elevation at the StartPoint
  (setq args0 (list surf 'FindElevationAtXY (car p0) (cadr p0)))
  (setq elev0 (vl-catch-all-apply 'vlax-invoke-method args0))

  ;Try and get the Surface Elevation at the EndPoint
  (setq args1 (list surf 'FindElevationAtXY (car p1) (cadr p1)))
  (setq elev1 (vl-catch-all-apply 'vlax-invoke-method args1))

  ;Proceed only if both ends lay on a surface
  (if (and (not(vl-catch-all-error-p elev0)) (not(vl-catch-all-error-p elev1)))
    (progn
      (setq np0 (list (car p0) (cadr p0) (- (+ elev0 vertOffset) halfdia)))
      (setq np1 (list (car p1) (cadr p1) (- (+ elev1 vertOffset) halfdia)))
      (vlax-invoke-method pipe 'SetStartAndEndPoints (vlax-3d-point np0) (vlax-3d-point np1))
      (setq output T)
      )
    (setq output nil)
    )
  output
  )

Are you able to modify the PipeToSurface command (see my original post) to use one of the subroutines that I post here? 

---

Hello @hippe013 ,

Thank you for your help again.  I tried to combine 2nd subroutine and got the result. It works nicely. 

I have a little request that rather than picking surface levels from both ends of pipe it should pick surface elevation exactly from mid of pipe and adjust pipe middle level accordingly.

Hope you understand.

Thank you.

[hippe013]

I think that this latest request you should be able to complete. Feel free to ask if you have any questions. Also, feel free to mark of one the posts as a solution to your original question. The example code that I have provided should provide give you enough information as to how to complete your latest request. You might have questions about computing the midpoint between two points and I can help you with that. However, I am not here to fill people's code requests. I prefer that they learn to write to the code themselves. Let me know what questions you might have. 

Regards & Happy Coding!

[saqib_tipa]

Hi @hippe013 ,

Thank you for the reply. You are right we should learn to write the code. I have tried to learn its kind of hard to learn till now and I really appreciate you and all other who try to help and try to teach.

Please see my 7th post I was already requesting this before I just missed to tag you when I was requesting about center of pipe. Its not all new request and please I will be happy if you can manage it to work with middle of pipe and match top of the pipe to the surface we select.

Hope you can understand and yes I will surely mark them all as 'accept' it is always in my mind.

Thank you.

[hippe013 · Accepted solution]

In the example code that I have provided, we get and store the start and end points as P0 & P1. You want to get the middle point in between those two points. We need to get the angle in the XY plane between those two points. We also need to get the distance between those two points so that we can cut that distance in half. We then use the Polar function to compute the mid-point. 

;Lets create a copy of the two points as 2D points.
(setq p02d (list (car p0) (cadr p0) 0))
(setq p12d (list (car p1) (cadr p1) 0))

;Get the Angle between the two points
(setq ang (angle p02d p12d))

;Get the 2D Distance and cut the distance in half
(setq dist (/ (distance p02d p12d) 2.0))

;Compute the Mid-Point
(setq midPnt (polar p02d ang dist))

Now that you have the mid-point, you can use the code above to try and extract the surface elevation at that point. 

[saqib_tipa]

@hippe013 

Thank you for the reply. I will try to combine these codes to make it work as we need. I am not sure if I will manage it to compile. I understood that we just got that mid point where we want to extract elevation but don't understand completely where and what else should we change in previous provided code because of my limited knowledge of coding. But I will try and let you know by tomorrow. If I am unable to compile this code then will need your further assistance.

Thank you.

[hippe013]

Sounds good! I look forward to seeing what you come up with. 

[saqib_tipa]

---

@hippe013 wrote:

In the example code that I have provided, we get and store the start and end points as P0 & P1. You want to get the middle point in between those two points. We need to get the angle in the XY plane between those two points. We also need to get the distance between those two points so that we can cut that distance in half. We then use the Polar function to compute the mid-point. 

;Lets create a copy of the two points as 2D points.
(setq p02d (list (car p0) (cadr p0) 0))
(setq p12d (list (car p1) (cadr p1) 0))

;Get the Angle between the two points
(setq ang (angle p02d p12d))

;Get the 2D Distance and cut the distance in half
(setq dist (/ (distance p02d p12d) 2.0))

;Compute the Mid-Point
(setq midPnt (polar p02d ang dist))

Now that you have the mid-point, you can use the code above to try and extract the surface elevation at that point. 

---

Hello @hippe013,

I tried for a long time to combine the codes but unfortunately could not make a final working Lisp, as I am not much knowledge of what code should go before or after or what needs to be changed because of new code. I know it's messed up. I tried to change few things but could not manage it. Please combine those codes so that it can work correctly.

Thank you.

(defun c:PipeToSurface ( / surfSS surf pipeSS pipe success)
  (princ "\nSelect Surface: ")
  (setq surfSS (ssget ":s+." '(( 0 . "AECC_TIN_SURFACE"))))
  (if surfSS
    (progn
      (setq surf (vlax-ename->vla-object (ssname surfSS 0)))
      (while (setq pipeSS (ssget ":s+." '(( 0 . "AECC_PIPE"))))
	(setq pipe (vlax-ename->vla-object (ssname pipeSS 0)))
	(setq success (SetPipeTopToSurface pipe surf 0.000))
	(if success
	  (princ "\nPipe Inverts have been set to surface.")
	  (princ "\nPipe Mid not lay on surface.")
	  )
	)
      )
    )
  (princ)
  )


    
  


;SetPipeTopToSurface - Sets Pipes Mid Top Points onto a surface with a given vertical offset.
;Returns (T) if both points lay on the Surface                                              
;Returns (nil) if one or both of the end points do not lay on a surface.                    
;Example: (setq success (SetPipeTopToSurface pipeObject surfaceObject 0.00))            
(defun SetPipeTopToSurface (pipe surf vertOffset / p0 p1 p02d p12d halfdia args0 elev0 output)
  (setq p0 (vlax-safearray->list (vlax-variant-value (vlax-get-property pipe 'PointAtParam 0))))
  (setq p1(vlax-safearray->list (vlax-variant-value (vlax-get-property pipe 'PointAtParam 1))))
  (setq halfDia (/ (vlax-get-property pipe 'OuterDiameterOrWidth) 2.0))
   ;--------------------------------
  ;Try and get the Surface Elevation at MidPoint
  (setq args0 (list surf 'FindElevationAtXY (car p0) (cadr p0)))
  (setq elev0 (vl-catch-all-apply 'vlax-invoke-method args0))

;Lets create a copy of the two points as 2D points.
(setq p02d (list (car p0) (cadr p0) 0))
(setq p12d (list (car p1) (cadr p1) 0))

;Get the Angle between the two points
(setq ang (angle p02d p12d))

;Get the 2D Distance and cut the distance in half
(setq dist (/ (distance p02d p12d) 2.0))

;Compute the Mid-Point
(setq midPnt (polar p02d ang dist))

 ;--------------------------------
  ;Proceed only if Mid of pipe lay on a surface
  (if (and (not(vl-catch-all-error-p elev0)))
    (progn
      (setq nmidPnt (list (car midPnt) (cadr midPnt) (- (+ elev0 vertOffset) halfdia)))
      (vlax-invoke-method pipe 'SetStartAndEndPoints (vlax-3d-point nmidPnt))
      (setq output T)
      )
    (setq output nil)
    )
  output
  )

[hippe013 · Accepted solution]

It looks like you are trying to get the elevation from the surface from the end points and then computing the midpoint. You will need to compute this mid-point first and then place that into the arguments for the surface elevation. 

;Lets create a copy of the two points as 2D points.
(setq p02d (list (car p0) (cadr p0) 0))
(setq p12d (list (car p1) (cadr p1) 0))

;Get the Angle between the two points
(setq ang (angle p02d p12d))

;Get the 2D Distance and cut the distance in half
(setq dist (/ (distance p02d p12d) 2.0))

;Compute the Mid-Point
(setq midPnt (polar p02d ang dist))

;Try and get the Surface Elevation at MidPoint
(setq args0 (list surf 'FindElevationAtXY (car midPnt) (cadr midPnt)))
(setq elev0 (vl-catch-all-apply 'vlax-invoke-method args0))

I hope that this helps clarify things for you. 

[saqib_tipa]

---

@hippe013 wrote:

It looks like you are trying to get the elevation from the surface from the end points and then computing the midpoint. You will need to compute this mid-point first and then place that into the arguments for the surface elevation. 

;Lets create a copy of the two points as 2D points.
(setq p02d (list (car p0) (cadr p0) 0))
(setq p12d (list (car p1) (cadr p1) 0))

;Get the Angle between the two points
(setq ang (angle p02d p12d))

;Get the 2D Distance and cut the distance in half
(setq dist (/ (distance p02d p12d) 2.0))

;Compute the Mid-Point
(setq midPnt (polar p02d ang dist))

;Try and get the Surface Elevation at MidPoint
(setq args0 (list surf 'FindElevationAtXY (car midPnt) (cadr midPnt)))
(setq elev0 (vl-catch-all-apply 'vlax-invoke-method args0))

I hope that this helps clarify things for you. 

---

Hello @hippe013,

Thank you for the reply, when I saw your reply and you just posted the partial code I thought it will now take months to finalize my requested code because of me not having enough knowledge of these codes. I tried again for a long time to compile it and see what mistakes are there in my last compiled code. I saw I have changed and removed last part where we have to give start and end invert levels which we have taken from surface at pipe middle point. Before I thought that we have to give that level at pipe middle only but then realized there is no such thing pipe middle level in civil3d. Then I tried few more changing and at last I got the code I was looking for.

Thanks to you for your codes and helping me to understand these things.  It will save my time from manually inputting levels of pipes.

But please remember I really don't know that much of these codes if I have to built this kind of code from scratch I really can't because I don't know how to start what coding, arguments and commands are needed to built that code.

Thank you so much again for your time and help.

[hippe013]

Excellent! I am happy that you were able to figure out what changes that you needed to make. 

Learning how to code in LISP, or any other programming language, can be challenging and time consuming. However, it can be very rewarding once you do learn, as you can then automate these tedious tasks. There are many people on these forums that are more than willing to help with any questions that you may have.

Would you be willing to post your final code for others to see? 

[saqib_tipa]

Hello @hippe013 ,

Thank you, I wish I could learn coding and make Lisps for me and others, but I am still in learning phase and for some people it is difficult to learn this Lisp language fast and I am one from them. But always try to learn. You are right it is very useful in daily working tasks to make them automate. 

I really respect and appreciate those people wo always try to help others.

Yes, why not it's all your code and I just compiled it.

Thank you.

(defun c:PipeToSurface ( / surfSS surf pipeSS pipe success)
  (princ "\nSelect Surface: ")
  (setq surfSS (ssget ":s+." '(( 0 . "AECC_TIN_SURFACE"))))
  (if surfSS
    (progn
      (setq surf (vlax-ename->vla-object (ssname surfSS 0)))
      (while (setq pipeSS (ssget ":s+." '(( 0 . "AECC_PIPE"))))
	(setq pipe (vlax-ename->vla-object (ssname pipeSS 0)))
	(setq success (SetPipeTopToSurface pipe surf 0.000))
	(if success
	  (princ "\nPipe Inverts have been set to surface.")
	  (princ "\nPipe Mid not lay on surface.")
	  )
	)
      )
    )
  (princ)
  )


;SetPipeTopToSurface - Sets Pipes Mid Top Points onto a surface with a given vertical offset.
;Returns (T) if both points lay on the Surface                                              
;Returns (nil) if one or both of the end points do not lay on a surface.                    
;Example: (setq success (SetPipeTopToSurface pipeObject surfaceObject 0.00))            
(defun SetPipeTopToSurface (pipe surf vertOffset / p0 p1 p02d p12d halfdia args0 elev0 midPnt output)
  (setq p0 (vlax-safearray->list (vlax-variant-value (vlax-get-property pipe 'PointAtParam 0))))
  (setq p1 (vlax-safearray->list (vlax-variant-value (vlax-get-property pipe 'PointAtParam 1))))
  (setq halfDia (/ (vlax-get-property pipe 'OuterDiameterOrWidth) 2.0))
;Lets create a copy of the two points as 2D points.
(setq p02d (list (car p0) (cadr p0) 0))
(setq p12d (list (car p1) (cadr p1) 0))

;Get the Angle between the two points
(setq ang (angle p02d p12d))

;Get the 2D Distance and cut the distance in half
(setq dist (/ (distance p02d p12d) 2.0))

;Compute the Mid-Point
(setq midPnt (polar p02d ang dist))

;Try and get the Surface Elevation at MidPoint
(setq args0 (list surf 'FindElevationAtXY (car midPnt) (cadr midPnt)))
(setq elev0 (vl-catch-all-apply 'vlax-invoke-method args0))

  ;Proceed only if Mid of pipe lay on a surface
  (if (and (not(vl-catch-all-error-p elev0)))
    (progn
      (setq np0 (list (car p0) (cadr p0) (- (+ elev0 vertOffset) halfdia)))
      (setq np1 (list (car p1) (cadr p1) (- (+ elev0 vertOffset) halfdia)))
      (vlax-invoke-method pipe 'SetStartAndEndPoints (vlax-3d-point np0) (vlax-3d-point np1))
      (setq output T)
      )
    (setq output nil)
    )
  output
  )

 (This is working for me, but if there any errors you may point them)