topic Re: oldie but goody neds new shoes! in Visual LISP, AutoLISP and General Customization Forum

oldie but goody neds new shoes!

DC-MWA — Mon, 04 Mar 2019 20:50:46 GMT

I have a great little routine I've been using since the early nineties.

It re-inserts blocks by picking the desired block. (matching layer, scale, etc).

Works great, doesnt work on dynamic / anonymous blocks.

Wondering if anyone out there has something similar that will work with regular blocks and dynamic blocks?

Or if there is an easy solution to make this one work.

I have attached lisp.

Re: oldie but goody neds new shoes!

Kent1Cooper — Mon, 04 Mar 2019 22:10:04 GMT

Am I right that it's Inserting another on the same Layer and at the same scale, with the only difference being a new insertion point and rotation? How about just Copying it and Rotating the copy? Minimally tested:

(defun c:gb (/ ent entlst)
  (while (not (setq ent (entsel "\nSelect block to re-insert: "))))
  (setq entlst (entget (setq ent (car ent))))
  (if (= (cdr (assoc 0 entlst)) "INSERT")
    (command ; then
      "_.copy" ent "" "_none" (cdr (assoc 10 entlst)) pause
      "_.rotate" "_last" "" "@" "_reference"
        (angtos (cdr (assoc 50 entlst)) (getvar 'aunits) 8)
        pause
    ); command
    (prompt "\nThis entity is not a block!"); else
  ); if
  (princ)
); defun

Re: oldie but goody neds new shoes!

DC-MWA — Thu, 07 Mar 2019 20:55:17 GMT

Sorry for delay. I just gt back to the office.

Thanks for your time.

I'll be back to "programming" this weekend.

Re: oldie but goody neds new shoes!

dbhunia — Mon, 11 Mar 2019 08:24:15 GMT

You also can try this.......

(defun c:gb (/ cmd clay ent entlst nlay OLDLAYER SB)
 (setq cmd (getvar "cmdecho"))
 (while (/= "INSERT" (cdr (assoc 0 (entget (setq ent (car (entsel "\nSelect block to re-insert: ")))))))
        (prompt "\nThis entity is not a block!")
 )
 (if (= (cdr (assoc 0 (setq entlst (entget ent)))) "INSERT")
  (progn 
   (if (= :vlax-true (vla-get-IsDynamicBlock (vlax-ename->vla-object ent)))
       (Setq SB (vla-get-Effectivename (vlax-ename->vla-object (cdr (assoc -1 entlst)))))
       (Setq SB (cdr (assoc 2 entlst)))
   )
   (setvar "cmdecho" 1)
   (command "_.insert" SB "scale" (cdr (assoc 41 entlst)) pause pause)
   (setvar "cmdecho" 0)
   (command "_.chprop" (entlast) "" "LA" (cdr (assoc 8 entlst)) "")
  )
 )
 (setvar "cmdecho" cmd)
 (princ)
)