Communauté
AutoCAD – tous produits - Français
Bienvenue sur les forums AutoCAD d’Autodesk. Partagez vos connaissances, posez des questions, et explorez les sujets AutoCAD populaires.
annuler
Affichage des résultats de 
Afficher  uniquement  | Rechercher plutôt 
Vouliez-vous dire : 

AutoCAD : Style de lignes

3 RÉPONSES 3
RÉSOLU
Répondre
Message 1 sur 4
techniquedessin54
205 Visites, 3 Réponses

AutoCAD : Style de lignes

IMG_0340.png

Bonjour,

 

j’aurais voulu savoir comment créer ce style de ligne en noir et blanc sur autocad s’il vous plaît ? 

merci 

IMG_0337.jpeg


Le titre du sujet a été modifié par un modérateur pour faciliter la recherche. Titre original:
Style de lignes

3 RÉPONSES 3
Message 2 sur 4
tramber
en réponse à: techniquedessin54

Compliqué d'intégrer les deux.... même dans les vieilles fonctions Multilignes.

Néanmoins le pointillé large est possible en jouant avec la largeur de polyligne. La largeur n'étant pas l'épaisseur.

La largeur étant un concept intégré à la polyligne, il y a l'option LArgeur ou Demie-largeur, qu'il suffit de régler une fois (puis une autre pour revenir à zéro) en exécutant la commande. PLINEWIDTH gérant cette valeur.

On rappelle qu'il est toujours possible de gérer cette largeur dans les propriétés.

Message 3 sur 4

Bonjour,

Je peux te proposer un type de ligne approchant.

Pour ce faire, il te suffit de copier-coller le code suivant DIRECTEMENT dans la ligne de commande d'Autocad. (valider éventuellement la copie par "entrée")

Ce code vas se charger de définir le style de texte nécessaire au type de ligne, écrire le fichier "transport.lin" et charger celui-ci dans le dessin pour qu'il soit disponible.

((lambda ( / f_lin doc)
  (if (not (tblsearch "STYLE" "TRANSPORT"))
    (entmakex
      '(
        (0 . "STYLE")
        (100 . "AcDbSymbolTableRecord")
        (100 . "AcDbTextStyleTableRecord")
        (2 . "TRANSPORT")
        (70 . 0)
        (40 . 0.0)
        (41 . 1.0)
        (50 . 0.0)
        (71 . 0)
        (42 . 1.0)
        (3 . "ARIAL.TTF")
        (4 . "")
       )
    )
  )
  (entmake
    (list
      '(0 . "LTYPE")
      '(100 . "AcDbSymbolTableRecord")
      '(100 . "AcDbLinetypeTableRecord")
      '(2 . "TRANSPORT")
      '(70 . 0)
      '(3 . "alterné")
      '(72 . 65)
      '(73 . 3)
      '(40 . 1.287)
      '(49 . 0.0)
      '(74 . 2)
      '(75 . 0)
      (CONS 340 (TBLOBJNAME "STYLE" "TRANSPORT"))
      '(46 . 1.0)
      '(50 . 0.0)
      '(44 . -0.595)
      '(45 . -0.3215)
      '(9 . "■")
      '(49 . -0.6435)
      '(74 . 2)
      '(75 . 0)
      (CONS 340 (TBLOBJNAME "STYLE" "TRANSPORT"))
      '(46 . 1.0)
      '(50 . 0.0)
      '(44 . -0.595)
      '(45 . -0.3215)
      '(9 . "□")
      '(49 . -0.6435)
      '(74 . 0)
    )
  )
  (if (not (findfile "transport.lin"))
    (progn
      (setq f_lin (open (strcat (getvar "ROAMABLEROOTPREFIX") "support\\transport.lin") "w"))
      (write-line "*TRANSPORT,alterné" f_lin)
      (write-line "A,0,[\"\\U+25A0\",TRANSPORT,S=1,R=0,X=-0.595,Y=-0.3215],-0.6435,[\"\\U+25A1\",TRANSPORT,S=1,R=0,X=-0.595,Y=-0.3215],-0.6435" f_lin)
      (close f_lin)
    )
  )
  (setq doc (vla-get-activedocument (vlax-get-acad-object)))
  (if
    (and
      (not
        (vlax-for item (vla-get-linetypes doc)
          (if (= (strcase (vla-get-name item)) (strcase "transport")) T)
        )
      )
      (vl-catch-all-error-p
        (vl-catch-all-apply
          'vla-load
          (list (vla-get-Linetypes doc) "TRANSPORT" "transport.lin")
        )
      )
    )
    nil
    T
  )
  (princ "\nCréation de Type de Ligne \"TRANSPORT\" effectué!")
  (prin1)
))
Message 4 sur 4
braudpat
en réponse à: techniquedessin54

Hello

 

OUI bien joue Bruno !

En utilisant certains caracteres graphiques et/ou Polices speciales, on peut arriver a faire des trucs !

Voir image jointe ...

 

Bye, Pat

 

Patrice ( Supporting Troops ) - Autodesk Expert Elite
If you are happy with my answer please mark "Accept as Solution" and if very happy please give me a Kudos (Felicitations) - Thanks

Patrice BRAUD

EESignature


Vous n'avez pas trouvé ce que vous recherchiez ? Posez une question à la communauté ou partagez vos connaissances.

Publier dans les forums  

Autodesk Design & Make Report