topic Re: Lisp Code Additional Help! in Visual LISP, AutoLISP and General Customization Forum

Lisp Code Additional Help!

Kyle.Pederson — Fri, 07 Dec 2018 13:43:29 GMT

I have a code that someone has created for me, but have yet to hear from them anymore with a few tweaks to it. Hoping someone can help. Program is for inserting Google Map Images, Scale and Rotate them.

Currently the program is set to where you need to insert them Google Map Image prior to running to command. I'd like to have the attach command implemented into the code. Following that the rotate command in the code is wanting me to select 2 points that will be horizontal, at times the image doesn't need to be rotated and I'd like an option to rotate or not. Lastly, If you exit out of the command midway thru, all preselected object snaps are lost. How can I keep that from happening? Thanks for any help you guys can provide.

;;;--- App to insert a google image, scale and rotate

(defun C:GM()
  (setq oldEcho(getvar "cmdecho"))
  (setq oldSnap(getvar "osmode"))
  (setvar "cmdecho" 0)
  (setvar "osmode" 0)
  (setq dist(getdist "\n Select two points on image to measure: "))
  (setq gdist(getdist "\n Google Dimension: "))
  (setq en(car(entsel "\n Select image: ")))
  (command "scale" en "" (list 0 0 0) (/ gdist dist))
  (command "zoom" "extents")
  (setq ang(getangle "\n Select two points to be horizontal: "))
  (command "rotate" en "" (list 0 0 0) (angtos (- ang ang ang) 1 8))
  (setvar "osmode" oldSnap)
  (setvar "cmdecho" oldEcho)
  (princ)
)

Re: Lisp Code Additional Help!

Moshe-A — Fri, 07 Dec 2018 14:33:04 GMT

@Kyle.Pederson hi,

here is my fix to MG command

something about the rotate calc was weird to me so i put it on remark and added my version to it so test it if it's ok.

about osnap...if you want to break in mid function just press enter instead of esc, this will preserve your osnap settings.

enjoy

moshe

(defun C:GM (/ oldEcho oldSnap dist gdist en ang)
  (setq oldEcho(getvar "cmdecho"))
  (setq oldSnap(getvar "osmode"))
  (setvar "cmdecho" 0)
  (setvar "osmode" 0)
  
  (if (and
	(setq dist (getdist "\nSelect two points on image to measure: "))
        (setq gdist (getdist "\nGoogle Dimension: "))
        (setq en (car (entsel "\nSelect image: ")))
      )
   (progn
    (command "scale" en "" (list 0 0 0) (/ gdist dist))
    (command "zoom" "extents")
    
    (if (setq ang (getangle "\nSelect two points to be horizontal: "))
    ; (command "rotate" en "" (list 0 0 0) (angtos (- ang ang ang) 1 8))
     (command "rotate" en "" (list 0 0 0) (angtos (* -1 ang) 1 8))
    )
   ); progn
  ); if
  
  (setvar "osmode" oldSnap)
  (setvar "cmdecho" oldEcho)
  (princ)
)

Re: Lisp Code Additional Help!

scot-65 — Fri, 07 Dec 2018 23:14:50 GMT

>>> (* -1 ang)
=
(- ang)

???

Re: Lisp Code Additional Help!

scot-65 — Fri, 07 Dec 2018 23:46:34 GMT

Allow the user to keep the OSNAP as is and follow Moshe's
handling of user input before executing.

I would suggest to rework [remove] the getangle statement as this is also user input:
(setq ang
(if (not (setq p1 (getpoint "Specify first point of angle <0>: ")))
0
(angle p1 (getpoint "Specify second point: "))
);if
);setq
Place the above inside the "and".
*unverified*

Once the user input is satisfied (which means you entered into PROGN),
it is at this time to tinker with the OSNAP setting [if required].
...and CMDECHO.

Suggest adding 16384 to the OSNAP value as this will temporarily
suppress the OSNAP. At the end, subtract.
If the program errors out, one can simply select the icon in the tray area
to turn back on.

;set:
(if (< (getvar "OSMODE") 16384) (setvar "OSMODE" (+ (getvar "OSMODE") 16384)))
;reset (and inside *error*):
(if (> (getvar "OSMODE") 16384) (setvar "OSMODE" (- (getvar "OSMODE") 16384)))

During development of tools, and the program subsequently errors out, these bits
of code will auto-correct OSMODE.

???

Re: Lisp Code Additional Help!

Kyle.Pederson — Tue, 11 Dec 2018 22:09:15 GMT

I haven't been able to test yet, but wouldn't doing below ask for the points and rotate based on the not correctly scaled image? I'd like to have the image scaled appropriately, and then either have the option to keep the current image without rotation or allow to pick 2 points of the correctly scaled image based on the Google Dimension to rotate horizontal (0 Degrees)

(setq ang
 (if (not (setq p1 (getpoint "Specify first point of angle <0>: ")))
 0
 (angle p1 (getpoint "Specify second point: "))
 );if
);setq
Place the above inside the "and".

