Xref Scene filter in layer/object explorers

[tbusseyA33GU]

Is there any way to filter out xref scene objects from the layer/object explorers?


They don't seem to respect the xref filter (I'm assuming this only works on xref objects, not xref scenes)

[A娘 · Accepted solution]

add a custom filter property when needed

global xrefobjectsel=#()
global AEI_objlayer_sel_delay = timestamp()
fn travelnode o =
(
	tempsel= for oo in o.children collect oo
	for oo in o.children do
		if oo.children.count > 0 do 
			join tempsel (travelnode oo)
	tempsel
)
fn refreshxref =
(
	xrefobjectsel=#()
	count=xrefs.getXRefFileCount()
	if count == 0 then
	 	return 0
	else
		for i = 1 to count do 
		(
			aXref=xrefs.getXRefFile i
			xrefsel = for o in aXref.tree.children collect o
			for o in xrefsel where o.children.count > 0 do 
				join xrefsel (travelnode o)
			append xrefobjectsel xrefsel
		)
	AEI_objlayer_sel_delay = timestamp()
)
fn getxrefindex theNode = 
(
	if timestamp() - AEI_objlayer_sel_delay > 5000 do
		refreshxref()
	if xrefobjectsel.count == 0 then
		return 0
	else
	for i = 1 to xrefobjectsel.count do 
	(
		if finditem xrefobjectsel[i] thenode do 
			return i
	)
	0
)
SceneExplorerManager.addReadOnlyProperty "xrefindex" getxrefindex

run script above , there will be a new filter called xrefindex added to list , active advanced filter and add rule xrefindex with 0 , xref scene objects will be removed , rule with 1 , only objects in 1st xref file shows
when add xref scene , layer explorer should be closed or not add xrefindex column or rule

[haifeng_yuSEVKN]

hello @tbusseyA33GU, thanks very much for the information. I noticed that it seems like we are not able to filter out Xref scene objects from the layer/object explorers. However, we can load/unload the objects in Xref Scene editor. May I ask how you would like to fiter out the Xref objects in the explorers? Are you trying to hide/unhide objects or move them to certain layers? Thank you!

[joaquim.moral]

Hi @tbusseyA33GU,

Could you kindly confirm that you followed our colleague @haifeng_yuSEVKN's instructions? That way, we could help you more effectively.

Thanks!

[haifeng_yuSEVKN]

hell @tbusseyA33GU, thank you for posting the question about Xref Scene filter in layer/object explorers. I assume that you may need a bit of time to work on this issue, please feel free to find if the information provided is beneficial to you. Also, you could try using the suggestion provided by @A娘. Thank you @A娘 for sharing additional information.