topic Re: LSP: Replace Last Character with User Specified Character in Visual LISP, AutoLISP and General Customization Forum

LSP: Replace Last Character with User Specified Character

jlaidle1 — Wed, 27 Feb 2019 18:45:47 GMT

Lisp needed to replace the last character in selected text objects, with a user specified text value?

Re: LSP: Replace Last Character with User Specified Character

ronjonp — Wed, 27 Feb 2019 19:06:08 GMT

If it's just one character at the end this should do:

(setq str "MyText")
(setq newstr "Foo")
(strcat (substr str 1 (1- (strlen str))) newstr)

And the whole enchilada 🙂

(defun c:foo (/ a b s)
  (if
    (and (/= "" (setq a (getstring "\nEnter new string: "))) (setq s (ssget ":L" '((0 . "text")))))
     (foreach x	(vl-remove-if 'listp (mapcar 'cadr (ssnamex s)))
       (setq b (cdr (assoc 1 (entget x))))
       (entmod (append (entget x) (list (cons 1 (strcat (substr b 1 (1- (strlen b))) a)))))
     )
  )
  (princ)
)

Re: LSP: Replace Last Character with User Specified Character

ВeekeeCZ — Wed, 27 Feb 2019 19:06:39 GMT

(defun c:TextLastRep ( / s c i e x)

  (if (and (setq s (ssget "_:L" '((0 . "TEXT"))))
	   (setq c (getstring T "\nNew last char: "))
	   )
    (repeat (setq i (sslength s))
      (and (setq e (ssname s (setq i (1- i))))
	   (setq x (getpropertyvalue e "TextString"))
	   (setq x (substr x 1 (1- (strlen x))))
	   (setpropertyvalue e "TextString" (strcat x c)))))
  (princ)
  )

Re: LSP: Replace Last Character with User Specified Character

jlaidle1 — Wed, 27 Feb 2019 19:38:28 GMT

Works great!!!!!! Can this also work for MTEXT objects?

Our users sometimes, for some reason, use MTEXT for single line text objects.

Re: LSP: Replace Last Character with User Specified Character

ronjonp — Wed, 27 Feb 2019 19:49:54 GMT

@jlaidle1 wrote:

Works great!!!!!! Can this also work for MTEXT objects?

Our users sometimes, for some reason, use MTEXT for single line text objects.

THIS should do what you want as well .. not MTEXT though.

Re: LSP: Replace Last Character with User Specified Character

ronjonp — Wed, 27 Feb 2019 19:55:31 GMT

Here's one that will do mtext too .. although the last character in an mtext string could be part of formatting so results could get a bit wonky.

(defun c:foo (/ a b o s)
  (and (/= "" (setq a (getstring "\nEnter new string: ")))
       (setq s (ssget ":L" '((0 . "*text"))))
       (foreach	x (vl-remove-if 'listp (mapcar 'cadr (ssnamex s)))
	 (setq b (vla-get-textstring (setq o (vlax-ename->vla-object x))))
	 (vla-put-textstring o (strcat (substr b 1 (1- (strlen b))) a))
       )
  )
  (princ)
)
(vl-load-com)

Re: LSP: Replace Last Character with User Specified Character

ВeekeeCZ — Wed, 27 Feb 2019 20:12:45 GMT

This will skip the formatted MTexts with info warning.

(defun c:TextLastRep ( / s c i p e x)

  (if (and (setq s (ssget "_:L" '((0 . "*TEXT"))))
	   (setq c (getstring T "\nNew last char: "))
	   )
    (repeat (setq i (sslength s))
      (and (setq e (ssname s (setq i (1- i))))
	   (setq p (if (= "MText" (getpropertyvalue e "LocalizedName"))
		     (cond ((= (getpropertyvalue e "Text")
			       (getpropertyvalue e "Contents"))
			    "Contents")
			   ((prompt (strcat "\n'" (getpropertyvalue e "Text") "' skipped due format chars: " (getpropertyvalue e "Contents")))))
		     "TextString"))
	   (setq x (getpropertyvalue e p))
	   (setq x (substr x 1 (1- (strlen x))))
	   (setpropertyvalue e p (strcat x c)))))
  (princ)
  )

Re: LSP: Replace Last Character with User Specified Character

ronjonp — Thu, 28 Feb 2019 14:14:36 GMT

@jlaidle1 Not sure what to make of this thread. I've helped hundreds of people over the years and this is the first time I've been publicly ghosted. ( is that a thing now? )

Anyhoo ... if you're ever using an older version of CAD that does not include the get/setpropertyvalue functions included in @ВeekeeCZ 's code .. feel free to use mine as it should work.

Re: LSP: Replace Last Character with User Specified Character

rozywahana — Mon, 31 Jul 2023 14:46:05 GMT

mr @ronjonp could u help me making lsp for string-replace

;; Example usage
(setq str "abcdeeeabcdeeeabcdeee")
(setq trimmed-str (string-replace str "e" ""))
;; trimmed-str will be "abcdabcdabcd"

Re: LSP: Replace Last Character with User Specified Character

ronjonp — Mon, 31 Jul 2023 15:08:02 GMT

@rozywahana Try this:

(defun _removechar (ch str) (vl-list->string (vl-remove (ascii ch) (vl-string->list str)))) (setq str "abcdeeeabcdeeeabcdeee") (_removechar "e" str) ;; "abcdabcdabcd"

Re: LSP: Replace Last Character with User Specified Character

rozywahana — Tue, 01 Aug 2023 01:58:10 GMT

mr @ronjonp can you write it in full code
Thank you in advance

Re: LSP: Replace Last Character with User Specified Character

ronjonp — Tue, 01 Aug 2023 02:27:15 GMT

@rozywahana

Full code HERE

Remove few string at front text

rozywahana — Tue, 01 Aug 2023 03:00:39 GMT

thanks before @ronjonp

actually i mean lisp that can remove few character at front text like this,

before:

After:

Re: LSP: Replace Last Character with User Specified Character

ronjonp — Tue, 01 Aug 2023 03:14:50 GMT

I'll take a look tomorrow this is not nearly the same request a your initial

mr @ronjonp could u help me making lsp for string-replace ;; Example usage (setq str "abcdeeeabcdeeeabcdeee") (setq trimmed-str (string-replace str "e" "")) ;; trimmed-str will be "abcdabcdabcd"