AutoCAD - Belirli aralıklarda nokta ile çember çizimi

[m_balta9HQBH]

Merhaba.

Belirli bir aralıkta belirli sayıda nokta ile nasıl çember yapabilirim.

Örneğin;

0,5 mm aralıklarla 350 adet nokta kullanarak çember oluşturmak istiyorum.

ya da 

20 cm çapında çemberi nokta aralıklarından bağımsız 350 nokta ile oluşturmak istiyorum.

Teşekkürler.

@m_balta9HQBH , konu başlığı daha anlaşılır olması için @Olcay.Kuk tarafından düzenlendi. Önceki başlık "Belirli aralıklarda nokta ile çember çizimi"

[Mesut_Akcan · Accepted solution]

1) ARRAYPOLAR komutu ile yapılabilir

2) VBA kodlaması ile yapılabilir. Benzer işi yapan kod: https://youtu.be/j8toU9Jzj_g

3) AutoLisp kodları ile yapılabilir.

[Mesut_Akcan]

VBA kodu isteğinize uygun uyarladım.

Sub Noktalarla_Cember()
'Belirtilen nokta sayısı ve yarıçap ile noktadan oluşan çember
'Mesut Akcan
'19/7/2023
'mesutakcan.blogspot.com

Dim cizgi As AcadLine
Dim ut As AcadUtility
Dim ms As AcadModelSpace
Const pi = 3.14159265358979
Set ut = ThisDrawing.Utility
Set ms = ThisDrawing.ModelSpace

On Error GoTo hata:
'aktifrenk = ThisDrawing.GetVariable("CECOLOR")
With ut
    ks = .GetInteger("Nokta sayısı:")
    m = .GetPoint(, "Merkez nokta:")
    r = .GetDistance(m, "Yarıçap:")
    dilim = 2 * pi / ks 'radyan
    For k = 1 To ks
        aci = k * dilim
        kn = .PolarPoint(m, aci, r)
        Set p = ms.AddPoint(kn)
        'p.color = acGreen
    Next
End With
'ThisDrawing.SetVariable "CECOLOR", aktifrenk
Exit Sub
hata:
If ThisDrawing.GetVariable("LASTPROMPT") Like "*Cancel*" Then
    Exit Sub
Else
    ut.Prompt "Bir hata oluştu!"
End If
End Sub

[m_balta9HQBH]

Teşekkür ederim çok işime yaradı. Buna ilave olarak bi sorum daha var yardımcı olursanız memnun olurum.

Çemberin etrafına istediğim aralıklarda noktaları yerleştirdim. Şimdi bunları seri bir şekilde numaralandırmak istiyorum. noyaz adında bir lisp var fakat bunda her yeni numara için tıklamam gerekiyor. 350 sayı seri bir şekilde numaralandırılabilir mi?

[Mesut_Akcan]

isteğinize uygun VBA kodu:

Sub Noktalarla_Cember_2()
'Belirtilen nokta sayısı ve yarıçap ile noktadan oluşan çember
'Nokta yanına çember içinde sıra numarasını yazar

'Mesut Akcan
'19/7/2023
'mesutakcan.blogspot.com

Dim ut As AcadUtility
Dim ms As AcadModelSpace
Dim no As AcadText
Const pi = 3.14159265358979
Set ut = ThisDrawing.Utility
Set ms = ThisDrawing.ModelSpace

On Error GoTo hata:
yy = ThisDrawing.GetVariable("TEXTSIZE") 'yazı yüksekliği
With ut
    ns = .GetInteger("Nokta sayısı:")
    m = .GetPoint(, "Merkez nokta:")
    r = .GetDistance(m, "Yarıçap:")
    dilim = 2 * pi / ns 'dilim açısı. radyan
    For k = 1 To ns
        aci = k * dilim
        nk = .PolarPoint(m, aci, r) 'nokta konumu
        mk = .PolarPoint(m, aci, 2 * yy + r) 'çerçeve merkez konumu
        yg = Len(k) 'yazı genişliği
        Set p = ms.AddPoint(nk) 'nokta ekle
        Set c = ms.AddCircle(mk, yy * Len(ns) / 2) 'çember çiz
        Set no = ms.AddText(k, mk, yy) 'numara yaz
        no.Alignment = acAlignmentMiddleCenter 'ortaya yasla
        no.TextAlignmentPoint = mk 'yaslama noktası
    Next
End With
Exit Sub
hata:
'ESC basıldıysa
If ThisDrawing.GetVariable("LASTPROMPT") Like "*Cancel*" Then
    Exit Sub
Else
    ut.Prompt "Bir hata oluştu!"
End If
End Sub

[serkancavuslar]

@m_balta9HQBH Merhaba,

Bu işlemi AutoCAD ve AutoCAD LT ile yapabilmek için,

Komut Satırına ptype ile nokta stilinizi belirleyin,
Çemberinizi Çizin
divide komutu ile çemberinizi seçin ve 350 yazın,