topic Re: Code doesn't work on coworker's computer in Autocad 18 OR 16 in Visual LISP, AutoLISP and General Customization Forum

Code doesn't work on coworker's computer in Autocad 18 OR 16

Anonymous — Wed, 17 Apr 2019 20:02:14 GMT

I have a fairly simple program that takes some user input and draws fairly basic shapes, dimensions, adds text etc.

Every computer I have tested it on works completely fine except for one coworker's. He has both Acad 18 and 16 installed on the computer and it does not work on either of them.

I simplified the program to calculate some basic points that form rectangles from user inputted width and height, and draw Plines to these points and close. The first pline always draws correct, but the second pline never does. When I double check the point values, the points are calculated correctly but it does not draw to them (j1-4).

Does anyone have any idea of a setting that would cause subsequent Plines to not draw to the points that are given to it?

As I stated earlier, this only has happened on one users computer and it does a similar behavior between different versions of AutoCAD.

; Set First Clear Opening Point on Click
(setq c1 (getpoint "\nSelect Insertion Point:"))

;Calculate Clear Opening Points
(setq c2 (polar c1 (dtr 0) width))
(setq c3 (polar c2 (dtr 90) height))
(setq c4 (polar c3 (dtr 180) width))

;Calculate Jamb Points
(setq j1 (polar c1 (dtr 180) 2))
(setq j2 (polar j1 (dtr 0) (+ width 4)))
(setq j3 (polar j2 (dtr 90) (+ height 2)))
(setq j4 (polar j3 (dtr 180) (+ width 4)))

;Draw Clear Opening
(command "._PLINE" c1 c2 c3 c4 "c")

;Draw Jamb
(command "._PLINE" j1 j2 j3 j4 "c")

Betreff: Code doesn't work on coworker's computer in Autocad 18 OR 16

cadffm — Wed, 17 Apr 2019 20:20:19 GMT

You knowing that there is a command that can draw a closed polyline by w&h?

Rectang

Ok, you are using native autocad commands to create your pline,

in this case you have to controle the objectsnap.

Set osnapcoord to 1 in your lisp first,

or add "_non" in front of every coordinate input in your command sequence.

Or handle with osmode setting, but think about re-set the original value, also in case of errors.

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

tcorey — Wed, 17 Apr 2019 21:30:16 GMT

Try this:

(defun c:test ()
(setq cosmode (getvar "OSMODE"))
(setvar "OSMODE" 0)
(setq width (getreal "\nEnter width: "))
(setq height (getreal "\nEnter height: "))
; Set First Clear Opening Point on Click
(setq c1 (getpoint "\nSelect Insertion Point:"))
 
;Calculate Clear Opening Points
(setq c2 (polar c1 0 width))
(setq c3 (polar c2 (/ pi 2) height))
(setq c4 (polar c3 pi width))
 
;Calculate Jamb Points
(setq j1 (polar c1 pi 2))
(setq j2 (polar j1 0 (+ width 4)))
(setq j3 (polar j2 (/ pi 2) (+ height 2)))
(setq j4 (polar j3 pi (+ width 4)))
 
;Draw Clear Opening
(command "._PLINE" c1 c2 c3 c4 "c")
;Draw Jamb
(command "._PLINE" j1 j2 j3 j4 "c")
(setvar "OSMODE" cosmode)
(princ)
)

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

scot-65 — Wed, 17 Apr 2019 22:07:21 GMT

Have you tried:
;Draw Clear Opening
(command "._PLINE" "_non" c1 "_non" c2 "_non" c3 "_non" c4 "c")

;Draw Jamb
(command "._PLINE" "_non" j1 "_non" j2 "_non" j3 "_non" j4 "c")

Or:
before drawing the lines
(if (< (getvar "OSMODE") 16384) (setvar "OSMODE" (+ (getvar "OSMODE") 16384)))
after drawing the lines
(if (> (getvar "OSMODE") 16384) (setvar "OSMODE" (- (getvar "OSMODE") 16384)))

