Script pour fermer une polyligne

[Anonymous]

Bonjour à tous!

Je ne sais pas vous, mais moi je n'aime pas que mes polylignes ne soient pas fermées!

Alors je me demandais s'il existait un script pour fermer une polyligne rapidement, plutôt que de passer par les propriétés...

D'avance merci!

Stéphane,

[_gile · Accepted solution]

Salut,

N'étant pas sûr de ce que tu entends par "script" (j'imagine que tu ne fais pas référence aux scrpts AutoCAD : fichiers .scr qu'on lance avec la commande SCRIPT), je te propose plusieures solutions.

Une macro de commande à affecter à un bouton (icone) ou un menu via le CUI :

^C^C_pedit;\_close;;

 Un LISP simplissime (identique à la macro ci-dessus) qui définit une commande : CLPL

(defun c:CLPL ()
  (command "_.pedit" pause "_close" "")
  (princ)
)

 Un autre LISP un peu plus élaboré qui permet une sélection de plusieurs polylignes

(defun c:CLPL (/ ss n elst)
  (if (setq ss (ssget '((0 . "*POLYLINE"))))
    (repeat (setq n (sslength ss))
      (setq elst (entget (ssname ss (setq n (1- n)))))
      (entmod
	(subst
	  (cons 70 (Boole 7 (cdr (assoc 70 elst)) 1))
	  (assoc 70 elst)
	  elst
	)
      )
    )
  )
  (princ)
)

[Anonymous]

Bravo, et surtout merci!!!

C'est exactement ce que je voulais.

Bonne soirée à toi!