Not sure I'm going to be able to help with the unwrapping (though I will have a look at it), but in the meantime...
Boxes are easier to work with for this (rather than a Sphere) because they automatically have each face set to a different MatID (1 through 6).
Using "$" - probably better to use "selection", as in
for obj in selection do
"Selection" is a pre-defined global which is "a collection of the objects currently selected". However, if you need to iterate over the whole scene (excluding helpers, lights etc) then
for obj in geometry do
may be more appropriate, though it locks up my Max if I use it - probably because the geometry global changes as the new objects are created - taking a copy of it and using the copy does work.
Not much point in setting "baseObj = $" then using "$" in the code.
Not sure why you're using "execute" - tbh I'm not even sure what it's doing! There are warnings in the help about exectue and the scope in which it runs (global).
"Convertto <node> <class>" construct is a Mapped function - works on a collection, but the <node> in this case is a single object, so a simple "convertToPoly <node>" is much clearer.
Quite why the original code has 1 line using "tempobj.modifiers" and the rest just using "Unwrapper" I don't know (sorry Randall btw). If there's no difference (and I don't know if there is or isn't), then they should (for consistency) be the same - one or the other but not a mixture (after the modifier has beed added).
The overall layout of the code needs a little attention, I feel. There are several separate steps to go through, depending on exactly what you're trying to do - breaking up the code (into functions) makes it easier to follow and easier to maintain.
While it may seem easier to put everything in the one loop (and it may be quicker) it makes debuggin much more difficult. The newNodes array cound be dispensed with (below) but it's much clearer (at least to me) not to have too many nested calls - easy eough to change if you prefer it that way though.
The following appears to work in Max 2009 - you'haven't told us (unless I missed it) which version you're using - it really helps if you put this in your signature.
(
local newNodes = #()
fn addUnwrapper obj =
(
max modify mode
modPanel.setCurrentObject obj
subObjectLevel = 4
Unwrapper = Unwrap_UVW name:"Unwrapper"
Unwrapper.setApplyToWholeObject true
addModifier obj Unwrapper
Temp = obj.modifiers
Temp.setMapChannel 2
Temp.setTVSubObjectMode 3
Temp.flattenMap 45.0 #() 0.001 true 0 true true
subObjectLevel = 0
)
fn explodeToElementsByMatID obj =
(
local MatID = 1, PolyList = #()
while (polyop.getNumFaces obj > 0) do
(
obj.selectByMaterial MatID
polyList = polyop.getFaceSelection obj
if (polyList.count > 0) do
(
newName = (uniquename (obj.name + "'" + "DetachedObject" + "'"))
polyOp.detachfaces obj polyList delete:true asnode:true name:newName
append newNodes (getNodeByName newName exact:true)
)
MatID += 1
)
)
baseObjects = for bo in geometry collect bo
for bo in baseObjects do
(
convertToPoly bo
explodeToElementsByMatID bo
)
for nn in newNodes do
(
addUnwrapper nn
)
Max Select None
)
Max 2016 (SP1/EXT1)
Win7Pro x64 (SP1). i5-3570K @ 4.4GHz, 8Gb Ram, DX11.
nVidia GTX760 (2GB) (Driver 430.86).
