topic Delete Invisible and empty attribute by selection window in Visual LISP, AutoLISP and General Customization Forum

Delete Invisible and empty attribute by selection window

Anonymous — Sun, 01 Sep 2019 00:34:23 GMT

Hi, I'm newbie in lisp programming. so I need a little help in this lisp routine which can delete invisible attribute by selecting blocks manually on screen . so I want it to be selected automatically by window selection set ex ( 0.0 5.5)

and also to delete any visible empty attribute.

Re: Delete Invisible and empty attribute by selection window

dlanorh — Sun, 01 Sep 2019 01:32:13 GMT

Will it always be a window from 0,0 to 5,5?

Re: Delete Invisible and empty attribute by selection window

Anonymous — Sun, 01 Sep 2019 01:36:25 GMT

This is just example , but the exact coordination is (27.2 60.0 0.0) '(634.5 405.0 0.0).

Re: Delete Invisible and empty attribute by selection window

dlanorh — Sun, 01 Sep 2019 14:19:20 GMT

Using the given information this should work

(defun c:DIA nil (c:DeleteInvisibleAttributes))

(defun c:DeleteInvisibleAttributes ( / ss ) (vl-load-com)
  ;; Example by Lee Mac 2010 - www.lee-mac.com
  (if (ssget "_W" '(27.2 60.0) '(634.5 405.0) '((0 . "INSERT") (66 . 1)))
    (progn
      (vlax-for obj
        (setq ss
          (vla-get-ActiveSelectionSet
            (vla-get-ActiveDocument (vlax-get-acad-object))
          )
        )
        (mapcar
          (function
            (lambda ( attrib )
              (if (eq :vlax-true (vla-get-Invisible attrib))
                (vla-delete attrib)
              )
            )
          )
          (vlax-invoke obj 'GetAttributes)
        )
      )
      (vla-delete ss)
    )
  )
  (princ)
)

This Website is an excellent resource for all things selection set related, as well as Autolisp in general.

Re: Delete Invisible and empty attribute by selection window

Anonymous — Sun, 01 Sep 2019 14:56:11 GMT

Thanks a lot , yes it's working as I want except that it not deleting the empty visible attributes. but that's ok

Re: Delete Invisible and empty attribute by selection window

dlanorh — Sun, 01 Sep 2019 21:32:14 GMT

@Anonymous My apologies. I missed the empty bit. Try this version, but be aware that the text string must be truly empty (strlen = 0). If the attribute text string contains spaces it won't be deleted. Would you like this added as well?

(defun c:DIA nil (c:DeleteInvisibleAttributes))

(defun c:DeleteInvisibleAttributes ( / ss ) (vl-load-com)
  ;; Example by Lee Mac 2010 - www.lee-mac.com
  (if (ssget "_W" '(27.2 60.0) '(634.5 405.0) '((0 . "INSERT") (66 . 1)))
    (progn
      (vlax-for obj
        (setq ss (vla-get-ActiveSelectionSet (vla-get-ActiveDocument (vlax-get-acad-object))))
        (mapcar
          (function
            (lambda ( attrib )
              (if (or (eq :vlax-true (vla-get-Invisible attrib)) (= (strlen (vla-get-textstring attrib)) 0))
                (vla-delete attrib)
              )
            )
          )
          (vlax-invoke obj 'GetAttributes)
        )
      )
      (vla-delete ss)
    )
  )
  (princ)
)