topic Re: Hatch lisp in Visual LISP, AutoLISP and General Customization Forum

Hatch lisp

Anonymous — Mon, 04 Feb 2019 11:09:01 GMT

hi!!!

can someone give me a lisp to change transparency of the hatching in the blocks please

Re: Hatch lisp

Jonathan3891 — Mon, 04 Feb 2019 13:40:37 GMT

This solution was posted here

(defun c:HT ( / aDoc tr)
     (vl-load-com)
     (setq aDoc (vla-get-ActiveDocument (vlax-get-acad-object))) 
     (if
       (progn
         (initget 132)
         (setq tr (getint "\nSpecify transparency (0-90): "))
         (cond
           ((eq (type tr) 'int)
            (if (<= 0 tr 90) (setq tr (itoa tr)))
           )
           ((eq (type tr) 'str)
            (or
              (wcmatch (strcase tr) "BYLAYER,BYBLOCK")
              (not (princ "\nInvalid value."))
            )
           )
         )
       )
       (vlax-for blk (vla-get-blocks aDoc)
         (if
           (and
             (eq :vlax-false (vla-get-islayout blk))
             (eq :vlax-false (vla-get-isxref blk))
           )
           (vlax-for itm blk
             (if
               (eq (vla-get-ObjectName itm) "AcDbHatch")
               (vla-put-entitytransparency itm tr)
             )
           )
         )
       )   
     )
     (vla-regen adoc acActiveViewport)
     (princ)
)

Re: Hatch lisp

Anonymous — Mon, 04 Feb 2019 14:53:32 GMT

thank you so much Jonathan;that's what I have been looking for some time my problem is finally resolved a thousand times thank you very much thank you

Re: Hatch lisp

Jonathan3891 — Mon, 04 Feb 2019 18:40:48 GMT

You're welcome!