topic Re: Recursive construction of associated list in Visual LISP, AutoLISP and General Customization Forum

Recursive construction of associated list

giuseppebeatrice222 — Wed, 15 May 2019 10:05:15 GMT

I read a very interesting forum in https://forums.autodesk.com/t5/visual-lisp-autolisp-and-general/recursive-assoc-and-subst/m-p/7823584?collapse_discussion=true&page=2&q=nested%20association%20list&search_type=thread

where Gile gave an optimum explanation and a solution to a question regarding the search of associated values and the substitution of values in nested association lists.

Now I have a subsequente question, of how making from the scratch a nested association list, giving a key list and the final, nested value.

For example, if I want to assign to the variable al a nested association list (setq al '(("GRP1" ("A" (2 (21 . "b")))))) is it possible to construct a recursive function of the tipe (MAKEORSUBST (list "GRP1" "A" 2) '(21 . "b"))

In addition, if I have fixed the preceding value for al and I want to add a new value (22 . "c") to the inner value (21 . "b") with the last key 2, can I obtain the result with a command of type (MAKEORSUBST (list "GRP1" "A" 2) '(22 . "c"))?

I have made numerous attempts to construct such a function on the basis of the functions provided by Gile in that forum, but with no results.

Please, can Gile himself or someone other give me a help?

Thanks in advance

Re: Recursive construction of associated list

ВeekeeCZ — Wed, 15 May 2019 10:43:06 GMT

OT. If you want to draw someone's attention you can use the @ character to do that: @_gile

Then he receives an email that he was mentioned by someone.

Re: Recursive construction of associated list

ronjonp — Wed, 15 May 2019 13:39:13 GMT

HERE is some code by master ElpanovEvgeniy.

Another thread HERE to flatten lists by master MP 🙂

Re: Recursive construction of associated list

_gile — Wed, 15 May 2019 15:02:56 GMT

Hi,

The makeorsubst function also need an argument for the exisitng list/tree (nil if none)

(defun makeorsubst (keys val lst / sub)
  (cond
    ((null keys)
     (if (setq sub (assoc (car val) lst))
       (subst val sub lst)
       (cons val lst)
     )
    )
    ((setq sub (assoc (car keys) lst))
     (subst (cons (car keys)
		  (makeorsubst (cdr keys) val (cdr sub))
	    )
	    sub
	    lst
     )
    )
    (T
     (append
       (list (cons (car keys) (makeorsubst (cdr keys) val nil)))
       lst
       )
    )
  )
)

_$ (setq tree (makeorsubst '("GRP1" "A" 2) '(21 . "b") nil))
(("GRP1" ("A" (2 (21 . "b")))))
_$ (setq tree (makeorsubst '("GRP1" "A" 2) '(22 . "c") tree))
(("GRP1" ("A" (2 (22 . "c") (21 . "b")))))
_$ (setq tree (makeorsubst '("GRP1" "A" 2) '(22 . "d") tree))
(("GRP1" ("A" (2 (22 . "d") (21 . "b")))))
_$ (setq tree (makeorsubst '("GRP1" "A" 3) '(31 . "a") tree))
(("GRP1" ("A" (3 (31 . "a")) (2 (22 . "d") (21 . "b")))))

Re: Recursive construction of associated list

giuseppebeatrice222 — Wed, 15 May 2019 16:24:20 GMT

Many many thanks Gile, it works very fine.

Your knowledge of recursion is fantastic.