topic Re: Creating multiple closed polygons in selected closed boundaries in Visual LISP, AutoLISP and General Customization Forum

Creating multiple closed polygons in selected closed boundaries

Anonymous — Tue, 27 Nov 2018 08:53:51 GMT

Dear Helpers,

I stucked in creating lot of closed polygons in closed boudaries. Suppose we have so many rooms in a floor of a building with just lines and arcs. The lisp should generate multiple polygons inside the closed boundaries of rooms or zones.

Please have a look on attached drawing.

Re: Creating multiple closed polygons in selected closed boundaries

dbhunia — Tue, 27 Nov 2018 09:31:47 GMT

If your every Room is named then try this........(Chose a layer create Polyline & change its properties.....)

(defun C:CB (/)
(setvar "CMDECHO" 0)
(princ "\nSelect the Text/Mtext Inside the Closed Area: ")
(Setq selectionset (ssget '((0 . "*TEXT"))))
(repeat (setq N (sslength selectionset))
	(setq Data (ssname selectionset (setq N (- N 1))))
	(setq EntityData (entget Data))
	(setq IP_Text (cdr (assoc 10 EntityData)))
	(command "BOUNDARY" "_none" IP_Text "") 
)
(setvar "CMDECHO" 1)
(princ)
)

Re: Creating multiple closed polygons in selected closed boundaries

Anonymous — Tue, 27 Nov 2018 09:45:44 GMT

Exact Solution I got from you.

Very Nice. Thankin you So much. Perfectly suited to my task

Re: Creating multiple closed polygons in selected closed boundaries

Anonymous — Tue, 27 Nov 2018 09:50:31 GMT

Thank you Very much.

But it's not working with without text. If some rooms may not having text inside. So in that case also it should create Room boundaries.

Thank you inadvance, Sir.

Re: Creating multiple closed polygons in selected closed boundaries

dbhunia — Tue, 27 Nov 2018 10:08:10 GMT

chek this..... created by @ВeekeeCZ.....

https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/ssget-to-select-a-polyline-using-two-coordinates-as-filters/td-p/8408912

And first give some clue how the problem can be solved.......

Second post your workout.......

Because its sure you are going to ask many questions 1 by 1.......

Re: Creating multiple closed polygons in selected closed boundaries

phanaem — Tue, 27 Nov 2018 10:12:31 GMT

Try the attached lisp.

Works with lines, arcs, circles and polylines, parallel to UCS.

Re: Creating multiple closed polygons in selected closed boundaries

Anonymous — Tue, 27 Nov 2018 10:18:59 GMT

I used the below code from that link. But couldn't work.

(defun c:testeclose ( / ss i obj pnt ptlst ptsum )

  (if (setq ss (ssget '((0 . "LWPOLYLINE") (-4 . "<NOT") (-4 . "&=") (70 . 1) (-4 . "NOT>") (-4 . ">") (90 . 2))))
    (repeat (setq i (sslength ss))
      (setq ptlst nil ptsum '(0 0)
	    ptlst (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 10))
				      (entget (ssname ss (setq i (1- i)))))))
      (foreach x ptlst (setq ptsum (mapcar '+ x ptsum)))
      (setq pnt (mapcar '/ ptsum (list (length ptlst) (length ptlst))))
      (if pnt (command "_.-boundary" "_non" pnt ""))))
  (princ)
)

Re: Creating multiple closed polygons in selected closed boundaries

Anonymous — Tue, 27 Nov 2018 11:32:47 GMT

Thank you So much Sir. It's working fetatstic

Re: Creating multiple closed polygons in selected closed boundaries

alansanudo — Fri, 21 Feb 2020 18:02:11 GMT

What's the command how can i execute it? will it work to create multiple boundaries for different "areas" as the image attached?

Re: Creating multiple closed polygons in selected closed boundaries

Kent1Cooper — Fri, 21 Feb 2020 19:12:19 GMT

@alansanudo wrote:

What's the command how can i execute it? will it work to create multiple boundaries for different "areas" as the image attached?

Here's a way to do that. It asks you to pick points [just on-screen -- nothing drawn] defining opposite corners of a rectangular area that completely encloses the drawn [I assume property-line] parcels, and asks for a spacing increment, starts a BOUNDARY command, and just picks every point in a grid at that spacing throughout the area. If it picks outboard of it all, a message goes by that no enclosed area was found, and if it picks more than once within the same area, a message goes by that the area has already been picked, but in either case it doesn't bother anything -- it keeps going. Give it a spacing increment small enough that it's bound to land inside every parcel somewhere at least once, maybe a little less than the smallest parcel edge expected. You will want to turn off Layers other than those of your property lines, so that it won't find an enclosed area outside of them all. And it depends on all the parcels really being closed. Minimally tested.

(defun C:MBound ; = Multiple Boundaries
  (/ cor1 cor2 UR rowleft pt)
  (setq
    cor1 (getpoint "\nOne corner of area-enclosing rectangle: ")
    cor2 (getcorner cor1 "\nOpposite corner: ")
    inc (getdist "\nPick-point spacing increment: ")
    UR (mapcar 'max cor1 cor2)
    rowleft (mapcar '+ (mapcar 'min cor1 cor2) (list inc inc))
    pt rowleft
  ); setq
  (command "_.boundary" "advanced" "object" "Polyline" "")
  (while (< (cadr pt) (cadr UR)); still below top edge
    (while (< (car pt) (car UR)); still to left of right edge
      (command pt)
      (setq pt (polar pt 0 inc))
    ); while
    (setq
      rowleft (polar rowleft (/ pi 2) inc)
      pt rowleft
    ); setq
  ); while
  (command "")
  (princ)
); defun

Re: Creating multiple closed polygons in selected closed boundaries

alansanudo — Fri, 21 Feb 2020 19:33:02 GMT

Thanks for the explanation, but how do I execute the code? sorry for my ignorance.

Re: Creating multiple closed polygons in selected closed boundaries

Kent1Cooper — Fri, 21 Feb 2020 19:40:41 GMT

Copy the code into a plain-text editor such as Notepad. Save it to a file with a .LSP filetype ending [call it anything you want]. In AutoCAD, APPLOAD that file. The command name is MBound [the part immediately following C: -- not case-sensitive].

Re: Creating multiple closed polygons in selected closed boundaries

kareemelnady8 — Sat, 06 Apr 2024 15:18:54 GMT

"Enclosed polylines v1.03.lsp" this is perfect it's very good thank you

Re: Creating multiple closed polygons in selected closed boundaries

albinZ5N68 — Sat, 22 Mar 2025 11:32:40 GMT

Hi, thanks for your work.

I'm trying to adapt it to get the result shown in the attachment (automatic separation of closed parts, with inclusion of objects inside the parts).

But already, when I use the LISP on my entire drawing, if I have multiple separate elements, the region detection gives me full regions instead of only the smallest ones... Do you know why?