topic Re: select xrefs but exclude a few using wildcards?? in Visual LISP, AutoLISP and General Customization Forum

select xrefs but exclude a few using wildcards??

DC-MWA — Thu, 18 Apr 2019 20:09:44 GMT

Hello,

I have a cool little routine we use within our acaddoc that sets all xrefs to relative paths.

Several users are having trouble with the titleblocks which are linked to our server.

I'm trying to remove xrefs named *tb*dwg and *titleblock*.dwg from the selection set.

I have attached the lisp in question.

Thanks in advance for any input.

Re: select xrefs but exclude a few using wildcards??

Moshe-A — Thu, 18 Apr 2019 21:08:56 GMT

@DC-MWA hi,

here is my version (untested)

enjoy

moshe

(defun xr_relpath (/ findxref verify_name ;| local functions |;)
  
 (defun findxref (/ td xrf)
  (while (setq td (tblnext "block" (not td)))
   (and (= (logand (cdr (assoc 70 td)) 4) 4)
        (setq xrf (cons (strcase (cdr (assoc 2 td))) xrf))
   )
  )

  xrf
 ); findxref


 (defun verify_name (/ exclude ; local function
		       bname)
   
  (defun exclude ()
   (vl-remove-if
    'not
     (mapcar
      '(lambda (bn)
         (if (and
               (wcmatch (strcase bn) "~*TB*")
               (wcmatch (strcase bn) "~*TITLEBLOCK*")
               (wcmatch (strcase bn) "~*STAMP")
             )
          bn
         )
       ); lambda
       (findxref) 
      ); mapcar
   ); vl-remove-if
  ); exclude

  (setq bname "") 
  (foreach bn (exclude)
   (setq bname (strcat bname bn ","))
  )

  ; remove last comma
  (substr bname 1 (1- (strlen bname)))
 ); verify_name

  
 (if (findxref)
  (progn
   (princ "\nMaking xref paths relative...")
   (setvar "cmdecho" 0)
   (command "-xref" "t" (verify_name) "r")
   (setvar "cmdecho" 1)
  );end pr
  (progn
   (Princ "\nNo xrefs found in drawing")
  );end pr
 );end if
  
 (princ)
)

Re: select xrefs but exclude a few using wildcards??

Moshe-A — Thu, 18 Apr 2019 21:22:12 GMT

or a little more shorter

(defun xr_relpath (/ findxref verify_name ;| local functions |;)
  
 (defun findxref (/ td xrf)
  (while (setq td (tblnext "block" (not td)))
   (and (= (logand (cdr (assoc 70 td)) 4) 4)
        (setq xrf (cons (strcase (cdr (assoc 2 td))) xrf))
   )
  )

  xrf
 ); findxref

 (defun verify_name ()
  (apply
   'strcat
   (vl-remove-if
    'not
     (mapcar
      '(lambda (bn)
        (if (and
               (wcmatch (strcase bn) "~*TB*")
               (wcmatch (strcase bn) "~*TITLEBLOCK*")
               (wcmatch (strcase bn) "~*STAMP")
            )
        (strcat bn ",")
       )
      ); lambda
     (findxref) 
    ); mapcar
   ); vl-remove-if
  ) 
 ); verify_name
  
 (if (findxref)
  (progn
   (princ "\nMaking xref paths relative...")
   (setvar "cmdecho" 0)
   (command "-xref" "t" (verify_name) "r")
   (setvar "cmdecho" 1)
  );end pr
  (progn
   (Princ "\nNo xrefs found in drawing")
  );end pr
 );end if
  
 (princ)
)

Re: select xrefs but exclude a few using wildcards??

DC-MWA — Thu, 18 Apr 2019 21:28:37 GMT

that works great!

thank you!