Changing attribute settings - unit precision

[yu85.info]

Hi. I have this block (attched). I want to change the precision of the units in the ELEV attribute from - 0.000 

to - 0.00

Is there a simple way to do this?

Thank you very much

[ВeekeeCZ]

Well, the easier way to change it is definitely to rewrite the value in the Properties palette manually.

But.... if you have plenty of those objects... then you would need a routine for that. Eg. this one.

(vl-load-com)

(defun c:AttRound ( / s a r i e)

  (if (and (setq s (ssget "_:L" '((0 . "INSERT"))))
	   (setq a (car (nentsel "\nPick an attribute to round: ")))
	   (setq a (cdr (assoc 2 (entget a))))
	   (setq r (cond ((getint "\nSpecify number or decimal to round to <2>: ")) (2)))
	   )
    (repeat (setq i (sslength s))
      (setq e (ssname s (setq i (1- i))))
      (if (not (vl-catch-all-error-p (vl-catch-all-apply 'getpropertyvalue (list e a))))
	(setpropertyvalue e a (rtos (atof (getpropertyvalue e a )) 2 r)))))
  (princ)
  )

Learn HERE how to use a LISP if you need to.

[yu85.info]

@ВeekeeCZ  AMAZING! It helped me a lot. 

sorry for being rude... is there a way that I will be able to type the attribute name insted of picking it?

anyway it is a very nice lisp 

thank you very much

[ВeekeeCZ]

Sure.

(defun c:AttRound ( / s a r i e)

  (if (and (setq s (ssget "_:L" '((0 . "INSERT"))))
	   (setq a (getstring "\nTag: ")
	   (setq r (cond ((getint "\nSpecify number or decimal to round to <2>: ")) (2)))
	   )
    (repeat (setq i (sslength s))
      (setq e (ssname s (setq i (1- i))))
      (if (not (vl-catch-all-error-p (vl-catch-all-apply 'getpropertyvalue (list e a))))
	(setpropertyvalue e a (rtos (atof (getpropertyvalue e a )) 2 r)))))
  (princ)
  )

[yu85.info]

@ВeekeeCZ  sorry but I tried to load this one and I am getting this massage:

Command: (LOAD "D:/InfraTek/LISP/attRound2.lsp") ; error: malformed list on input

thank you again

[ВeekeeCZ · Accepted solution]

Sorry, one parent missing.

(vl-load-com) 

(defun c:AttRound ( / s a r i e)

  (if (and (setq s (ssget "_:L" '((0 . "INSERT"))))
	   (setq a (getstring "\nTag: "))
	   (setq r (cond ((getint "\nSpecify number or decimal to round to <2>: ")) (2)))
	   )
    (repeat (setq i (sslength s))
      (setq e (ssname s (setq i (1- i))))
      (if (not (vl-catch-all-error-p (vl-catch-all-apply 'getpropertyvalue (list e a))))
	(setpropertyvalue e a (rtos (atof (getpropertyvalue e a )) 2 r)))))
  (princ)
  )

[yu85.info]

Perfect:)

thx

I appreciate it