What is this?
It turns off OSMODE and if an error occurs, the user can simply
click on the button in the status line to turn back on.

???

Betreff: Code doesn't work on coworker's computer in Autocad 18 OR 16

Anonymous — Mon, 22 Apr 2019 18:28:28 GMT

The code already has snap control built in so this is not it. It is not snapping to existing lines, they are specific points in space that are reproduce-able and the same every time.

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

Anonymous — Mon, 22 Apr 2019 18:40:06 GMT

I should have stated that i disable snapping in the code. I did not paste the whole code just the portion asking for input and then drawing. The lines it creates do not snap to existing entities, they are drawn to specific points in space that are the same every time. The points are not the points that I direct the lines to draw to.

I have attached the actual code that I have tried to run. This is simplified down to the bare bones and still refuses to draw to the correct points on only one user's computer. I do not know the system variable that is doing this. The first lines draw correctly (c1-4), and the following ones do not (j1-4). When I check the points j1-4, they are calculated correctly.

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

CodeDing — Mon, 22 Apr 2019 20:29:36 GMT

@Anonymous ,

Just fyi, both plines ARE being created when using your posted LISP...

What units are you using by chance? I use architectural, and from a distance mine APPEARS to be perfectly overlapped (they're not). But when I create a smaller version they are clearly not overlapped..

Architectural (large distances)Architectural (small distances)

Best,

~DD

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

Anonymous — Tue, 23 Apr 2019 14:57:15 GMT

They should not be overlapping as shown below. The issue on my coworker's computer is not that both lines don't get drawn. The inner box always draws correctly with the correct width and correct locations. The second polyline does not draw correctly (and subsequent mtexts, dimensions, etc do not draw correctly). It should draw to points j1-4 but it does not, even though when I look at the j1-4 values they are correct.

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

CodeDing — Tue, 23 Apr 2019 15:20:02 GMT

@Anonymous ,

It appears your code is drawing exactly as you state it to be..

For J points (assuming default direction is set to EAST, and COUNTERCLOCKWISE direction)..

What is the desired end-state you are looking for?

Best,

~DD

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

Anonymous — Tue, 23 Apr 2019 15:20:55 GMT

I have tested this on over 10 computers and it works correctly on all but one of them. Both Autocad 2018 AND Autocad 2016 are installed on this computer and it does not work in either version. There must be a system variable enabled on his computer that is causing this but I have had no luck after days of research.

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

Anonymous — Tue, 23 Apr 2019 15:26:57 GMT

This is what it looks like on the problem computer running the exact same code that I uploaded. The points j1-j4 were calculated correctly and have the correct values stored in these. The second polyline does not draw to these points.

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

CodeDing — Tue, 23 Apr 2019 15:29:11 GMT

@Anonymous ,

Try comparing these 2 between the "good" computers and the "bad" computer:

ANGDIR

ANGBASE

Best,

~DD

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

Anonymous — Tue, 23 Apr 2019 15:40:22 GMT

They are both 0 on both machines

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

CodeDing — Tue, 23 Apr 2019 15:54:43 GMT

@Anonymous ,

Can you.. turn off your OSNAPS, copy/paste this into your command line, then select a point, and post the results?

(progn
(setq width 4.0 height 4.0)
(setq c1 (getpoint "\nSelect Point: "))
(setq c2 (polar c1 0.0 width))
(setq c3 (polar c2 (* 0.5 pi) height))
(setq c4 (polar c3 pi width))
(setq j1 (polar c1 pi 2.0))
(setq j2 (polar j1 0.0 (+ width 4.0)))
(setq j3 (polar j2 (* 0.5 pi) (+ height 2.0)))
(setq j4 (polar j3 pi (+ width 4.0)))
(command "._PLINE" c1 c2 c3 c4 "c")
(command "._PLINE" j1 j2 j3 j4 "c"))

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

Anonymous — Tue, 23 Apr 2019 17:26:27 GMT

This seemed to work so I changed the code to use radians instead of the dtr function as shown in the attached and it still does not work as expected. Next I hard coded the width and height values and it still didn't work.

What is the difference in the way the code is working vs copy pasting this directly into the command line?

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

CodeDing — Tue, 23 Apr 2019 18:12:09 GMT

@Anonymous ,

Try using reals instead of integers.. That was the other thing I changed. I have attached it.

Best,

~DD

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

Anonymous — Tue, 23 Apr 2019 18:33:54 GMT

Wasn't it either. See image below. This is truly mind boggling.

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

Anonymous — Tue, 23 Apr 2019 18:46:04 GMT

The points j1 through j4 are all what is expected when i type in !j1 etc.

j1 = -2,0

j2 = 44,0

j3 = 44,86

j4 = -2,86

These are the points that it ACTUALLY draws to.

*j2 and j3 should read w+2 not 2w+2

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

ronjonp — Tue, 23 Apr 2019 20:28:04 GMT

Maybe try this ( lightly tested and not sure what the result should look like )... removes command calls and POLAR.

(defun c:foo (/ _addlwpolyline a c c1 d height j1 j2 j3 j4 width)
  (defun _addlwpolyline	(layer width ptlst 0or1)
    (entmakex (apply 'append
		     (list (list '(0 . "LWPOLYLINE")
				 (cons 100 "AcDbEntity")
				 (cons 8 layer)
				 (cons 100 "AcDbPolyline")
				 (cons 90 (length ptlst))
				 (cons 43 width)
				 (cons 38 (caddr (trans '(0 0 0) 1 (trans '(0. 0. 1.) 1 0))))
				 (cons 70 0or1)
			   )
			   (mapcar (function (lambda (x) (list 10 (car x) (cadr x)))) ptlst)
			   (list (cons 210 (trans '(0. 0. 1.) 1 0)))
		     )
	      )
    )
  )
  (cond	((setq c1 (getpoint "\nSelect Insertion Point:"))
	 (setq a c1)
	 (setq width 42.0)
	 (setq height 84.0)
	 (setq c (list '(0 0 0) (list width 0 0) (list 0 height 0) (list (- width) 0 0)))
	 (setq d
		(list '(-2 0 0) (list (+ width 4) 0 0) (list 0 (+ height 2) 0) (list (- (+ width 4)) 0 0))
	 )
	 (_addlwpolyline "DOOR" 0 (mapcar '(lambda (x) (setq a (mapcar '+ a x))) c) 1)
	 (_addlwpolyline "DOOR" 0 (mapcar '(lambda (x) (setq c1 (mapcar '+ c1 x))) d) 1)
	)
  )
  (princ)
)

