Parabola en Visual Lisp

[alessiozavaldi]

Esiste  un comando che disegna una parabola?

Existe un comando que diseñe una parabola?

[joaquim.moral · Accepted solution]

Ciao Alessio @alessiozavaldi,

Grazie per aver partecipato alla comunità Autodesk.

A quale software ti riferisci per disegnare la parabola?

Grazie,

[alessiozavaldi]

ad uno script in visul lisp che mi crea una parabola o catenaria con dati di ingresso.

Un script en Visual LISP que me cree una parábola o una catenaria con datos de entrada.

[Edwin.Saez · Accepted solution]

@alessiozavaldi ,

Intenta con el siguiente lisp:

(defun c:PARABOLA (/ vert a f h k x x-min x-max y step pts)
  (setq vert (getpoint "\nEspecifica el vértice de la parábola: ")) ; (h k)
  (setq h (car vert))
  (setq k (cadr vert))

  (initget "Arriba Abajo")
  (setq dir (getkword "\nDirección de apertura [Arriba/Abajo]: "))

  (setq f (getreal "\nDistancia focal (f): "))
  (if (= dir "Abajo")
    (setq a (/ -1.0 (* 4.0 f)))
    (setq a (/ 1.0 (* 4.0 f)))
  )

  (setq x-min (- h 10.0))
  (setq x-max (+ h 10.0))
  (setq step 0.2)
  (setq x x-min)
  (setq pts '())

  (while (<= x x-max)
    (setq y (+ (* a (* (- x h) (- x h))) k))
    (setq pts (append pts (list (list x y 0.0))))
    (setq x (+ x step))
  )

  (entmakex
    (list
      '(0 . "LWPOLYLINE")
      (cons 100 "AcDbEntity")
      (cons 100 "AcDbPolyline")
      (cons 90 (length pts)) ; Número de vértices
      (cons 70 0) ; No cerrado
      (append
        (mapcar (function (lambda (pt) (list 10 (car pt) (cadr pt)))) pts)
      )
    )
  )
  (princ "\nParábola creada.")
  (princ)
)

[calderg1000 · Accepted solution]

Saludos @alessiozavaldi 

Hice unos pequeños cambios a la rutina presentado por el compañero @Edwin.Saez 

Espero que te pueda ser de ayuda...

(defun c:PARABOLA (/ vert a f h k x x-min x-max y step pts)
  (setq vert (getpoint "\nEspecifica el vértice de la parábola: ")
        h    (car vert)
        k    (cadr vert)
        f    (getreal "\nDistancia focal (f): ")
  )
  (initget "Arriba aBajo")
  (setq dir (getkword "\nDirección de apertura:Arriba/aBajo [A/B]: "))
  (if (= dir "aBajo")
    (setq a (/ -1.0 (* 4.0 f)))
    (setq a (/ 1.0 (* 4.0 f)))
  )
  (setq x-min (- h 10.0)
        x-max (+ h 10.0)
        step  0.2
        x     x-min
        pts   '()
  )
  (while (<= x x-max)
    (setq y (+ (* a (* (- x h) (- x h))) k))
    (setq pts (append pts (list (list x y 0.0))))
    (setq x (+ x step))
  )
  (entmakex (append
              (list
                '(0 . "LWPOLYLINE")
                (cons 100 "AcDbEntity")
                (cons 100 "AcDbPolyline")
                (cons 90 (length pts))           
                (cons 70 0)                     
              )
              (mapcar '(lambda (pt) (cons 10 pt)) pts)
            )
  )
  (princ "\n1 Parábola creada.")
  (princ)
)

[Valentin_CAD]

@alessiozavaldi ,

Estos enlaces también pueden ayudar:

• Cómo dibujar parábolas en AutoCAD

• TL Parabola | AutoCAD | Autodesk App Store

• CAD Forum - Parabola - true spline parabola, two methods (LSP LISP for AutoCAD)

[arturopolanco]

Hola @alessiozavaldi 

Es util tambien para nosotros tener una idea de para que la quieres usar.

Por ejemplo puede ser para redes de transmision electrica.

En estos casos hemos tenido algunos hilos aqui en el foro que explican este proceso:

https://forums.autodesk.com/t5/autocad-todos-los-productos-foro/dibujo-de-parabola/td-p/6321866

Por otro lado, lo mas comun es usar alguna aplicacion para estos fines, como son 

• JTB Catenary → https://jtbworld.com/catenary-for-autocad
• DLTCAD → https://dlt-cad.com/

Pero si eliges usar la opcion de crear un LISP tambien es util conocer las fórmulas matemáticas para calcular las coordenadas de puntos que definen la curva de la catenaria.

Mas detalles aqui: 

http://www.sc.ehu.es/sbweb/fisica/solido/din_rotacion/catenaria/catenaria.htm

Espero que esta informacion sea de utilidad.