topic Re: Select text from the screen and write to the textbox. in Visual LISP, AutoLISP and General Customization Forum

Select text from the screen and write to the textbox.

ferhatttcoskun — Thu, 28 Nov 2019 16:47:56 GMT

Let the text or mtext objects I select from the screen write to texbox1.text

write next selection to textbox2

write next selection to textbox3

write next selection to textbox4

If I click in an empty place, it will beep.

if I choose another object, msgbox"please select text or mtext object"

I want to do like this.
Can you help me, please?

Thank you.

Re: Select text from the screen and write to the textbox.

hak_vz — Sat, 30 Nov 2019 14:47:08 GMT

To export contents of one or multiple text (mtext) objects to a file as follows:

1) Select text and mtext objects you want to extract text

2 )Start command text2file

2) If asked for a first time it will ask for destination folder and name of text file basic string (file, textbox)

3) Contents of that text entities will be written to "basicstring1.txt)

4) At the end it opens that file in notepad

If you select unwanted object it won't mater, and it will save you from beeps.

(defun c:text2file ( / LM:browseforfolder  inittextout f file e i ent ss ty text listout)
; Extract text or mtext object to file
; hak_vz  30.11.2019
;
(defun *error* ()
    (close file) 
    (princ)
)
(defun LM:browseforfolder ( msg dir bit / err fld pth shl slf )
;; Browse for Folder  -  Lee Mac
;; Displays a dialog prompting the user to select a folder.
;; msg - [str] message to display at top of dialog
;; dir - [str] [optional] root directory (or nil)
;; bit - [int] bit-coded flag specifying dialog display settings
;; Returns: [str] Selected folder filepath, else nil.
    (setq err
        (vl-catch-all-apply
            (function
                (lambda ( / app hwd )
                    (if (setq app (vlax-get-acad-object)
                              shl (vla-getinterfaceobject app "shell.application")
                              hwd (vl-catch-all-apply 'vla-get-hwnd (list app))
                              fld (vlax-invoke-method shl 'browseforfolder (if (vl-catch-all-error-p hwd) 0 hwd) msg bit dir)
                        )
                        (setq slf (vlax-get-property fld 'self)
                              pth (vlax-get-property slf 'path)
                              pth (vl-string-right-trim "\\" (vl-string-translate "/" "\\" pth))
                        )
                    )
                )
            )
        )
    )
    (if slf (vlax-release-object slf))
    (if fld (vlax-release-object fld))
    (if shl (vlax-release-object shl))
    (if (vl-catch-all-error-p err)
        (prompt (vl-catch-all-error-message err))
        pth
    )
)

(defun inittextout () ;variables are globals
(setq folderout (LM:browseforfolder "Select a folder" nil 0))
(setq fileoutname (getstring "\nName of output files base >"))
(setq filecounter 0)
(princ)
)

(if (not folderout) (inittextout))

(setq filecounter (1+ filecounter))
(setq f (strcat folderout "/" fileoutname (itoa filecounter) ".txt"))
(setq file (open f "w"))
(setq ss (cadr (ssgetfirst)) i 0)
(while (< i (sslength ss))
(setq e (ssname ss i) ent (entget e))
(setq ty (strcase(cdr (assoc 0 ent)) T))
(setq text (cdr (assoc 1 ent)))
(if (= ty "mtext") 
(while (wcmatch text "*\\P*") (setq text (vl-string-subst "\n" "\\P" text)))
)    
(setq listout (cons text listout))
(setq i (1+ i))
)
(foreach e listout
    (write-line e file)
)
(close file)
(princ (strcat "\nData is writen to " f))
(startapp "notepad" f)
(princ)
)

I hope it works for you. If it does, set this post as a final solution.

Re: Select text from the screen and write to the textbox.

hak_vz — Sat, 30 Nov 2019 17:33:57 GMT

If extracting data from a complex MTEXT object is not correct, you may temporary explode mtext object.

If the text string is less than 250 characters, all characters appear in group 1. If the text string is greater than 250 characters, the string is divided into 250-character chunks, which appear in one or more group 3 codes. If group 3 codes are used, the last group is a group 1 and has fewer than 250 character. Taking into account all formatting would be too complex.

Re: Select text from the screen and write to the textbox.

hak_vz — Sat, 30 Nov 2019 19:31:58 GMT

Here is my final code that works OK with TEXT and MTEXT entities with strings with more than 250 characters.

(defun c:text2file ( / LM:browseforfolder  inittextout f file e i m ent ss ty text endtext  txts listout);
(vl-load-com)
; Extract text or mtext object to file
; hak_vz  30.11.2019
;
(defun *error* ()
    (close file) 
    (princ)
)

(defun LM:browseforfolder ( msg dir bit / err fld pth shl slf )
;; Browse for Folder  -  Lee Mac
;; Displays a dialog prompting the user to select a folder.
;; msg - [str] message to display at top of dialog
;; dir - [str] [optional] root directory (or nil)
;; bit - [int] bit-coded flag specifying dialog display settings
;; Returns: [str] Selected folder filepath, else nil.
    (setq err
        (vl-catch-all-apply
            (function
                (lambda ( / app hwd )
                    (if (setq app (vlax-get-acad-object)
                              shl (vla-getinterfaceobject app "shell.application")
                              hwd (vl-catch-all-apply 'vla-get-hwnd (list app))
                              fld (vlax-invoke-method shl 'browseforfolder (if (vl-catch-all-error-p hwd) 0 hwd) msg bit dir)
                        )
                        (setq slf (vlax-get-property fld 'self)
                              pth (vlax-get-property slf 'path)
                              pth (vl-string-right-trim "\\" (vl-string-translate "/" "\\" pth))
                        )
                    )
                )
            )
        )
    )
    (if slf (vlax-release-object slf))
    (if fld (vlax-release-object fld))
    (if shl (vlax-release-object shl))
    (if (vl-catch-all-error-p err)
        (prompt (vl-catch-all-error-message err))
        pth
    )
)

(defun inittextout () ;variables are globals
(setq folderout (LM:browseforfolder "Select a folder" nil 0))
(setq fileoutname (getstring "\nName of output files base >"))
(setq filecounter 0)
(princ)
)

(if (not folderout) (inittextout))

(setq filecounter (1+ filecounter))
(setq f (strcat folderout "/" fileoutname (itoa filecounter) ".txt"))
(setq file (open f "w"))
(setq ss (cadr (ssgetfirst)) i 0)
(while (< i (sslength ss))
(setq e (ssname ss i) ent (entget e))
(setq ty (strcase(cdr (assoc 0 ent)) T))
(if (= ty "text")
    (setq text (cdr (assoc 1 ent)))
)

(if (= ty "mtext")
    (progn
        (if (not (and(assoc 3 ent))) 
            (progn
                (setq text (cdr (assoc 1 ent)))
                (while (wcmatch text "*\\P*") (setq text (vl-string-subst "\n" "\\P" text)))
            )
            (progn
                (setq endtext (cdr (assoc 1 ent)))
                (cond (ent
                         (while (setq m (assoc 3 ent) ent (cdr (member m ent)))
                           (setq txts (cons (cdr m) txts))
                         )
                        )
                )
                (setq text "" txts (reverse txts))
                (foreach tx txts
                    (setq text (strcat text tx))
                )
            (setq text (strcat text endtext) endtext nil)
            (while (wcmatch text "*\\P*") (setq text (vl-string-subst "\n" "\\P" text)))
            )      
        )
    )
 
)

(setq listout (cons text listout))
(setq i (1+ i))
)
(setq text nil)
(foreach e listout
    (write-line e file)
)
(close file)
(princ (strcat "\nData is writen to " f))
(startapp "notepad" f)
(princ)
)

Re: Select text from the screen and write to the textbox.

ferhatttcoskun — Mon, 02 Dec 2019 14:43:55 GMT

Private Function PickText() As String

    Dim ent As AcadEntity
    Dim pt As Variant
    Dim txtEnt As AcadText
    Dim mtxtEnt As AcadMText
    Dim go As Boolean
    
    Dim val As String
    
    On Error Resume Next
    
    Do
        go = False
        ThisDrawing.Utility.GetEntity ent, pt, vbCrLf & "Select a TEX/MText object:"
        
        If Err.Number <> 0 Then
            '' user pressed Esc, or clicked an empty location
            PickText = ""
            Exit Function
        End If
        
        If TypeOf ent Is AcadText Then
            Set txtEnt = ent
            val = txtEnt.TextString
        ElseIf TypeOf ent Is AcadMText Then
            Set mtxtEnt = ent
            val = mtxtEnt.TextString
        Else
            go = True
            ThisDrawing.Utility.Prompt vbCrLf & _
                "invalid selection: must be Text/MText object!" & vbCrLf
        End If
    
    Loop While go
    
    PickText = val
    
End Function

Re: Select text from the screen and write to the textbox.

hak_vz — Mon, 02 Dec 2019 15:30:28 GMT

Does this really solve your problem?

Re: Select text from the screen and write to the textbox.

doaiena — Mon, 02 Dec 2019 15:32:09 GMT

@ferhatttcoskun You ask a question in the AutoLisp forum, you get your solution from @hak_vz . Yet you ignore him and post a piece of code, written in a different language, that does nothing more, than set a variable and mark it as a solution...

It is at best misleading to someone, who might be searching for the same solution.

Re: Select text from the screen and write to the textbox.

hak_vz — Mon, 02 Dec 2019 15:52:39 GMT

@ferhatttcoskun asked the same question on visual basic forum and was given this solution by @norman.yuan

https://forums.autodesk.com/t5/visual-basic-customization/select-text-from-the-screen-and-write-to-the-textbox/m-p/9177262#M103360

Re: Select text from the screen and write to the textbox.

doaiena — Mon, 02 Dec 2019 16:10:41 GMT

Well, it looks like i have misinterpreted the objective.

Re: Select text from the screen and write to the textbox.

hak_vz — Mon, 02 Dec 2019 17:09:45 GMT

It is a question asked in a wrong forum. For someone who want to use it to extract text (mtext) into a textbox (application) it is a correct answer. If you want to use it instantly in everyday work, that's another story.

Re: Select text from the screen and write to the textbox.

ferhatttcoskun — Tue, 03 Dec 2019 06:10:40 GMT

I may have asked the question in the wrong place.
Thank you for your interest.

Re: Select text from the screen and write to the textbox.

hak_vz — Tue, 03 Dec 2019 06:42:21 GMT

In case you received a solution from someone else, make a link to that post in other forum and explain what you really asked, and why this is a solution.

It was a nice weekend making this, but I'll makethis code useful to myself.