topic Re: Select and filter blocks with unique attributed text in Visual LISP, AutoLISP and General Customization Forum

Select and filter blocks with unique attributed text

kheck6VR8C — Sun, 05 May 2019 16:55:42 GMT

I'm not sure if anyone can help but I have been researching and trying to find a lisp routine where you can select entire drawing and it will filter out and select only the blocks with unique attributed text. For example, the block is called D-LIST-WATER but the attribute ID may have V4, V8 for water valves. There are several of these callouts but I want to be able to select all of them but have it filter out only one V4 and V8.

Ideally, it would be great if it can filter out these call outs and put it in a key note list that we can place on the sheets but filtering out the attributes would work as well.

Does anyone have any suggestions or a lisp routine that can do this?

Re: Select and filter blocks with unique attributed text

ВeekeeCZ — Sun, 05 May 2019 17:20:16 GMT

The FIND command is not enough for you?

Search for "V[48]" check field List of values, Use wildcards, Search blocks, Block Att Value

See the SCREENCAST

See HELP of wildcards.

Re: Select and filter blocks with unique attributed text

kheck6VR8C — Sun, 05 May 2019 18:31:25 GMT

Obviously, the find command will not select all the blocks with unique or the same attributes so I'm not sure what the "find isn't good enough" was about because that is not what I am trying to accomplish. Again, I am trying to select all of the blocks that have unique attributes such as, only one block with V4, one with V6, one with T4, one with T6...etc. This is so we can pull out these callouts without having to sort through what's there and not.

Re: Select and filter blocks with unique attributed text

ВeekeeCZ — Sun, 05 May 2019 18:47:07 GMT

Missed the work 'unique', obviously. So FIND is not enough, got it.

So collect unique att values across all tags of all blocks in the drawing, right? Or exclude all that are more than once.

Re: Select and filter blocks with unique attributed text

kheck6VR8C — Sun, 05 May 2019 18:52:40 GMT

Yes, select all the unique attribute values across all tags of all blocks and exclude the ones that are duplicated attribute valves for those blocks. That way, I can pull the unique attribute values and organize them into a call out list for the sheets. If I can select only the blocks that has the unique values, then I don't need to thumb thru the entire drawing trying to remember what call out numbers were used.

Re: Select and filter blocks with unique attributed text

ВeekeeCZ — Sun, 05 May 2019 19:59:32 GMT

OK, hope I understood you better now. Try and see.

All blocks in current space only. Cannot hold the active selection set across layouts.

(vl-load-com)

