topic Re: Lisp or command for square with red hatch in Visual LISP, AutoLISP and General Customization Forum

Lisp or command for square with red hatch

Anonymous — Thu, 25 Oct 2018 09:13:22 GMT

I'm looking for a lisp or a command that allows me to create a square (not always a rectangle) with a black edge and a red hatch.

If also possible i'ld like to follow it up by a dimension of a specific "dimension style".

Thanks advance for your time and effort.

Re: Lisp or command for square with red hatch

ВeekeeCZ — Thu, 25 Oct 2018 09:35:01 GMT

Post a dwg to have a look.

Any layer preference? Or just current?

Which autocad version you have?

Anyway, try this easy one... simple to learn of.

(defun c:RectangleFilled ( / ocl)
  (setq ocl (getvar 'CECOLOR))
  (setvar 'CECOLOR "7")
  (command-s "_.RECTANG")
  (setvar 'CECOLOR "1")
  (command "_.BHATCH" "_S" "_L" "" "")
  (command "_.DIMSTYLE" "_Re" "ISO-25")
  (setvar 'CECOLOR ocl)
  (princ)
)

Re: Lisp or command for square with red hatch

Anonymous — Thu, 25 Oct 2018 11:49:35 GMT

Hi thanks for the time and effort

But the rectangle function isn't exactly what I'm looking for.

Sometimes the square will be at an angle

I'm using Autocad 2019

Preferably it'll start in layer 0 with lineweights of 0.09mm (or by layer).

Thanks again!

Re: Lisp or command for square with red hatch

ВeekeeCZ — Thu, 25 Oct 2018 12:18:20 GMT

@Anonymous wrote:

Sometimes the square will be at an angle ...

Sure, why not - still can be done with the RECTANG command.

Re: Lisp or command for square with red hatch

Anonymous — Thu, 25 Oct 2018 13:57:52 GMT

It doesn't seem to work with oblique angles.

Below you'll see why, this is after I've selected the first point.

Autocad automatically assumes a Rectangular square along x-y.

The command "solid" seem more what I need, but doesnt have a black border.

Still thanks for the help though...

Re: Lisp or command for square with red hatch

Kent1Cooper — Thu, 25 Oct 2018 13:58:11 GMT

How would you want the User to give input for the location and size of that square/rectangle? Will those long Lines [or Rays or Xlines?] always be there already? Should the User pick points on them, or pick one corner and be prompted for a length along them, or....? Do you want the outline of the square/rectangle as a closed Polyline [such as the RECTANG command makes], or could the longer Lines form two sides and the other two sides be only Lines across the space between those?

If you're going to use the Solid Hatch pattern, I recommend you consider a SOLID [of the 2D variety] instead. It takes less memory, and will Stretch along with the surroundings if you make that kind of change [a Hatch pattern made with a (command)-function Hatch command won't be associative, even if that's the current setting for Hatching, so if you Stretch the surroundings, you'll then have to grip-edit the Hatch to the changed outline].

Re: Lisp or command for square with red hatch

Kent1Cooper — Thu, 25 Oct 2018 14:04:35 GMT

@Anonymous wrote:

.... Autocad automatically assumes a Rectangular square along x-y. ....

You seem to have missed the fact that there's a Rotation option in RECTANG after you've given it the first point [in new-enough versions, which you have]. Note the "or" at the end of the prompt box, and the pull-down list.

Re: Lisp or command for square with red hatch

ВeekeeCZ — Thu, 25 Oct 2018 14:39:57 GMT

How about like this, is it better now?

(defun c:RectangleFilled ( / ocl)
  (setq ocl (getvar 'CECOLOR))
  (setvar 'CECOLOR "7")
  (command "_.RECTANG" pause "_Rotation" "_Pick" "@" (getpoint (getvar 'lastpoint)) pause)
  (setvar 'CECOLOR "1")
  (command "_.BHATCH" "_S" "_L" "" "")
  (command "_.DIMSTYLE" "_Re" "YourDimStyle")
  (setvar 'CECOLOR ocl)
  (princ)
)

You can also add (setvar 'hpname "solid") if that is pattern you use.

Re: Lisp or command for square with red hatch

Anonymous — Thu, 25 Oct 2018 14:58:30 GMT

Yesss, that's almost perfect!

The hatch however seems to be the last type I've used, instead of a solid.

And the dim-action doesn't seem to activate. If you could only help with the solidhatching I'ld be so gratefull.

Thanks for everybody's help so far, you've been magnificent!

I'm trying to study up on lisp but I'm still far from knowing anything

Re: Lisp or command for square with red hatch

ВeekeeCZ — Thu, 25 Oct 2018 15:13:51 GMT

Sure! Also added a feature to activate your dim action! I hope the right one.

Still need to fill your DIM style... which has to be defined in the drawing.

(defun c:RectangleFilled ( / ocl)
  (setq ocl (getvar 'CECOLOR))
  (setvar 'CECOLOR "7")
  (command "_.RECTANG" pause "_Rotation" "_Pick" "@" (getpoint (getvar 'lastpoint)) pause)
  (setvar 'CECOLOR "1")
  (command "_.BHATCH" "_P" "_Solid" "_S" "_L" "" "")
  (command "_.DIMSTYLE" "_Re" "YourDimStyle")
  (setvar 'CECOLOR ocl)
  (initcommandversion)
  (command "_DIM")
  (princ)
)

Re: Lisp or command for square with red hatch

Kent1Cooper — Thu, 25 Oct 2018 16:05:16 GMT

@ВeekeeCZ wrote:

....
....
  (command "_DIM")
....

Given the images, I'd go for:

(command "_.dimaligned")

Re: Lisp or command for square with red hatch

Anonymous — Fri, 26 Oct 2018 08:11:05 GMT

Perfecttt !!!

That's point on, 100% what I was looking for.

Works excellent with the dimstyle and everything.

Thanks everybody for your time and effort, it may look like a simple command but it's one we use frequently.

Re: Lisp or command for square with red hatch

Anonymous — Fri, 26 Oct 2018 13:28:55 GMT

Would it be possible to add one more option?

After I've placed the dimension (only one, if that helps) the dimstyle should return to another (or previous) one.

I tried adding the "dimstyle command to the bottom, but since the first dim-command doesn't end after placing one dimension. It's kinda stuck in that action. And If I press escape, it exits the lisp without ever getting to the next resetting of the dimstyle. Any insight on how this can be solved?

Re: Lisp or command for square with red hatch

ВeekeeCZ — Fri, 26 Oct 2018 14:01:57 GMT

It could be solved surprisingly easy... add "-s" suffix. COMMAND-S keeps the user inside the command until he decides to quit.

Also added the *error* function which returns all the changed variables in case of error or ESC hit or so.

(defun c:RectangleFilled ( / *error* ocl ost)

  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break"))
      (princ (strcat "\nError: " errmsg)))
      (setvar 'CECOLOR ocl)
      (command-s "_.DIMSTYLE" "_Re" ost)
    (princ))
  
  (setq ocl (getvar 'CECOLOR))
  (setq ost (getvar 'DIMSTYLE))
  
  (setvar 'CECOLOR "7")
  (command "_.RECTANG" pause "_Rotation" "_Pick" "@" (getpoint (getvar 'LASTPOINT)) pause)
  (setvar 'CECOLOR "1")
  (command "_.BHATCH" "_P" "_Solid" "_S" "_L" "" "")
  (command "_.DIMSTYLE" "_Re" "ISO-25")
  (setvar 'CECOLOR ocl)
  (initcommandversion)
  (command-s "_.DIM")
  (command "_.DIMSTYLE" "_Re" ost)
  (princ)
)

The blue part can be alternated with this line, to follow Kent's suggestion. This way you can save one more click.

(command "_.DIMALIGNED" "" PAUSE PAUSE)  ; select an edge, then place the

BTW It's not about how many dims you need to add, but how many user inputs you need to do. Single PAUSE for each. So in this case it depends how you're use to make a DIM - whether you select <object> then an EDGE then place the DIM, or pick a left end, then right end, then place the DIM - that's something for you to thing about and place the correct "" for <enter> or PAUSE to the code.

Re: Lisp or command for square with red hatch

Anonymous — Tue, 30 Oct 2018 08:26:00 GMT

Works like a charm!

I think the defun: "C" has to be a capital letter tough?

It didn't work untill I changed that.

But thanks again for all your time and effort! A true Lisp-wizard

Re: Lisp or command for square with red hatch

ВeekeeCZ — Tue, 30 Oct 2018 08:51:58 GMT

Glad to help!

@Anonymous wrote:

... I think the defun: "C" has to be a capital letter tough?...

Not really.

Try this c:Test and see...

(defun c:Test () (princ "That was with 'c'!") (princ))

Re: Lisp or command for square with red hatch

Anonymous — Thu, 26 Nov 2020 08:15:53 GMT

Hi all, after working with the command for some time (thanks again!)

I've still noticed a few issues I was wondering could be fixed... ?

In a nutshell, some settings before I've used the command should be unchanged after the command.

- The hatch color should always be red (0% transparency).
Afterwards hatchcolor should return to the previous setting or bylayer.

- The rotation should afterward return to 0degrees (now, when I use the command for a rotated rectangle the degrees are stored. When I then draw a regular rectangle it always takes the previous inclanation and is never 0degreees.

- The dimstyle should also return to the previous dimstyle. Instead it defaults to the one in the command.

I'ld be happy to try some things out if anyone could give me hint as where to look...
I've tried to put -s in front of the commands but doesn't seem to help.

Re: Lisp or command for square with red hatch

ВeekeeCZ — Thu, 26 Nov 2020 09:53:08 GMT

I wonder what you are actually doing because the code posted #13 (possibly with DIMALIGN included) should always restore the color and dimstyle.

Though, not a rectang rotation, that's another story and not that simple (you need to re-run the command, set rotation to 0, and force the command to end: (command "_.rectang" '(0 0) "_R" 0) (command). And on top of that, this won't work in the *error*.

(defun c:RectangleFilled ( / *error* ocl ost)

  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break"))
      (princ (strcat "\nError: " errmsg)))
      (setvar 'CECOLOR ocl) ; restore in case of error (inc. ESC)
      (command-s "_.DIMSTYLE" "_Re" ost)
    (princ))
  
  (setq ocl (getvar 'CECOLOR)) ; save old value
  (setq ost (getvar 'DIMSTYLE))
  
  (setvar 'CECOLOR "7") ; change 
  (command "_.RECTANG" pause "_Rotation" "_Pick" "@" (getpoint (getvar 'LASTPOINT)) pause)
  (setvar 'CECOLOR "1") ; change again
  (command "_.BHATCH" "_P" "_Solid" "_S" "_L" "" "")
  (command "_.DIMSTYLE" "_Re" "ISO-25")
  (setvar 'CECOLOR ocl) ; restore
  (initcommandversion)
  (command-s "_.DIM")
  (command "_.DIMSTYLE" "_Re" ost)
  (princ)
)

Re: Lisp or command for square with red hatch

Anonymous — Mon, 30 Nov 2020 13:00:49 GMT

Hi. thanks so much for replying.

I've tried the last code... I might restore the hatch afterwards, but the hatchcolor of the created item isnt always red. It takes the last hatchcolor+transparancy that was used.

For instance... when I manually hatch an object in pink. Then start the lisp,, the hatch used for the lisp-rectangle will also be pink...

Is there a way around this? Ive tried experimenting with several tiny modifications but nothing seems to work.

Re: Lisp or command for square with red hatch

ВeekeeCZ — Mon, 30 Nov 2020 14:48:33 GMT

Here is your help:

Here's the code updated.

(defun c:RectangleFilled ( / *error* oCECOLOR oHPCOLOR oHPTRANSPARENCY oDIMSTYLE)
  
  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break"))
      (princ (strcat "\nError: " errmsg)))
    (if oCECOLOR (setvar 'CECOLOR oCECOLOR))    
    (if oHPCOLOR (setvar 'HPCOLOR oHPCOLOR))
    (if oHPTRANSPARENCY (setvar 'HPTRANSPARENCY oHPTRANSPARENCY))
    (command-s "_.DIMSTYLE" "_Re" oDIMSTYLE)
    (princ))
  
  (setq oCECOLOR (getvar 'CECOLOR))
  (setq oHPCOLOR (getvar 'HPCOLOR))
  (setq oHPTRANSPARENCY (getvar 'HPTRANSPARENCY))
  (setq oDIMSTYLE (getvar 'DIMSTYLE))
  
  (setvar 'CECOLOR "7")
  (command "_.RECTANG" pause "_Rotation" "_Pick" "@" (getpoint (getvar 'LASTPOINT)) pause)
  (command "_.RECTANG" '(0 0) "_R" 0.) (command)
  (setvar 'HPCOLOR "1")
  (setvar 'HPTRANSPARENCY "0")
  (command "_.BHATCH" "_P" "_Solid" "_S" "_L" "" "")
  (command "_.DIMSTYLE" "_Re" "ISO-25")
  (setvar 'CECOLOR oCECOLOR)
  (command "_.DIMALIGNED" "" pause)
  (if (> (getvar 'cmdactive) 0) (command pause))
  (command "_.DIMSTYLE" "_Re" ost)
  (princ)
  )

Note: If you don't want to add a dim to it, right-click will cancel the dimalign.