Make dwl visible when opening a dwg

[salbrechtJHHCV]

Anyone have a way to make dwl files visible in ACAD open dwg dialog box... then I could see if somethings open before opening.  Why?  Well, because I use dropbox & don't want to view them in explorer every open.

Thanks all :o)

[paullimapa]

Since AutoCAD’s open file window only shows supported file types like dwg and dxf, it won’t be able to show any other unsupported file types. 
Also you may want to invest in alternative online services that support dwg file locking 

[rkmcswain · Accepted solution]

Sure - in the file dialog box, in the "File name" field, type in *.* and tap the Enter key.

You'll see ALL files including .dwl

FYI: Neither the presence or absence of the .dwl and .dwl2 files is a valid indication that a file is in use.

[pendean]

@salbrechtJHHCV Since you need to use DropBox with others for file sharing, explore options like https://dropbox.tech/developers/file-locking-using-the-dropbox-api
and https://protekitsolutions.com/how-to-properly-handle-files-in-dropbox-to-prevent-duplicate-or-confli...
PLUS you can always purchase 3rd party tools like https://toolbox.easeus.com/file-lock-tips/password-protect-dropbox-folder.html#:~:text=Method%202.%2... (I am not affiliated with them in any way, just one of a few options out there)

[salbrechtJHHCV]

Well I'll be dipped... just (1) asterisk and a quick enter & - Whoop there it is!  Not trying to tell anyone to use this method.  But this will be useful for me how I operate.

Thank you!

[paullimapa]

if you're interested in running a lisp function OPN that replaces AutoCAD's OPEN window with one that by default lists all filetypes with *.dw?:

; OPN replaces AutoCAD's Select Open window with another that initially shows files with *.dw? extensions
; OP:
; https://forums.autodesk.com/t5/autocad-forum/make-dwl-visible-when-opening-a-dwg/m-p/12280372
(defun c:opn (/ aec_openp fil)
 ;;;--- aec_openp function
; checks to see if file is open already by another program
; returns T if file is opened or read-only 
; https://forums.augi.com/showthread.php?6102-Detect-Read-Only-file-attribute&highlight=open
; Usage:
; (aec_openp (strcat(getvar"dwgprefix")(getvar"dwgname")))
; Returns:
; T
; Usage:
; (aec_openp "C:\\Autodesk\\Floor Plan Sample.dwg")
; Returns:
; nil
 (defun aec_openp (file-arg / file)
  (cond 
   ((setq file (open file-arg "a"))
        (close file)
   )
  )
  (not file)
 ) ; defun 
 (if(and(member "acetutil.arx"(arx))acet-ui-getfile)  
  (setq fil (acet-ui-getfile "Select Drawing File to Open" (getvar"dwgprefix") "dw?;dxf" "" 288))
  (setq fil (getfiled "Select Drawing File to Open" (getvar"dwgprefix") "dw?;dxf" 4))
 )
 (if fil
  (if
    (and 
     (not(aec_openp fil))
     (zerop(getvar "SDI"))
     (or
       (wcmatch (strcase fil) "*.DWG")
       (wcmatch (strcase fil) "*.DWS")
       (wcmatch (strcase fil) "*.DWT")
       (wcmatch (strcase fil) "*.DXF")
     ) 
    )
   (progn
    (vla-open (vla-get-documents (vlax-get-acad-object)) fil :vlax-false)
; https://www.cadtutor.net/forum/topic/50535-switch-between-opened-drawings-vla-activate/?do=findComment&comment=419633     
    (vlax-for doc (vla-get-Documents (vlax-get-acad-object))
     (if (eq (vla-get-fullname doc) fil)
      (vla-put-windowstate doc acmax)
      (vla-put-windowstate doc acmin)
     )
    )
   )
   (alert(strcat"\nSelected file is Not a Drawing or is Already Opened:\n\n[" fil "]"))
  )
  (princ"\nNothing selected.")
 )
 (princ)
)

[salbrechtJHHCV]

Thanks. Maybe I'll give this a try as well.