Palette - Polyligne avec largeur global
Bonjour,
Pour gérer cela, je pense qu'il faut plutôt utiliser une macro de type :
^C^Cplinewid;10;-calque;etablir;"moncalque";;polyligne;
Salut @La_Lozère,
Tu peux regarder du côté de cet article : https://www.autodesk.com/support/technical/article/caas/sfdcarticles/sfdcarticles/Drawing-polyline-o...
Olivier Eckmann
Bonjour Olivier,
Merci pour le lien. Si j'ai bien compris, cela sauvegarde la valeur de plinewid dans la variable pwid et la restaure à la fin.
Ca correspond à peu près à ce que je veux, mais cela ne me dessine pas la polyligne dans le calque spécifié mais dans le calque courant.
Voici la définition de ma commande dans la palette :
Normalement la polyligne devrait se dessiner dans le calque RECEP_ASS_ENT, mais non...
Je vais essayer de présenter les choses de manière un peu plus globale.
J'ai un fichier avec des calques existant, eux-même avec des définitions de type de ligne, couleur, épaisseur, etc. spécifique. Dans ce fichier, je créais un bout de polyligne dans un calque choisi. Je fais un glissé déposé dans ma palette, se qui fait que je me retrouve avec une commande de polyligne qui permet, dans n'importe quel fichier, de dessiner une polyligne qui sera dans le bon calque, et le-dis calque avec les bonnes propriétés. Et même la possibilité d'avoir une liste déroulante de commandes (polyligne, cercle, arc, ligne, etc.). Mais ça je peux m'en passer car je veux une polyligne. Et jusque là, tout va bien, sauf que cette méthode ne permet pas de récupérer la largeur globale que j'aurais pu donner à mon bout de polyligne ayant servi de référence.
En appliquant ta solution Olivier, la poyligne a bien l'épaisseur voulue, mais pas dans le bon calque (et donc pas les bonne caractéristiques de couleur, type de ligne, etc.).
En reprenant le fil de discussion, on peut s’appuyer sur la réponse de @O_Eckmann basée sur l’article Autodesk :
https://www.autodesk.com/support/technical/article/caas/sfdcarticles/sfdcarticles/Drawing-polyline-o...
L’idée ici est de transformer cet exemple réduit à une seule ligne en une nouvelle commande AutoLISP à charger (ex. : EDPS_POLYLIGNE), afin d’obtenir une commande dédiée et réutilisable.
;;; https://www.autodesk.com/support/technical/article/caas/sfdcarticles/sfdcarticles/Drawing-polyline-of-specified-width-without-changing-global-PLINEWID-value.html
;; ^C^C(setq pwid (getvar "plinewid"));plinewid;<desired width>;_pline;(while (> (getvar "cmdactive") 0) (command pause))(setvar "plinewid" pwid)
;;; ------------------------------------------------------------------------
;;; Commande : EDPS_POLYLIGNE
;;; Objectif :
;;; Dessiner une polyligne avec une largeur spécifique
;;; sans modifier durablement la variable système PLINEWID
;;;
;;; Principe :
;;; - Sauvegarder la valeur courante de PLINEWID
;;; - Forcer temporairement une largeur donnée
;;; - Lancer la commande PLINE en mode interactif
;;; - Attendre la fin de la commande utilisateur
;;; - Restaurer la valeur initiale de PLINEWID
;;; ------------------------------------------------------------------------
(defun c:edps_polyligne (/ pwid)
;;; Récupération et sauvegarde de la largeur globale actuelle des polylignes
;;; PLINEWID est une variable système AutoCAD
(setq pwid (getvar "plinewid"))
;;; Définition temporaire de la largeur de polyligne
;;; Valeur exprimée dans l’unité du dessin (ici 10)
(setvar "plinewid" 10)
;;; Lancement de la commande PLINE en version internationale
;;; L’utilisateur dessine la polyligne de manière interactive
(command "_.pline")
;;; Boucle d’attente :
;;; Tant que la commande PLINE est active,
;;; on laisse AutoCAD attendre une action utilisateur (clic, entrée, ESC…)
(while (> (getvar "cmdactive") 0)
(command pause)
)
;;; Restauration de la largeur initiale des polylignes
;;; Évite tout effet de bord sur les futures commandes PLINE
(setvar "plinewid" pwid)
;;; Fin propre de la fonction
(princ)
)Pour avoir le bon calque de création, il suffit de définir, dans l’outil de la palette, le calque souhaité selon le besoin.
La macro : ^C^CEDPS_POLYLIGNE
Variante intéressante (amélioration possible)
On peut facilement faire évoluer le LISP pour demander la largeur au moment de l’appel, en passant un paramètre via une macro.
Exemples de macros :
-
^C^CEDPS_POLYLIGNE;10 -
^C^CEDPS_POLYLIGNE;20
Dans ce cas, on obtient une commande unique, mais paramétrable selon le besoin (10, 20, etc.).
À noter : cette approche fonctionne également sous AutoCAD LT 2024 et versions ultérieures.
Industrialisation AutoCAD / AutoCAD LT – 2D / 3D
Architectures AutoLISP & .NET maintenables
Références industrielles, notamment AutoCAD Electrical
(contexte exigeant, architectures éprouvées)
Blog : Trucs & Astuces sur AutoCAD LT (2024+)
Bonjour @La_Lozère ,
Si tu veux fixer le calque, soit tu l'ajoutes au début de ta macro
^C^C-calque;E;<Mon Camque>;;(setq pwid (getvar "plinewid"));plinewid;<Largeur>;_pline;(while (> (getvar "cmdactive") 0) (command pause))(setvar "plinewid" pwid)Par exemple pour une largeur de 0.5 dans le calque RECEP_ASS_ENT, on écrit
^C^C-calque;E;RECEP_ASS_ENT;;(setq pwid (getvar "plinewid"));plinewid;0.5;_pline;(while (> (getvar "cmdactive") 0) (command pause))(setvar "plinewid" pwid)
Soit tu repars de ce que propose @didier_lourdelle , avec une fonction plus générique qui passe le calque et l'épaisseur en paramètre
;;; https://www.autodesk.com/support/technical/article/caas/sfdcarticles/sfdcarticles/Drawing-polyline-of-specified-width-without-changing-global-PLINEWID-value.html
;; ^C^C(setq pwid (getvar "plinewid"));plinewid;<desired width>;_pline;(while (> (getvar "cmdactive") 0) (command pause))(setvar "plinewid" pwid)
;;; ------------------------------------------------------------------------
;;; Commande : (poly_lozere Calque Largeur)
;;; par exemple (poly_lozere "RECEP_ASS_ENT" 0.5)
;;; Objectif :
;;; Dessiner une polyligne avec une largeur spécifique dans un calque spécifique
;;; sans modifier durablement la variable système PLINEWID
;;;
;;; Principe :
;;; - Sauvegarder la valeur courante de PLINEWID
;;; - Sauvegarder le calque courant
;;; - Forcer temporairement une largeur donnée
;;; - Lancer la commande PLINE en mode interactif
;;; - Attendre la fin de la commande utilisateur
;;; - Restaurer la valeur initiale de PLINEWID
;;; - Restaurer l'ancien calque courant
;;; ------------------------------------------------------------------------
(defun poly_lozere (sCalque dLargeur / sOldLayer dOldPwid)
;;; Récupération et sauvegarde de la largeur globale actuelle des polylignes
;;; PLINEWID est une variable système AutoCAD
(setq dOldPwid (getvar "plinewid"))
;;; Définition temporaire de la largeur de polyligne
;;; Valeur exprimée dans l’unité du dessin (ici 10)
(setvar "plinewid" (max 0.0 dLargeur))
;;; sauvegarde le calque courant
(setq sOldLayer (getvar "CLAYER"))
;;; Rend le calque courant
(command "_.-layer" "_m" sCalque "")
;;; Lancement de la commande PLINE en version internationale
;;; L’utilisateur dessine la polyligne de manière interactive
(command "_.pline")
;;; Boucle d’attente :
;;; Tant que la commande PLINE est active,
;;; on laisse AutoCAD attendre une action utilisateur (clic, entrée, ESC…)
(while (> (getvar "cmdactive") 0)
(command pause)
)
;;; Restauration de la largeur initiale des polylignes
;;; Évite tout effet de bord sur les futures commandes PLINE
(setvar "plinewid" dOldPwid)
;;; restaure l'ancien calque courant
(setvar "CLAYER" sOldLayer)
;;; Fin propre de la fonction
(princ)
)Par exemple pour une largeur de 0.5 dans le calque RECEP_ASS_ENT, dans ta palette tu mets
^C^C(poly_lozere "RECEP_ASS_ENT" 0.5)
Olivier Eckmann
Salut à tous,
Toutes les solutions proposées sont franchement, super 👍🏻
Mais je ne suis pas sûr qu'elles répondent entièrement à ce que souhaiterais, @La_Lozère.
@La_Lozère a écrit :Le truc c'est qu'il faut, en fin de commande, rétablir plinewid à la valeur initiale (généralement 0).
Je vais fouiller...
En effet, lorsqu'on crée une polyligne depuis la palette d'outils, avec une largeur par défaut, ça modifie la variable système Plinewid. Par exemple, si l'outil polyligne de la palette; crée un polyligne avec une largeur de 0.5, la variable système Plinewid passe à 0.5. De ce fait, lorsqu'on souhaite créer une polyligne, ensuite, avec la commande classique, Polyligne, la nouvelle polyligne à une largeur par défaut de, 0.5, du fait que la variable système Plinewid est passée à 0.5, en créant la première polyligne, depuis la palette.
Or, il semblerait que, @La_Lozère, souhaiterais pouvoir créer une polyligne depuis la palette, avec une largeur de 0.5 et que la variable système, Plinewid se remette automatiquement, à 0, pour qu'ensuite, lorsqu'il souhaite, créer une polyligne, avec la commande classique, Polyligne, la variable de système, Plinewid, soit à 0, afin que la nouvelle polyligne soit toute fine.
C'est du moins comme ça, que j'ai compris la demande.
Ce post vous a été utile ? N'hésitez pas à aimer ce post.
Ce post a-t-il répondu à votre question ? Cliquez sur le bouton APPROUVER LA SOLUTION en dessous de la réponse.
« L’homme de bien n’exige pas de l’autre qu’il soit parfait, il l’aide à accomplir ce qu’il a en lui de meilleur. »
Lao Tseu
@reb_c2 a écrit :
Hello @La_Lozère,
suite aux remarques de @_Steven_, voici la Version 2 de la PALETTE D'OUTILS... (avec un dossier image cette fois-ci étant donné l'utilisation d'une icone PERSO !)...
j'ai simplement ajouté l'icone au début de la PALETTE, pour revenir sur la commande POLYLGIN avec une Epaisseur = 0.00
Christian
Salut Christian @reb_c2,
En espérant que @La_Lozère ne lance pas la commande Polyligne, au clavier.
L'idéal serait que la variable Plinewid de remette automatiquement à 0, afin de pouvoir lancer la commande, Polyligne, via le clavier ou le raccourcis, PO.
Il ne faut pas perdre de vue que les adeptes du clavier lancent la majorité des commandes, au clavier et n'utilisent les icônes ou les outils de palettes, que pour des besoins spécifiques 😉
Ce post vous a été utile ? N'hésitez pas à aimer ce post.
Ce post a-t-il répondu à votre question ? Cliquez sur le bouton APPROUVER LA SOLUTION en dessous de la réponse.
« L’homme de bien n’exige pas de l’autre qu’il soit parfait, il l’aide à accomplir ce qu’il a en lui de meilleur. »
Lao Tseu
Cette version tient compte de nos échanges ainsi que de ta vidéo.
Principe de la macro :
^C^CEDPS_POLYLIGNE;Largeur
^C^CEDPS_POLYLIGNE;10
^C^CEDPS_POLYLIGNE;30
Il est nécessaire de charger le fichier AutoLISP :
https://www.didier-lourdelle.fr/aide/chargement-des-programmes-autolisp/
C’est bien la palette d’outils qui se charge de créer le calque et d’appliquer correctement les propriétés.
À ce titre, la palette d’outils est quasi magique — à l’exception de la gestion de l’annotatif, qui n’est pas encore implémentée.
;;; Source Autodesk :
;;; https://www.autodesk.com/support/technical/article/caas/sfdcarticles/sfdcarticles/Drawing-polyline-of-specified-width-without-changing-global-PLINEWID-value.html
;;;
;;; Principe générique Autodesk :
;;; ^C^C
;;; (setq pwid (getvar "plinewid"))
;;; (setvar "plinewid" <largeur_souhaitee>)
;;; _pline
;;; (while (> (getvar "cmdactive") 0) (command pause))
;;; (setvar "plinewid" pwid)
;;;
;;; ------------------------------------------------------------------------
;;; Commande : EDPS_POLYLIGNE
;;;
;;; Objectif :
;;; Dessiner une polyligne avec une largeur spécifique
;;; sans modifier durablement la variable système PLINEWID.
;;;
;;; Principe de fonctionnement :
;;; - Sauvegarder la valeur courante de la variable système PLINEWID
;;; - Appliquer temporairement une largeur définie par l’utilisateur
;;; - Lancer la commande PLINE en mode interactif
;;; - Attendre la fin complète de la commande utilisateur
;;; - Restaurer la valeur initiale de PLINEWID
;;;
;;; Avantage :
;;; - Aucun effet de bord sur les futures polylignes
;;; - Respect de l’environnement utilisateur
;;; ------------------------------------------------------------------------
(defun c:edps_polyligne (/ pwid Epaisseur)
;;; Sauvegarde de la largeur globale actuelle des polylignes
;;; PLINEWID est une variable système AutoCAD (largeur par défaut)
(setq pwid (getvar "plinewid"))
;;; Demande à l’utilisateur de saisir l’épaisseur souhaitée
;;; La valeur est exprimée dans l’unité du dessin courant
(setq Epaisseur (getreal "\nChoisissez l'épaisseur de la polyligne : "))
;;; Application temporaire de la largeur saisie
(setvar "plinewid" Epaisseur)
;;; Lancement de la commande PLINE
;;; Utilisation du préfixe "_" pour garantir l’internationalisation
(command "_.pline")
;;; Boucle d’attente :
;;; Tant qu’une commande est active (cmdactive > 0),
;;; AutoCAD attend les entrées utilisateur (clics, Entrée, ESC, etc.)
(while (> (getvar "cmdactive") 0)
(command pause)
)
;;; Restauration de la largeur initiale des polylignes
;;; Garantit l’absence d’impact sur les commandes PLINE ultérieures
(setvar "plinewid" pwid)
;;; Fin silencieuse de la commande
(princ)
)
Industrialisation AutoCAD / AutoCAD LT – 2D / 3D
Architectures AutoLISP & .NET maintenables
Références industrielles, notamment AutoCAD Electrical
(contexte exigeant, architectures éprouvées)
Blog : Trucs & Astuces sur AutoCAD LT (2024+)
Salut @La_Lozère ,
Je ne comprends pas trop. Si tu as 50 types de représentation, il te faudra 50 boutons.
Que chacun lance la commande de base ou un lisp, je ne vois pas la différence ni la complexité.
La seule chose, c'est effectivement la création du calque qui se fait automatiquement si c'est une commande simple, et qui se fait par défaut si c'est un lisp.
Dans ce cas, il suffit d'un bouton pour charger tous les calques avec les bonnes couleurs, type de ligne, épaisseur ... depuis un DWG ou un gabarit.
A lancer une fois pour toute au début, ou bien après chaque purge.
Ca pourrait même être ajouté au lisp : si le calque de dessin n'existe pas, alors on charge tous les calques depuis un DWG (DWT) spécifique.
Sinon, vu que tu as Covadis, tu peux te faire une table de code avec tous les objets à dessiner puis tu lances Cov2D / Palette / Depuis une table de code et tu retrouves tous les objets dessinables directement paramétrés, prêt à l'emploi.
Olivier Eckmann
