topic Re: offset more then 1 polyline in Visual LISP, AutoLISP and General Customization Forum

offset more then 1 polyline

Anonymous — Wed, 12 Dec 2018 13:19:53 GMT

Hello,

i have an issue i want to make a lisp command to offset 2 polylines as an example i have a picture below.

the first are the polylines i need to offset. the second part is what i can get with a lisp i found online and the third picture is what i actually want.

the lisp i use for the bottom part is as follows:

(defun c:r4test ( / savesnap)
(setq ent (car (entsel "\nSelect polyline to offset: "))
pt (getpoint "\nSelect side to offset: "))
(foreach i '(distance 1 distance 2 distance 3 (command "._offset" i ent pt "")))

because i don't really know how to write these lisps i tried to add some for the line at the top. It seems not to be working and i cant really find an answer so far.

could someone explain what i would need to add to this lisp to also offset the top polyline?

Re: offset more then 1 polyline

ВeekeeCZ — Wed, 12 Dec 2018 13:41:31 GMT

Ok, those purple ones, are they just different in color or on a different layer?

Always post a dwg then we don't need to ask these ridiculous questions.

Edit: Ok, you might not be able to. Then post on some other public cloud and post just a link.

Re: offset more then 1 polyline

clindner — Wed, 12 Dec 2018 13:44:30 GMT

@Anonymous,

Try this:

(defun c:r4test (/ ent pt i)
  (setq ent (car (entsel "\nSelect polyline to offset: "))
	pt (getpoint "\nSelect side to offset: "))
  (foreach i '(1 2 3)
    (command "._offset" i ent pt "")
    ;; if i is odd, change color to magenta
    (if (/= 0 (rem i 2)) ; is i an even number
      (command "CHPROP" (entlast) "" "C" "6" "")
      )
    )
  (princ)
  )

This changes every other offset line to color 6, leaving the original entity alone. Did you want the selected pline changed to magenta?

Also, this code only offsets in one direction.

HTH.

Re: offset more then 1 polyline

Anonymous — Wed, 12 Dec 2018 13:45:01 GMT

Sorry i am new to this forum the purple lines are just a different colour.

Re: offset more then 1 polyline

Anonymous — Wed, 12 Dec 2018 13:53:20 GMT

Thanks i tried your code it does change the colours but not the right polylines. i do have to say thats not the main issue is wanted to solve. but i appreciate the help.

This is the first time i am trying to create a lisp so I can't say i know excactly what i am doing but as far as i have it now it works perfectly for the offsets at the bottom polyline.

Re: offset more then 1 polyline

ВeekeeCZ — Wed, 12 Dec 2018 14:05:01 GMT

The first one.

(defun c:r2b ( / ensel)

  (if (and (setq ensel (entsel "\nSelect polyline to offset: "))
	   (or *2rb-dist*
	       (setq *2rb-dist* (abs (getvar 'OFFSETDIST))))
	   (setq *2rb-dist* (cond ((getdist (strcat "\nSpecify distance <" (rtos *2rb-dist*) ">:")))
				  (*2rb-dist*)))
	   )
    (command "_.offset" *2rb-dist*
	     (car ensel) (polar (cadr ensel) (* pi 0.5) *2rb-dist*)
	     (car ensel) (polar (cadr ensel) (* pi 1.5) *2rb-dist*)
	     ""
	     "_.chprop" (car ensel) "" "_C" "Magenta" ""))
  (princ)
)

Re: offset more then 1 polyline

clindner — Wed, 12 Dec 2018 14:08:42 GMT

@Anonymous wrote:

Thanks i tried your code it does change the colours but not the right polylines.

Ok, maybe this will.

(defun c:r4test (/ ent pt i)
  (setq ent (car (entsel "\nSelect polyline to offset: "))
	pt (getpoint "\nSelect side to offset: "))
  (foreach i '(1 2 3)
    (command "._offset" i ent pt "")
    ;; if i is odd, change color to magenta
    (if (= 0 (rem i 2)) ; is i an even number
      (command "CHPROP" (entlast) "" "C" "6" "")
      )
    )
  (command "CHPROP" ent "" "C" "6" "")
  (princ)
  )

@Anonymous wrote:

i do have to say thats not the main issue is wanted to solve

Maybe we should start there! 🙂 What is the "main issue"?

The code I've provided will generate the results shown on the bottom right of your screenshot. If you also want the option to generate what's shown in the top right, then we need to consider how the user will choose which one they want.

Re: offset more then 1 polyline

Anonymous — Wed, 12 Dec 2018 14:22:21 GMT

I will try to explain what I think the lisp should do.

I have 2 polylines 1 above the other.

The bottom polyline has to offset 20 42.5 and 65 mm down

and the top polyline has to offset 22.5 up and down.

The part of the bottom polyline is working fine. I need to add code for the top polyline.

Re: offset more then 1 polyline

ВeekeeCZ — Wed, 12 Dec 2018 14:59:45 GMT

(defun c:R4 ( / *error* osm pt1 pt2 ss)
  
  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break,end"))
      (princ (strcat "\nError: " errmsg)))
    (if osmode (setvar 'OSMODE))
    (princ))
  
  (setq osm (getvar 'OSMODE))
  (setvar 'OSMODE 0)
  
  (if (and (setq pt1 (getpoint "\nSpecify point below bottom: "))
	   (setq pt2 (getcorner pt1 "\nSpecify point above upper: "))
	   (setq ss (ssget "_F" (list pt1 pt2)))
	   )
    (command "_.offset" 22.5
	     (ssname ss 1) pt1
	     (ssname ss 1) pt2
	     ""
	     "_.chprop" (ssname ss 1) "" "_C" "Magenta" ""
	     "._offset" 20 (ssname ss 0) pt1 ""
	     "._offset" 42.5 (ssname ss 0) pt1 ""
	     "_.chprop" "_Last" "" "_C" "Magenta" ""
	     "._offset" 65 (ssname ss 0) pt1 ""
	     "_.chprop" (ssname ss 0) "" "_C" "Magenta" ""))
  (*error* "end")
  )

Edit: Routine was turning off osnaps and never get it back. Fixed now.

Re: offset more then 1 polyline

clindner — Wed, 12 Dec 2018 14:44:06 GMT

That helps.

It's definitely doable but would require a little more time that I can commit for developing at this point. Sorry.

I'm anxious to see what solution you end up with.

Re: offset more then 1 polyline

Anonymous — Wed, 12 Dec 2018 14:52:50 GMT

Hello BeekeeCZ,

Thank you very much it looks like this is excactly what i needed. I will run some tests with it later.

Kind regards,

Bas

Re: offset more then 1 polyline

marko_ribar — Wed, 12 Dec 2018 19:21:59 GMT

Actually, you haven't fixed it correctly...

In error handler, it should be instead of :

(if osmode (setvar 'OSMODE))

like this :

(if osm (setvar 'OSMODE osm))

Regards, M.R.