topic Re: Center of the screen. in Visual LISP, AutoLISP and General Customization Forum

Center of the screen.

adaptacad — Fri, 06 Dec 2019 17:08:40 GMT

Is there a way to insert a block at the same rotation as another block closer to the center of my screen?

-> I zoomed, I called the command, and the new block will be inserted in the block closest to my zoom.

I got a .dwg with the example.

Re: Center of the screen.

Kent1Cooper — Fri, 06 Dec 2019 18:33:43 GMT

The VIEWCTR System Variable holds the [as you might expect] VIEW CenTeR, i.e. the middle of the current viewing area. You can use that as an insertion point for a Block with:

(getvar 'viewctr)

when asked for the insertion point.

But to find the already-inserted Block that's closest to that location would probably require a routine to find all Blocks in the current space, step through them all looking at the distance from there to each one's insertion point, and use the one for which that distance is shortest. It's probably doable in an AutoLisp routine, if that sounds like what you need to do.

Re: Center of the screen.

hak_vz — Fri, 06 Dec 2019 18:30:46 GMT

Command INSERT

Enable option: Insertion point -> specify on screen

Re: Center of the screen.

adaptacad — Fri, 06 Dec 2019 19:41:40 GMT

@Kent1Cooper

(command "Insert" "Blk_Insert" (getvar 'viewctr) 1 1 0)

It Works very well!
Now how to find the nearest block point?

Re: Center of the screen.

Kent1Cooper — Fri, 06 Dec 2019 20:21:52 GMT

@adaptacad wrote:

.... Now how to find the nearest block point?

Something like this [minimally tested]:

(defun C:IBCVC ; = Insert at Block Closest to View Center
  (/ ss dst vc n blk bdst theOne)
  (if (setq ss (ssget "_X" (list '(0 . "INSERT") (cons 410 (getvar 'ctab)))))
    (progn ; then
      (setq
        dst (distance (getvar 'extmin) (getvar 'extmax))
          ; virtually guaranteed farther than some Block will be from ViewCenter
        vc (getvar 'viewctr)
      ); setq
      (repeat (setq n (sslength ss))
        (setq blk (ssname ss (setq n (1- n))))
        (if (< (setq bdst (distance (cdr (assoc 10 (entget blk))) vc)) dst); closer than any other so far
          (setq theOne blk dst bdst); then -- mark as closest; its distance for basis of next comparison
        ); if
      ); repeat
      (command "_.insert" "Blk_Insert" "_none" (cdr (assoc 10 (entget theOne))) 1 1 0)
    ); progn
  ); if
  (princ)
); defun

Re: Center of the screen.

hak_vz — Fri, 06 Dec 2019 21:02:50 GMT

(defun c:ntb ( / cp dx dy p1 p2 ss i mindist di mp tp *error*)
(defun *error* () (princ))
(setvar "cmdecho" 0)
(setq 
    cp (getvar "VIEWCTR")
    dy (* 0.5 (getvar "VIEWSIZE"))
    dx (* 0.5 (* vy (/ (car (getvar "SCREENSIZE"))(cadr (getvar"SCREENSIZE")))))
    p1 (mapcar '- cp (list dx dy))
    p2 (mapcar '+ cp (list dx dy))
    ss (ssget "w" p1 p2 '((0 . "INSERT")))    
    i 0
    mindist 1e8
)
    (if ss
        (progn
            (command "Insert" "Blk_Insert" cp 1 1 0)
            (while (< i (sslength ss))
                (setq di (distance cp (setq tp(cdr (assoc 10 (entget (ssname ss i)))))))
                (if (< di mindist)
                    (setq mp tp mindist di)
                )
             (setq i (+ i 1))
            )
            (command "move" (entlast) "" cp mp)
        )
        (princ "\nThere is no block in visible area!")
    )
(setvar "cmdecho" 1)
(princ)
)

Re: Center of the screen.

adaptacad — Sat, 07 Dec 2019 00:48:07 GMT

@Kent1Cooper Thank you very much!! it Works very well!
How do I rotate at the same angle as "Block_Mult"?
How not to insert in the base of "Block_Mult" but in the place of the example?

Re: Center of the screen.

adaptacad — Sat, 07 Dec 2019 00:48:58 GMT

@hak_vz It does not work !!

Re: Center of the screen.

hak_vz — Sat, 07 Dec 2019 07:00:53 GMT

(defun c:ntb ( / cp dx dy p1 p2 ss i mindist di mp tp *error*)
(defun *error* () (princ))
(setvar "cmdecho" 0)
(setq 
    cp (getvar "VIEWCTR")
    dy (* 0.5 (getvar "VIEWSIZE"))
    dx (* 0.5 (* dy (/ (car (getvar "SCREENSIZE"))(cadr (getvar"SCREENSIZE")))))
    p1 (mapcar '- cp (list dx dy))
    p2 (mapcar '+ cp (list dx dy))
    ss (ssget "w" p1 p2 '((0 . "INSERT")))    
    i 0
    mindist 1e8
)
    (if ss
        (progn
            (command "Insert" "Blk_Insert" cp 1 1 0)
            (while (< i (sslength ss))
                (setq di (distance cp (setq tp(cdr (assoc 10 (entget (ssname ss i)))))))
                (if (< di mindist)
                    (setq mp tp mindist di)
                )
             (setq i (+ i 1))
            )
            (command "move" (entlast) "" cp mp)
        )
        (princ "\nThere is no block in visible area!")
    )
(setvar "cmdecho" 1)
(princ)
)


(defun c:ntb2 ( / cp dx dy p1 p2 ss i mindist di mp tp *error*)
(defun *error* () (princ))
(setvar "cmdecho" 0)
(setq 
cp (getvar "VIEWCTR")
ss (ssget "x" '((0 . "INSERT"))) 
i 0
mindist 1e8
)
(if ss
(progn
(while (< i (sslength ss))
(setq di (distance cp (setq tp(cdr (assoc 10 (entget (ssname ss i)))))))
(if (< di mindist)
(setq mp tp mindist di)
)
(setq i (+ i 1))
)
(command "Insert" "Blk_Insert" mp 1 1 0)
)
)
(setvar "cmdecho" 1)
(princ)
)

Re: Center of the screen.

Kent1Cooper — Sat, 07 Dec 2019 12:51:01 GMT

@adaptacad wrote:

….
How do I rotate at the same angle as "Block_Mult"?
How not to insert in the base of "Block_Mult" but in the place of the example?

[No AutoCAD here, but I'll give it a shot....]

1. You should be able to replace the 0 at the end of the Insert command with:

(cdr (assoc 50 (entget theOne)))

2. I'm not sure what you mean by "in the place of the example" -- what would determine where that place is, if it's not the insertion point of the Block closest to the center of the current view?

Re: Center of the screen.

adaptacad — Sat, 07 Dec 2019 16:36:44 GMT

@hak_vz It Works very well. Thank you!!!

@Kent1Cooper This point with the same rotation as the block.

Re: Center of the screen.

hak_vz — Sat, 07 Dec 2019 17:56:14 GMT

(defun c:ntb ( / cp dx dy p1 p2 ss i mindist di mp tp e *error*)
(defun *error* () (princ))
(defun rad_to_deg (rad)(* 180.0 (/ rad pi)))
(setvar "cmdecho" 0)
(setq
cp (getvar "VIEWCTR")
dy (* 0.5 (getvar "VIEWSIZE"))
dx (* 0.5 (* dy (/ (car (getvar "SCREENSIZE"))(cadr (getvar"SCREENSIZE")))))
p1 (mapcar '- cp (list dx dy))
p2 (mapcar '+ cp (list dx dy))
ss (ssget "w" p1 p2 '((0 . "INSERT")))
i 0
mindist 1e8
)
(if ss
(progn

(while (< i (sslength ss))
(setq di (distance cp (setq tp(cdr (assoc 10 (entget (ssname ss i)))))))
(if (< di mindist)
(setq mp tp mindist di e (ssname ss i))
)
(setq i (+ i 1))
)
(command "Insert" "Blk_Insert" mp 1 1 0)
(command "rotate" (entlast) "" mp (rad_to_deg(cdr (assoc 50 (entget e)))))
)
(princ "\nThere is no block in visible area!")
)
(setvar "cmdecho" 1)
(princ)
)

Re: Center of the screen.

adaptacad — Sat, 07 Dec 2019 18:01:45 GMT

@hak_vz wrote:
(defun c:ntb ( / cp dx dy p1 p2 ss i mindist di mp tp e *error*)
(defun *error* () (princ))
(defun rad_to_deg (rad)(* 180.0 (/ rad pi)))
(setvar "cmdecho" 0)
(setq
cp (getvar "VIEWCTR")
dy (* 0.5 (getvar "VIEWSIZE"))
dx (* 0.5 (* dy (/ (car (getvar "SCREENSIZE"))(cadr (getvar"SCREENSIZE")))))
p1 (mapcar '- cp (list dx dy))
p2 (mapcar '+ cp (list dx dy))
ss (ssget "w" p1 p2 '((0 . "INSERT")))
i 0
mindist 1e8
)
(if ss
(progn

(while (< i (sslength ss))
(setq di (distance cp (setq tp(cdr (assoc 10 (entget (ssname ss i)))))))
(if (< di mindist)
(setq mp tp mindist di e (ssname ss i))
)
(setq i (+ i 1))
)
(command "Insert" "Blk_Insert" mp 1 1 0)
(command "rotate" (entlast) "" mp (rad_to_deg(cdr (assoc 50 (entget e)))))
)
(princ "\nThere is no block in visible area!")
)
(setvar "cmdecho" 1)
(princ)
)

@hak_vz Thank you. Rotation works great, but how to insert at this point?

Re: Center of the screen.

hak_vz — Sat, 07 Dec 2019 18:23:03 GMT

Sorry but I get lost.

I've got this. Problem is probably in some system variables . At first I had problem with rotation. In my case it is base angle direction is East and i use cc direction. I guess you may have something different.

In both codes we only work with insertion points, so I don't see a reason that they don't join.

Re: Center of the screen.

Kent1Cooper — Sun, 08 Dec 2019 03:25:41 GMT

@adaptacad wrote:

....

@Kent1Cooper This point with the same rotation as the block.

Is "this point" not the insertion point of that Block? The blue square down lower looks like a grip, which presumably would be the insertion point. If that's true, I suggest you redefine the Block to make the point you want at a specific location its insertion point. Otherwise, the routine will need to do some calculation, affected by the rotation, of the insertion point to use in order to land "this point" at the insertion point of the closest-to-view-center Block. And you will need to build the distance from this Block's insertion point to "this point" into that calculation.

Re: Center of the screen.

adaptacad — Mon, 09 Dec 2019 13:17:46 GMT

@hak_vz It's working very well, I would just like to move the block to that point.
understand?

Re: Center of the screen.

adaptacad — Mon, 09 Dec 2019 13:20:11 GMT

@Kent1Cooper I can't change the base of the block! 😕

Re: Center of the screen.

Kent1Cooper — Mon, 09 Dec 2019 13:26:34 GMT

If the recently-posted images show the Block at zero rotation, and if you want the location at the freehand arrowhead point to be what's at the insertion point of the closest-to-view-center Block, try this variant [untested]:

(defun C:IBCVC ; = Insert at Block Closest to View Center
  (/ ss dst vc n blk bdst theOne)
  (if (setq ss (ssget "_X" (list '(0 . "INSERT") (cons 410 (getvar 'ctab)))))
    (progn ; then
      (setq
        dst (distance (getvar 'extmin) (getvar 'extmax))
          ; virtually guaranteed farther than some Block will be from ViewCenter
        vc (getvar 'viewctr)
      ); setq
      (repeat (setq n (sslength ss))
        (setq blk (ssname ss (setq n (1- n))))
        (if (< (setq bdst (distance (cdr (assoc 10 (entget blk))) vc)) dst); closer than any other so far
          (setq theOne blk dst bdst); then -- mark as closest; its distance as next comparison
        ); if
      ); repeat
      (setq rot (cdr (assoc 50 (entget theOne))))
      (command "_.insert" "Blk_Insert" "_none"
        (polar (cdr (assoc 10 (entget theOne))) (- rot (/ pi 2)) 2.5)
        1 1 rot
      ); command
    ); progn
  ); if
  (princ)
); defun

Re: Center of the screen.

hak_vz — Mon, 09 Dec 2019 13:33:18 GMT

Will write it later.

Re: Center of the screen.

hak_vz — Mon, 09 Dec 2019 15:28:44 GMT

(defun c:ntb ( / cp dx dy p1 p2 ss i mindist di mp tp e *error*) 
(defun *error* () (princ))
(defun rad_to_deg (rad)(* 180.0 (/ rad pi)))
(setvar "cmdecho" 0)
(setq 
    cp (getvar "VIEWCTR")
    dy (* 0.5 (getvar "VIEWSIZE"))
    dx (* 0.5 (* dy (/ (car (getvar "SCREENSIZE"))(cadr (getvar"SCREENSIZE")))))
    p1 (mapcar '- cp (list dx dy))
    p2 (mapcar '+ cp (list dx dy))
    ss (ssget "w" p1 p2 '((0 . "INSERT")))    
    i 0
    mindist 1e8
)
    (if ss
        (progn
           
            (while (< i (sslength ss))
                (setq di (distance cp (setq tp(cdr (assoc 10 (entget (ssname ss i)))))))
                (if (< di mindist)
                    (setq mp tp mindist di e  (ssname ss i))
                )
             (setq i (+ i 1))
            )
            (command "Insert" "Blk_Insert" mp 1 1 0)
            (command "rotate" (entlast) "" mp (rad_to_deg(cdr (assoc 50 (entget e)))))
            (command "move" (entlast) "" mp (polar mp (+ (cdr (assoc 50 (entget e))) (* 0.5 pi)) 2.5))
        )
        (princ "\nThere is no block in visible area!")
    )
(setvar "cmdecho" 1)
(princ)
)