Salut,
Depuis l'arrivée des objets "fond de plan" (PDF, DWF, DGN) et de la palette "Références externes", il règne une grande confusion avec l'appellation "xref" dans laquelle on a tendance à regrouper les "xrefs" stricto-sensu, les images raster et les "fonds de plans".
Or en programmation on a besoin d'une plus grande rigueur.
Au sens strict, une "xref" est un fichier DWG insérés dans le dessin comme référence externe, c'est une variété de référence de bloc (nom DXF : "INSERT").
Une image est une "image raster" (nom DXF : "IMAGE").
Un fichier PDF, DWF, DGN inséré est appelé un fond de plan ou underlay (noms DXF "PDFUNDERLAY", "DWFUNDERLAY", "DGNUNDERLAY").
Ce sachant, on peut récupérer le "nom" de la "référence externe" en fonction de son type :
(defun xrefName (ename / elst dxfName)
(setq elst (entget ename)
dxfName (cdr (assoc 0 elst))
)
(cond
((= dxfName "INSERT")
(getpropertyvalue ename "BlockTableRecord/Name")
)
((= dxfName "IMAGE")
(getpropertyvalue ename "ImageName")
)
((member dxfName
'("PDFUNDERLAY" "DWFUNDERLAY" "DGNUNDERLAY")
)
(getpropertyvalue ename "DefinitionId/Name")
)
)
)
Exemple d'utilisation :
(defun c:test (/ ent name)
(if (setq ent (car (entsel)))
(if (setq name (xrefName ent))
(alert name)
(alert "Pas une xref")
)
)
(princ)
)
La routine 'xrefName' ci-dessus renvoie le nom de la "référence externe" tel qu'affiché dans la palette.
Pour avoir juste le nom du fichier source sans l'extension on peut utiliser celle-ci :
(defun xrefName (ename / elst dxfName)
(setq elst (entget ename)
dxfName (cdr (assoc 0 elst))
)
(cond
((= dxfName "INSERT")
(vl-filename-base (cdr (assoc 1 (tblsearch "block" (cdr (assoc 2 elst))))))
)
((member dxfName '("IMAGE" "PDFUNDERLAY" "DWFUNDERLAY" "DGNUNDERLAY"))
(vl-filename-base (cdr (assoc 1 (entget (cdr (assoc 340 elst))))))
)
)
)
La fonction dumpallproperties affiche, dans la fenêtre de texte, toutes les propriétés pour l'entité/object (ENAME)qui lui est passé en argument.
