with redraw off
(
delete objects
spinAttrib = attributes "spinAttrib"
(
parameters main
(
lastTM type:#matrix3 animatable:off
angle type:#float animatable:off
)
)
fn makeWheel name: radius: pos: wirecolor: =
(
in (p = point name:name pos:pos size:10 wirecolor:yellow)
(
w = cylinder name:(name + "_body") sides:24 segments:1 radius:radius height:3 slice:on sliceFrom:350 sliceTo:10 pos:pos wirecolor:wirecolor
w.objectOffsetRot = eulerangles 90 0 0
CenterObject w
)
p
)
mapped fn makeWheelScript p =
(
node = p.children[1]
ss = "tm = parent.transform*(inverse this.lastTM)\n"
ss += "sign = (if dot tm[1] this.lastTM[1] > 0 then 1 else -1)\n"
ss += "this.angle += 360*tm.pos.x*sign/(2*pi*radius)\n"
ss += "this.lastTM = parent.transform\n"
ss += "degtorad(this.angle)\n"
c = node.rotation.controller[2].controller = float_script()
custattributes.add c spinAttrib
c.lastTM = p.transform
c.addconstant "radius" node.radius
c.addnode "parent" p
c.setexpression ss
c
)
body =
(
b = (box name:"Wheel_chair" width:25 length:20 height:25 pos:[-5,0,17] wirecolor:blue) - (c = box width:30 length:25 height:25 pos:[0,0,25])
delete c
b
)
local wheels = #(), look
in body
(
look = point name:"Dir_Dummy" size:10 axistripod:on box:on pos:[15,0,5] wirecolor:green
append wheels (makeWheel name:"LF_wheel" radius:5 pos:[10,-10,5] wirecolor:red)
append wheels (makeWheel name:"RF_wheel" radius:5 pos:[10,10,5] wirecolor:red)
append wheels (makeWheel name:"LR_wheel" radius:15 pos:[-10,-13,15] wirecolor:orange)
append wheels (makeWheel name:"RR_wheel" radius:15 pos:[-10,13,15] wirecolor:orange)
)
makeWheelScript wheels
c = Orientation_Constraint local_world:2
c.appendTarget look 100
wheels[1].rotation.controller = wheels[2].rotation.controller = c
in coordsys local with animate on
(
at time 30 move body [60,0,0]
at time 30 rotate body (eulerangles 0 0 0)
at time 40 rotate body (eulerangles 0 0 -40)
at time 40 move body [15,5,0]
at time 70 move body [80,0,0]
at time 70 rotate body (eulerangles 0 0 0)
at time 80 rotate body (eulerangles 0 0 -40)
at time 100 move body [-100,0,0]
)
select body
)
here is an example i made for another people on another forum. Hope it might help
