Copier un texte puis le coller en suffixe d'un attribut

[magdi_95]

Bonjour à tous,

Je travail actuellement sur un projet qui necessite de realiser la codification de milliers de boitiers, pour ce faire j'utilise le lisp INCR (de Giles) pour la partie a incrementer  mais ce repere se termine par trois digits qui font reference a une trame de facade (presente en texte dans le plan).

ma question est la suivante: peut-on a partir d'un lisp COPIER le numero de la trame de facade d'un simple clic puis de la meme facon le COLLER en Suffixe sur le repere deja saisi (en attribut).

Un petit exemple pour mieux comprendre:

°Reperes de boitiers deja saisi en (attribut):

XVR0275A01-

XVR0275B01-

XVR0275C01-

XVR0275D01-

°Numero de la trame à ajouter en suffixe des repères ci dessus (Texte ligne)

486

°Resultats à obtenir (en attribut):

XVR0275A01-486

XVR0275B01-486

XVR0275C01-486

XVR0275D01-486

Le principe du copier/coller se rapproche beaucoup du lisp en piece jointe : rcvaltxt qui permet d'un simple clic de copier un texte ou un attribut et de coller la valeur (qui ecrase le texte existant) dans un autre texte ou attribut (mon cas est identique sauf que le "Coller" doit etre ajouter (en suffixe) au texte de destination

En esperant avoir ete assez clair!

Bonne soirée

Magdi

[olivier.eckmann]

Bonsoir,

(defun C:SFX2ATT ( / oText sSuffixe oAttrib oAttribLst sValAtt )
  (while (and (setq oText (car (entsel "\nSélectionner le texte à utiliser comme suffixe : ")))
	      (= "TEXT" (cdr (assoc 0 (entget oText))))
	      (setq sSuffixe (cdr (assoc 1 (entget oText))))
	 )
    (while (and (setq oAttrib (car (nentsel "\nSélectionner l'attribut à annoter : ")))
		(= "ATTRIB" (cdr (assoc 0 (setq oAttribLst (entget oAttrib)))))
		(setq sValAtt (cdr (assoc 1 oAttribLst)))
 	   )
      (setq oAttribLst (subst (cons 1 (strcat sValAtt sSuffixe)) (assoc 1 oAttribLst) oAttribLst))
      (entmod oAttribLst)
    )
  )
)

 Olivier

[magdi_95]

Bonjour Olivier,

Merci pour ta réactivité et ton savoir, le lisp fonctionne très bien s'est parfait encore une fois.

Bonne journée à tous.

Magdi