(defun c:SelectAttUnique (/ ss i en em lst at as sn)
  
  (if (setq ss (ssget "_X" (list '(0 . "INSERT") '(66 . 1) (cons 410 (getvar 'ctab)))))
    (progn
      (repeat (setq i (sslength ss))
	(setq en (ssname ss (setq i (1- i)))
	      em en)
	(while (= "ATTRIB" (cdr (assoc 0 (entget (setq em (entnext em))))))
	  (setq at (cdr (assoc 1 (entget em)))
		lst (if (setq as (assoc at lst))
		      (subst (list at)
			     as
			     lst)
		      (cons (list at en) lst)))))
      (setq sn (ssadd))
      (foreach e (vl-remove-if-not '(lambda (x) (= (length x) 2)) lst)
	(ssadd (cadr e) sn))
      (if (> (sslength sn) 0)
	(sssetfirst nil sn))))
  (princ)
  )

Re: Select and filter blocks with unique attributed text

kheck6VR8C — Sun, 05 May 2019 20:02:39 GMT

Thank you, I briefly tested it and it seems to me working but I'll look at it more later. Is there a way where it will allow you to "select" all the blocks in the drawing manually instead of selecting it for you automatically?

I really appreciate your help!

Re: Select and filter blocks with unique attributed text

ВeekeeCZ — Sun, 05 May 2019 20:06:59 GMT

Just remove the "_X".

SSGET is the function that makes the selection. Look HERE for more details if you're interested.

Re: Select and filter blocks with unique attributed text

Moshe-A — Sun, 05 May 2019 20:32:34 GMT

@kheck6VR8C hi,

Here is my version. command FLRBLK (filter blocks)

it will pause at:

Attribute value to scan:

your reply could be any attribute value or you can specify a wild-card pattern match the same as may specified in

>> (wcmatch) << function

enjoy

moshe

(vl-load-com)

(defun c:flrblk (/ scan_attrib ; local function
		   pattern ss0 ss1 AcDbBlockReference attributes^)
  
 (defun scan_attrib ()
  (vl-some
   '(lambda (AcDbAttrib)
     (wcmatch (vla-get-textString AcDbAttrib) pattern)
    )  
   attributes^
  )
 ); scan_attrib
  
 (if (and
       (/= (setq pattern (getstring "\nAttribute value to scan: ")) "")
       (setq ss0 (ssget "_x" '((0 . "insert") (66 . 1))))
     )
  (progn 
   (setq ss1 (ssadd))
   
   (foreach ename (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss0)))
    (setq AcDbBlockReference (vlax-ename->vla-object ename))
    (setq attributes^ (vlax-invoke AcDbBlockReference 'GetAttributes))
    (if (scan_attrib)
     (ssadd ename ss1)
    )

    (foreach obj attributes^
     (vlax-release-object obj)
    )

    (vlax-release-object AcDbBlockReference) 
   ); foreach

   (sssetfirst nil ss1)
  ); progn 
 ); if

 (princ) 
); c:fltblk

Re: Select and filter blocks with unique attributed text

Sea-Haven — Mon, 06 May 2019 01:46:02 GMT

You can replace the

(getstring "\nAttribute value to scan: ")

With a nentsel that returns the attribute value you are looking for, so becomes a pick option, can make it loop so look for more than 1 attribute value.

(setq pattern (cdr (assoc 1 (entget (car(nentsel "select attribute"))))))

Re: Select and filter blocks with unique attributed text

Moshe-A — Mon, 06 May 2019 05:12:57 GMT

@Sea-Haven hi,

and what if the attribute value i'm looking is off screen and i do not know where it exist?

beside that, the pattern that you specifies for (wcmatch) is not always the attribute value.

moshe

Re: Select and filter blocks with unique attributed text

kheck6VR8C — Mon, 06 May 2019 11:23:50 GMT

Thanks, the code below does exactly what I want where you can select everything in the drawing and filter out the unique values. But, to take it one step further, is there a way that you can take the blocks that are selected based upon the attribute value and have the blocks automatically stacked in a list format, in alphabetical order based upon the attribute value? The code only selects the blocks randomly and I need to manually stack them by moving them.

(vl-load-com)

(defun c:SelectAttUnique (/ ss i en em lst at as sn)

(if (setq ss (ssget (list '(0 . "INSERT") '(66 . 1) (cons 410 (getvar 'ctab)))))
    (progn
      (repeat (setq i (sslength ss))
(setq en (ssname ss (setq i (1- i)))
       em en)
(while (= "ATTRIB" (cdr (assoc 0 (entget (setq em (entnext em))))))
   (setq at (cdr (assoc 1 (entget em)))
  lst (if (setq as (assoc at lst))
        (subst (list (list at))
        as
        lst)
        (cons (list at en) lst)))))
      (setq sn (ssadd))
      (foreach e (vl-remove-if-not '(lambda (x) (= (length x) 2)) lst)
(ssadd (cadr e) sn))
      (if (> (sslength sn) 1)
(sssetfirst nil sn))))
(princ)
)

Re: Select and filter blocks with unique attributed text

ВeekeeCZ — Mon, 06 May 2019 11:43:50 GMT

Never mind.

Re: Select and filter blocks with unique attributed text

kheck6VR8C — Mon, 06 May 2019 11:53:12 GMT

I attached a drawing to show the before and after of what I am trying to do. Hope that helps

Re: Select and filter blocks with unique attributed text

kheck6VR8C — Mon, 06 May 2019 11:55:42 GMT

Sorry, the T1 and T3 aren't shown in alphabetic order in the example

Re: Select and filter blocks with unique attributed text

ВeekeeCZ — Mon, 06 May 2019 12:29:01 GMT

@ВeekeeCZ wrote:

...

So collect unique att values across ~~all~~ tags ID only of all blocks in the drawing, right? Or exclude all that are more than once.

From your DWG I see that I should fix my previous statement!!!

Re: Select and filter blocks with unique attributed text

kheck6VR8C — Mon, 06 May 2019 12:35:37 GMT

Yes, collect all the unique attribute across all blocks and exclude the ones that are duplicates. The code you wrote did exactly that but it would be helpful to put them in a list format. Basically, what I do with your code is once they are all selected based upon the attribute unique value, I copy them to off to the side so I can organize them into a list and then I'll take that list and put them onto the sheet for our call out list. By having them automatically placed in a list format in alphabetical order, it would eliminate the step of moving and organizing them into a list.

Re: Select and filter blocks with unique attributed text

ВeekeeCZ — Tue, 07 May 2019 10:00:20 GMT

@kheck6VR8C wrote:

Yes, collect all the unique attribute across all blocks and exclude the ones that are duplicates. The code you wrote did exactly that...

If I tell you that is not good enough, believe me. I wrote the routine...

Anyway, the following code includes two routines.

The moving part is taken from @Kent1Cooper's routine in other thread... and little modified by me.

(vl-load-com)

(defun c:SortUniqueBlks (/ *error* :addzero doc ss i en em lst val ass sn n blk minpt maxpt LL insX refY ins0)
  
  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break,end"))
      (princ (strcat "\nError: " errmsg)))
    (vla-endundomark doc)
    (princ))
  
  (defun :addzero (s / n a)
    (setq n (substr s (1+ (strlen (setq a (vl-string-right-trim "0123456789" s))))))
    (strcat a (cond ((= (strlen n) 1) "00") ((= (strlen n) 2) "0") ("")) n))

  ; -------------------------------------------------------------------------------------------------
  
  (if (setq ss (ssget (list '(0 . "INSERT") '(66 . 1) (cons 410 (getvar 'ctab)))))
    (progn
      (repeat (setq i (sslength ss))
        (setq en (ssname ss (setq i (1- i)))
              em en)
        (while (= "ATTRIB" (cdr (assoc 0 (entget (setq em (entnext em))))))
          (if (= "ID" (cdr (assoc 2 (entget em))))
            (setq val (cdr (assoc 1 (entget em)))
                  lst (if (setq ass (assoc val lst))
                        (subst (list (list val))
                               ass
                               lst)
                        (cons (list val en) lst))))))
      (setq sn (ssadd))
      (foreach e (vl-sort (vl-remove-if-not '(lambda (x) (= (length x) 2)) lst)
                          (function (lambda (a b) (< (:addzero (car a)) (:addzero (car b))))))
        (ssadd (cadr e) sn))
      
      (if (> (sslength sn) 0)
        (progn
          (vla-startundomark (setq doc (vla-get-activedocument (vlax-get-acad-object))))
          (repeat (setq n (sslength sn))
            (setq blk (ssname sn (setq n (1- n))))
            (vla-getboundingbox (vlax-ename->vla-object blk) 'minpt 'maxpt)
            (setq LL (vlax-safearray->list minpt))
            (if insX
              (progn
                (command "_.move" blk ""
                         "_none" (list (cadr (assoc 10 (entget blk))) (cadr LL))
                         "_none" (list insX (+ refY 0)))
                (vla-getboundingbox (vlax-ename->vla-object blk) 'minpt 'maxpt)
                (setq refY (cadr (vlax-safearray->list maxpt))); move refY up
                )
              (setq insX (cadr (assoc 10 (entget blk)))
                    refY (cadr (vlax-safearray->list maxpt))
                    ins0 (list insX (cadr LL)))))
          (command-s "_.move" sn "" "_non" ins0)
          (*error* "end")))))
  (princ)
  )



(defun c:SelectUniqueBlks (/ :addzero doc ss i en em lst val ass sn)
   
  (defun :addzero (s / n a)
    (setq n (substr s (1+ (strlen (setq a (vl-string-right-trim "0123456789" s))))))
    (strcat a (cond ((= (strlen n) 1) "00") ((= (strlen n) 2) "0") ("")) n))

  ; -------------------------------------------------------------------------------------------------
  
  (if (setq ss (ssget (list '(0 . "INSERT") '(66 . 1) (cons 410 (getvar 'ctab)))))
    (progn
      (repeat (setq i (sslength ss))
        (setq en (ssname ss (setq i (1- i)))
              em en)
        (while (= "ATTRIB" (cdr (assoc 0 (entget (setq em (entnext em))))))
          (if (= "ID" (cdr (assoc 2 (entget em))))
            (setq val (cdr (assoc 1 (entget em)))
                  lst (if (setq ass (assoc val lst))
                        (subst (list (list val))
                               ass
                               lst)
                        (cons (list val en) lst))))))
      (setq sn (ssadd))
      (foreach e (vl-sort (vl-remove-if-not '(lambda (x) (= (length x) 2)) lst)
                          (function (lambda (a b) (< (:addzero (car a)) (:addzero (car b))))))
        (ssadd (cadr e) sn))
      
      (if (> (sslength sn) 0)
        (progn
          (command "_.regen")
          (sssetfirst nil sn)))))
  (princ)
  )

Re: Select and filter blocks with unique attributed text

kheck6VR8C — Tue, 07 May 2019 10:59:13 GMT

Thank you, I really appreciate your help. I was testing it and it did do exactly what I wanted it to but there were a couple of things it was doing that I noticed which I'm not sure if you knew why.

First one, when I copy the block or multiple blocks with the same or different attribute values from one location to another, it wont select them after that. It's almost acting like, you can only use it one time and then the lisp wont select the unique attributes again.

The second one, when it does work, it is cutting them instead of coping them to the stacked location. Sometimes it wont cut them but most of the time, it removes them from the location they were originally placed at. It removes them about 98% of the time and that would create a problem when you have them placed throughout the fitting locations in model space.

The third one, it doesn't always select all of the unique attributes; it may select some or all, not sure why. I was having it not select some fittings and I am not sure if because the blocks are being copied with the same attribute values and it's not being regenerated or refreshed thus ignoring those values as being unique or if its something else causing it.

What's your thoughts? I know this lisp would be a great tool and really useful to a lot of people who use callouts with unique attribute values so it would be great to have it work. Thanks again for your help!

Re: Select and filter blocks with unique attributed text

kheck6VR8C — Tue, 07 May 2019 11:58:41 GMT

I'm not sure if this helps in troubleshooting but it seems like instead of coping the selecting items, it is selecting and moving random blocks to a stacked format. Again, after coping several blocks of different attribute values, the lisp stops working until I change one attribute value and run the lisp again, then it adds one or two blocks to the stacked list but again, not all. Then, when I change another attribute value, it adds more blocks to the stack list until all of them appear. But, again, its moving the blocks to the stacked list instead of coping them. Hope that helps.