Re: Lisp Code Additional Help!

CodeDing — Tue, 11 Dec 2018 22:37:19 GMT

@Kyle.Pederson,

First, I am going to HIGHLY recommend that you look into the ALIGN command. This will do most of the heavy lifting for you. It will Move, Scale and Rotate your object all in one command. Here is some lisp syntax:

(setq e (ensetl "\nSelect object to align: ")
(setq p1 (getpoint))
(setq p1new (getpoint))
(setq p2 (getpoint))
(setq p2new (getpoint))
(command "_.ALIGN" e "" p1 p1new p2 p2new "" "y")

Second, implementing an error handler, such as one of the ones Lee Mac has provided, will very easily reset your variables that have been changed. Since setting your variables is the first thing you do, this will work fine. See implemented example (note I have added the *error* as a local variable:

(defun C:GM( / *error* )

    (defun *error* ( msg )
	(setvar "cmdecho" oldEcho)
	(setvar "osmode" oldSnap)
        (if (not (member msg '("Function cancelled" "quit / exit abort")))
            (princ (strcat "\nError: " msg))
        )
        (princ)
    )

  (setq oldEcho(getvar "cmdecho"))
  (setq oldSnap(getvar "osmode"))
  (setvar "cmdecho" 0)
  (setvar "osmode" 0)
;.............................................

Third, while I am not directly providing you with a solution, it is good practice to keep your local variables defined so that less chance for errors can occur. Like so:

(defun C:GM( / *error* oldEcho oldSnap dist gdist en ang)

Hope this has been beneficial to you.

Best,

~DD

Re: Lisp Code Additional Help!

dbhunia — Wed, 12 Dec 2018 12:47:16 GMT

For error handling do as @CodeDing said..... and for the rest try this.......

(defun C:GM (/ *error* oldEcho oldSnap dist gdist en ang sc p1)

  (defun *error* ( msg )
	(setvar "cmdecho" oldEcho)
	(setvar "osmode" oldSnap)
        (if (not (member msg '("Function cancelled" "quit / exit abort")))
            (princ (strcat "\nError: " msg))
        )
  (princ)
  )
  (setq oldEcho(getvar "cmdecho"))
  (setq oldSnap(getvar "osmode"))
  (setvar "cmdecho" 0)
  (setvar "osmode" 0)

  (if (and
	(setq dist (getdist "\nSelect two points on image to measure: "))
        (setq gdist (getdist "\nGoogle Dimension: "))
        (setq en (car (entsel "\nSelect image: ")))
      )

      (progn
    	(command "scale" en "" (list 0 0 0) (/ gdist dist))
    	(command "zoom" "extents")
    	(initget "Y N")
    	(setq sc
	   (cond
	  	((getkword "\nWant to Rotate the Image [Yes / No] <No> : "))
	  	("N")
	   )
    	)
    
    	(if (= sc "Y")
          (progn
	     (setq ang
 		(if (not (setq p1 (getpoint "\nSpecify first point of angle <0>: ")))
 			0
 		        (angle p1 (getpoint p1 "Specify second point: "))
 		);if
	     );setq
    	     (command "rotate" en "" (list 0 0 0) (angtos ang))
	  )
       	)
      ); progn
  ); if
  
  (setvar "osmode" oldSnap)
  (setvar "cmdecho" oldEcho)
  (princ)
)

Re: Lisp Code Additional Help!

Kyle.Pederson — Wed, 12 Dec 2018 14:12:03 GMT

Thanks Dbhunia! the choice between rotating and not rotating is exactly what I was looking for. I did however change one line. from:

(command "rotate" en "" (list 0 0 0) (angtos ang))

to this:

(command "rotate" en "" (list 0 0 0) (angtos (* -1 ang) 1 8))

Your line was doubling the angle, and not bring it to 0 degrees (Horizontal)

I did have a question regarding how to add (Command "Attach" with a Scale of 1 and insertion point of 0,0,0 to the beginning of the code so I don't have this two step process of attaching image before running the command.

Re: Lisp Code Additional Help!

dbhunia — Wed, 12 Dec 2018 14:37:15 GMT

Give me 2 hour.... I am on the way to home.....after reaching home I can help you. .

Now I am operating from mobile.....

Inbetween this check this.....

https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/image-attach-lisp/td-p/4414723

You shall get your solution.....otherwise ask..

Re: Lisp Code Additional Help!

dbhunia — Wed, 12 Dec 2018 15:47:46 GMT

Try this...... (Tested in AutoCAD 2007 hopefully will run in upper version)

(defun C:GM (/ *error* oldEcho oldSnap dist gdist en ang sc p1); image)

  (defun *error* ( msg )
	(setvar "cmdecho" oldEcho)
	(setvar "osmode" oldSnap)
        (if (not (member msg '("Function cancelled" "quit / exit abort")))
            (princ (strcat "\nError: " msg))
        )
  (princ)
  )
  (setq oldEcho(getvar "cmdecho"))
  (setq oldSnap(getvar "osmode"))
  (setvar "cmdecho" 0)
  (setvar "osmode" 0)

  (if
    (setq image (getfiled "Select image" (getvar 'dwgprefix) "gif;jpg;png;tif" 8))
    (command "._undo" "_end" "._undo" "_begin" "._-image" "_attach"
              image '(0 0 0) 1.0 0.0 "._undo" "_end"
    )
  )

  (if (and
	(/= image nil)
	(setq en (entlast))
	(setq dist (getdist "\nSelect two points on image to measure: "))
        (setq gdist (getdist "\nGoogle Dimension: "))
	;(setq en (car (entsel "\nSelect image: ")))
      )

      (progn
    	(command "scale" en "" (list 0 0 0) (/ gdist dist))
    	(command "zoom" "extents")
    	(initget "Y N")
    	(setq sc
	   (cond
	  	((getkword "\nWant to Rotate the Image [Yes / No] <No> : "))
	  	("N")
	   )
    	)
    
    	(if (= sc "Y")
          (progn
	     (setq ang
 		(if (not (setq p1 (getpoint "\nSpecify first point of angle <0>: ")))
 			0
 		        (angle p1 (getpoint p1 "Specify second point: "))
 		);if
	     );setq
    	     ;(command "rotate" en "" (list 0 0 0) (angtos ang))
	     (command "rotate" en "" (list 0 0 0) (angtos (* -1 ang) 1 8))
	  )
       	)
      ); progn
  ); if
  
  (setvar "osmode" oldSnap)
  (setvar "cmdecho" oldEcho)
  (princ)
)

Re: Lisp Code Additional Help!

Kyle.Pederson — Wed, 12 Dec 2018 17:57:34 GMT

Fantastic! Currently it's preset to look through "My Documents" Folder. Can I change the preset to open up a folder of my choosing in the code?

Re: Lisp Code Additional Help!

dbhunia — Wed, 12 Dec 2018 18:26:29 GMT

suppose you have a folder at "C:\Final\XXX".........(your destination folder)

then change the line.....

(setq image (getfiled "Select image" (getvar 'dwgprefix) "gif;jpg;png;tif" 8))

to...

(setq image (getfiled "Select image" "C:\\Final\\XXX\\" "gif;jpg;png;tif" 8))

Good night here it's 12 o'clock....... Talk tomorrow...

Re: Lisp Code Additional Help!

Kyle.Pederson — Thu, 07 Mar 2019 20:01:33 GMT

Dbhunia , I'd like to increase the Decimal units Precision prior to it prompting "Select two points on Image" to two significant digits (0.00) during the command, and return to our standard precision of (0) after the command is ran if you could please help.

Re: Lisp Code Additional Help!

dbhunia — Fri, 08 Mar 2019 05:32:57 GMT

Try this.......

(defun C:GM (/ *error* oldEcho oldSnap olddecimal dist gdist en ang sc p1)

  (defun *error* ( msg )
	(setvar "cmdecho" oldEcho)
	(setvar "osmode" oldSnap)
	(setvar "LUPREC" olddecimal)
        (if (not (member msg '("Function cancelled" "quit / exit abort")))
            (princ (strcat "\nError: " msg))
        )
  (princ)
  )
  (setq oldEcho(getvar "cmdecho"))
  (setq oldSnap(getvar "osmode"))
  (setq olddecimal(getvar "LUPREC"))
  (setvar "cmdecho" 0)
  (setvar "osmode" 0)
  (setvar "LUPREC" 2)

  (if
    (setq image (getfiled "Select image" (getvar 'dwgprefix) "gif;jpg;png;tif" 8))
    (command "._undo" "_end" "._undo" "_begin" "._-image" "_attach"
              image '(0 0 0) 1.0 0.0 "._undo" "_end"
    )
  )

  (if (and
	(/= image nil)
	(setq en (entlast))
	(setq dist (getdist "\nSelect two points on image to measure: "))
        (setq gdist (getdist "\nGoogle Dimension: "))
	;(setq en (car (entsel "\nSelect image: ")))
      )

      (progn
    	(command "scale" en "" (list 0 0 0) (/ gdist dist))
    	(command "zoom" "extents")
    	(initget "Y N")
    	(setq sc
	   (cond
	  	((getkword "\nWant to Rotate the Image [Yes / No] <No> : "))
	  	("N")
	   )
    	)
    
    	(if (= sc "Y")
          (progn
	     (setq ang
 		(if (not (setq p1 (getpoint "\nSpecify first point of angle <0>: ")))
 			0
 		        (angle p1 (getpoint p1 "Specify second point: "))
 		);if
	     );setq
    	     ;(command "rotate" en "" (list 0 0 0) (angtos ang))
	     (command "rotate" en "" (list 0 0 0) (angtos (* -1 ang) 1 8))
	  )
       	)
      ); progn
  ); if
  
  (setvar "osmode" oldSnap)
  (setvar "cmdecho" oldEcho)
  (setvar "LUPREC" olddecimal)
  (princ)
)