topic Re: TableStyle Text Color in Visual LISP, AutoLISP and General Customization Forum

TableStyle Text Color

MarkSanchezSPEC — Tue, 12 Nov 2019 18:04:26 GMT

I've created a new text style via AutoLisp but am struggling trying to set the text color. I would like to set the Title, Header, and Data row text colors per my attachment (ACI colors 12, 11, and ByLayer respectively). I've tried (vla-put-TextColor) and (vla-SetCellContentColor) without success.

Re: TableStyle Text Color

ronjonp — Tue, 12 Nov 2019 19:36:02 GMT

Probably need to use VLA-SETCOLOR.

Re: TableStyle Text Color

ronjonp — Tue, 12 Nov 2019 20:29:09 GMT

Quick example to set the colors of the style from a picked table:

(defun c:foo (/ co e el o)
  ;; RJP » 2019-11-12
  (cond	((and (setq e (car (entsel)))
	      (= "ACAD_TABLE" (cdr (assoc 0 (setq el (entget e)))))
	      (setq co (vla-get-truecolor (vlax-ename->vla-object e)))
	      (setq o (cdr (assoc 342 el)))
	 )
	 (vla-put-colorindex co 12)
	 (vla-setcolor (setq o (vlax-ename->vla-object o)) actitlerow co)
	 (vla-put-colorindex co 11)
	 (vla-setcolor o acheaderrow co)
	 (vla-put-colorindex co 256)
	 (vla-setcolor o acdatarow co)
	)
  )
  (princ)
)

Re: TableStyle Text Color

MarkSanchezSPEC — Tue, 12 Nov 2019 20:40:01 GMT

vla-SetColor worked as follows:

    (setq colObj (vlax-create-object (strcat "AutoCAD.AcCmColor." (substr (getvar "ACADVER") 1 2))))
    (vla-put-colormethod colObj acColorMethodByACI)
    (vla-put-colorindex colObj 12)
    (vla-SetColor tblSty acTitleRow colObj)
    (vla-put-colorindex colObj 11)
    (vla-SetColor tblSty acHeaderRow colObj)
    (vla-put-colorindex colObj 256)
    (vla-SetColor tblSty acDataRow colObj)

(vlax-release-object colObj)

Thanks again!

Re: TableStyle Text Color

ronjonp — Tue, 12 Nov 2019 21:17:19 GMT

Glad to help 🙂 .. not sure if you saw the code above but it will let you select a table to change the style properties ( not much error checking ).

Re: TableStyle Text Color

MarkSanchezSPEC — Tue, 12 Nov 2019 21:24:35 GMT

I did. I'm just adding a table style for now but will keep that snippet handy too.

Regards!