Re: Code doesn't work on coworker's computer in Autocad 18 OR 16

CodeDing — Tue, 23 Apr 2019 21:23:05 GMT

@Anonymous ,

Here's my go at it..

(defun c:ENTRANCEELEVATION ( / osm lyr w h pBase pTmp)
;Store vars
(setq osm (getvar 'OSMODE) lyr (getvar 'CLAYER))
;Get user input
(initget 7) (setq w (getdist "\nEnter Entrance Width: "))
(initget 7) (setq h (getdist "\nEnter Entrance Height: "))
(initget 1) (setq pBase (getpoint "\nSelect Insertion Point: ")) (princ pBase)
;Prep for drawing
(setq pTmp (list (+ w (car pBase)) (+ h (cadr pBase))))
(setvar 'OSMODE (logior 16384 osm)) (setvar 'CLAYER "DOOR")
;Draw
(command "_.RECTANG" pBase pTmp);inner
(setq pBase (list (- (car pBase) 2.0) (cadr pBase))
      pTmp (list (+ 2.0 (car pTmp)) (+ 2.0 (cadr pTmp))))
(command "_.RECTANG" pBase pTmp);outer
;Restore & Finish
(setvar 'OSMODE osm) (setvar 'CLAYER lyr)
(prompt "Complete...")
(princ)
);defun

Best,

~DD