topic Re: Dialog box in LISP as when using native commands in Visual LISP, AutoLISP and General Customization Forum

Dialog box in LISP as when using native commands

jw9VSWM — Fri, 13 Sep 2024 15:10:16 GMT

Hi,

I'm using the native layout command in a LISP to control the folder destination. I have managed this somewhat via:

command "_.layout" "Template" selected-file

The first layout command gives me a pop-up window in the correct folder, but i get a textbox instead of a dialog box for layout choices. In other words. I would like the same effect as when using the button in the layout ribbon, not -layout "t".

Re: Dialog box in LISP as when using native commands

Kent1Cooper — Fri, 13 Sep 2024 15:20:37 GMT

If I understand correctly:

(initdia)
(command "_.layout" "_template")

Re: Dialog box in LISP as when using native commands

jw9VSWM — Fri, 13 Sep 2024 18:43:18 GMT

It did not help with the (initdia) unfortunately.

Here is my code:

(defun c:LayoutTemplate ()

(command "filedia" "1")
(setq folder "C:/Program Files/company name ACAD/") ;define folder location

(setq selected-file (getfiled "Select a Template File" folder "dwt" 16)) ;select .dwt template

(if selected-file
(progn
(princ (strcat "\nSelected file: " selected-file))

      (initdia)
      (command "._layout" "_Template" selected-file "")
      (princ "\nLayout import complete."))
(princ "\nNo file selected."))

I would like to get the dialog box for "insert Layouts" (image attached) that you get when using the layout from template button in the ribbon.

Is this possible through lisp?

Re: Dialog box in LISP as when using native commands

Kent1Cooper — Fri, 13 Sep 2024 19:21:06 GMT

Try this:

(initcommandversion)

(command "._layout" "_Template" selected-file)

Or maybe:

(initcommandversion)

(command-s "._layout" "_Template" selected-file)

Re: Dialog box in LISP as when using native commands

ВeekeeCZ — Sat, 14 Sep 2024 11:36:17 GMT

This combo works.

(setvar 'filedia 0)

(initcommandversion)

(command "layout" ...)

Edit: Not sure what's your ultimate goal, but I would prefer to use the built-in dialog over the getfile.

(defun c:LayoutTemplate ( / *error* o)
  
  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break,end"))
      (princ (strcat "\nError: " errmsg)))
    (if o (setenv "TemplatePath" o))
    (princ))
  
  (setq o (getenv "TemplatePath"))
  (setenv "TemplatePath" "c:/FilePath/Template/")
  (initdia)
  (command-s "_.layout" "_t")
  (setenv "TemplatePath" o)
  (princ)
  )

Re: Dialog box in LISP as when using native commands

Sea-Haven — Sat, 14 Sep 2024 02:01:53 GMT

If you know the name of the layouts inside the template dwt, then it can be done very easy.

If you have different DWT and hence different layout names then just use a cond to set the correct list of layout names.

(if (not AH:Butts)(load "Multi radio buttons.lsp")) (setq lst (list "please select " "A0_Landscape" "A1_Landscape" "A1_Portrait" "A2_Landscape" "A2_Portrait" "A3_Landscape")) (setq layname (ah:butts 2 "V" lst)) (command "layout" "T" masterlayouts layname) (setvar 'ctab layname) (command "pspace")

Re: Dialog box in LISP as when using native commands

paullimapa — Sat, 14 Sep 2024 20:26:10 GMT

another way to bring up file selection window is by using the symbol: ~

(command-s "_.layout" "_t" "~")

Re: Dialog box in LISP as when using native commands

jw9VSWM — Sun, 15 Sep 2024 13:39:01 GMT

Worked like a charm.

(initcommandversion)
(command "._layout" "_Template" selected-file)