topic Re: Need LISP routine to automatically place "number"-blocks on convey in Visual LISP, AutoLISP and General Customization Forum

Need LISP routine to automatically place "number"-blocks on conveyors

Anonymous — Tue, 11 Feb 2020 11:04:31 GMT

Hi all 🙂

I have no coding experience or previous experience with LISP, so I sincerely ask for your help. I make a lot of layouts with conveyors - sometimes with several thousands of conveyors. When my layouts are done, I usually need several hours of placing a simple "numbering" block in the end-points of every conveyor.

Each conveyor consists of a basepoint, a length parameter and a regular "point" in the end.

The numbering block, consists of a basepoint and a strech-point to move the text back and forth.

I need a LISP routine that automatically takes the basepoint of the numbering block, and places it on top of the "point" in each conveyor in the layout, so that the only thing I have to do by myself, is move the text on the numbering block.

I attached an example DWG that explains what I need, and what it is supposed to look like when the LISP has done its job - I really hope that you can help me 🙂

If anything is unclear, please just ask 🙂

Re: Need LISP routine to automatically place "number"-blocks on convey

hak_vz — Tue, 11 Feb 2020 11:48:24 GMT

I don't have a time to write some code but I'll share my view on this task. I think this is solvable without writting a code. I've opened your sample drawing and as I see you've got conveyors blocks that you join to numbering.

I don't know, maybe I'm wrong, but I would joint those two blocks into a single dynamic block with rules about how to orient numbering in regards to conveyour orijentation (outside, at midpoint ....).

Re: Need LISP routine to automatically place "number"-blocks on convey

Anonymous — Tue, 11 Feb 2020 11:57:35 GMT

@hak_vz wrote:
I don't have a time to write some code but I'll share my view on this task. I think this is solvable without writting a code. I've opened your sample drawing and as I see you've got conveyors blocks that you join to numbering.

I don't know, maybe I'm wrong, but I would joint those two blocks into a single dynamic block with rules about how to orient numbering in regards to conveyour orijentation (outside, at midpoint ....).

That was my initial idea, to have the numbering block as a part of the conveyor block - but when i need to mirror a group of conveyors, the text would also be mirrored. Also, the blocks need to be as simple as possible, and rotating them with a rotate parameter instead of using the rotate tool or the rotation in the Properties menu would definately confuse my coworkers 🙂

Re: Need LISP routine to automatically place "number"-blocks on convey

pbejse — Tue, 11 Feb 2020 18:15:00 GMT

Speaking of rotation, there's one odd block in that drawing at position X 10000, the rotation is 90 deg, while similar block definition with thb w same rotation is at either 0 or 180, cant wrap my ahead around it.

Are the conveyors rotation is either 0 or 90 and never at an odd angle?

Re: Need LISP routine to automatically place "number"-blocks on convey

pbejse — Tue, 11 Feb 2020 19:06:07 GMT

Q&D : You can build off this code..

(defun c:NOC (/  valid_blocks f ss i e data dpp len)
;;	pBe 2019	;;
  
(setq valid_blocks '("CONV-400x200" "CONV-600x400"));; Add more block names here with
(setq f (lambda (p) (vlax-get e p)))

(if 
      (setq ss (ssget '((0 . "INSERT")(2 . "`*U*,CONV-*"))))
      
  	(repeat (setq i (sslength ss))
          (setq e (vlax-ename->vla-object (ssname ss (Setq i (1- i)))))
          (setq data (mapcar 'f  '("Insertionpoint" "Rotation" "EffectiveName" "XScaleFactor")))

          (if (and
                (member (caddr data) valid_blocks)
                (setq dpp (mapcar '(lambda (e) (mapcar 'f
                                      '("PropertyName" "Value" )))
                                    (vlax-invoke e 'GetDynamicBlockProperties)))
                (> (setq len (cadr (Assoc "Length" dpp))) 0)
                )
		(vlax-invoke
		  (vlax-get (vla-get-ActiveLayout
		              (vla-get-activedocument
		                (vlax-get-acad-object)
		              )
		            )
		            'Block
		  )
		  'InsertBlock
		  (polar (car data)
                         (+ (if (minusp (last data)) pi 0.0) (Cadr data))
                         len)
		  "UnitNumber"	;; make sure this block exists in the drawing
		  1 1 1 0) ;; <-- block rotation at 0, Zero, cero, Null, bokya, nialas ....
		)
            )
          )
  (princ)
  )

HTH

Re: Need LISP routine to automatically place "number"-blocks on convey

Anonymous — Wed, 12 Feb 2020 07:21:26 GMT

@pbejse wrote:
Q&D : You can build off this code..

HTH

Code did EXACTLY what it was supposed to do - thank you so much!!! 🙂 Kudos!

Regarding the "weird" block you mentioned, if you orbit the drawing, you'll see that the block was 3d rotated 🙂

Re: Need LISP routine to automatically place "number"-blocks on convey

pbejse — Wed, 12 Feb 2020 07:46:34 GMT

@Anonymous wrote:

Code did EXACTLY what it was supposed to do - thank you so much!!! 🙂 Kudos!

Regarding the "weird" block you mentioned, if you orbit the drawing, you'll see that the block was 3d rotated 🙂

Glad to be of help KayChrisKAy.

I see, now why didn't I think of that 😄

Cheers

Re: Need LISP routine to automatically place "number"-blocks on convey

Anonymous — Wed, 12 Feb 2020 10:40:08 GMT

@pbejse wrote:
@Anonymous wrote:
Code did EXACTLY what it was supposed to do - thank you so much!!! 🙂 Kudos!
Regarding the "weird" block you mentioned, if you orbit the drawing, you'll see that the block was 3d rotated 🙂

Glad to be of help KayChrisKAy.
I see, now why didn't I think of that 😄

Cheers

Additional question - I apologize... 🙂 Is it somehow possible to, instead of defining all 50 blocks that I got, that start with "CONV-", to just setq valid_blocks to all blocks that has a name starting with "CONV-"?

Re: Need LISP routine to automatically place "number"-blocks on convey

pbejse — Wed, 12 Feb 2020 11:02:52 GMT

@Anonymous wrote:

estion - I apologize... 🙂 Is it somehow possible to, instead of defining all 50 blocks that I got, that start with "CONV-", to just setq valid_blocks to all blocks that has a name starting with "CONV-"?

Yup.

Replace

(member (caddr data) valid_blocks)

with

(vl-string-search "CONV-" (caddr data))

HTH

Re: Need LISP routine to automatically place "number"-blocks on convey

Anonymous — Wed, 12 Feb 2020 12:03:26 GMT

I feel stupid for asking a 3rd time, I'm very sorry! 😥

The lisp works great, but how do I add blocks to the routine that doesn't start with "CONV-"?

(defun c:NOC (/  valid_blocks f ss i e data dpp len)
;;	pBe 2019	;;
  
(setq valid_blocks '("CONV-400x200" "CONV-600x400" "TRANSF-400x200" "OVERH-400x200"));; Add more block names here with
(setq f (lambda (p) (vlax-get e p)))

(if 
      (setq ss (ssget '((0 . "INSERT")(2 . "`*U*,CONV-*")))) ;;I assume I have to add something here
      
  	(repeat (setq i (sslength ss))
          (setq e (vlax-ename->vla-object (ssname ss (Setq i (1- i)))))
          (setq data (mapcar 'f  '("Insertionpoint" "Rotation" "EffectiveName" "XScaleFactor")))

          (if (and
                ;;(member (caddr data) valid_blocks)
		(vl-string-search "CONV-" (caddr data)) ;;And also something here?
                (setq dpp (mapcar '(lambda (e) (mapcar 'f
                                      '("PropertyName" "Value" )))
                                    (vlax-invoke e 'GetDynamicBlockProperties)))
                (> (setq len (cadr (Assoc "Length" dpp))) 0)
                )
		(vlax-invoke
		  (vlax-get (vla-get-ActiveLayout
		              (vla-get-activedocument
		                (vlax-get-acad-object)
		              )
		            )
		            'Block
		  )
		  'InsertBlock
		  (polar (car data)
                         (+ (if (minusp (last data)) pi 0.0) (Cadr data))
                         len)
		  "POSITION2"	;; make sure this block exists in the drawing
		  1 1 1 0) ;; <-- block rotation at 0, Zero, cero, Null, bokya, nialas ....
		)
            )
          )
  (princ)
  )

This is the absolute last I need 🙂

Can you please help - I hope it's not too much trouble

Re: Need LISP routine to automatically place "number"-blocks on convey

pbejse — Wed, 12 Feb 2020 12:39:49 GMT

ITs not too much trouble, we will target blocks with this pattern "###x###" at the end of the block name similar to any of these "CONV-600x400" "TRANSF-400x200" "OVERH-600x200", also it should have the "LENGTH" property name.

It would also help if you you can define which blocks to insert in place of "UnitNumber" or "POSITION2" etc.. that way you dont need to change the block name to insert everytime you need to run the program. Perhaps we can just define one for each block like this:

(Defun c:iBlock1 nil (NOC "UnitNumber"))
(Defun c:iBlock2 nil (NOC "POSITION2"))

you can add as many as you like

Then we modify the main routine to accept any valid block name as an argument

(defun NOC ( bname /  valid_blocks f ss i e data dpp len)
;;	pBe 2019	;;
  (setq f (lambda (p) (vlax-get e p)))

(if 
      (setq ss (ssget '((0 . "INSERT")(2 . "`*U*,*###x###*"))))       
  	(repeat (setq i (sslength ss))
          (setq e (vlax-ename->vla-object (ssname ss (Setq i (1- i)))))
          (setq data (mapcar 'f  '("Insertionpoint" "Rotation" "EffectiveName" "XScaleFactor")))

          (if (and
                (wcmatch (strcase (caddr data)) "*###X###*")
                (setq dpp (mapcar '(lambda (e) (mapcar 'f
                                      '("PropertyName" "Value" )))
                                    (vlax-invoke e 'GetDynamicBlockProperties)))
                (> (setq len (cadr (Assoc "Length" dpp))) 0)
                )
		(vlax-invoke
		  (vlax-get (vla-get-ActiveLayout
		              (vla-get-activedocument
		                (vlax-get-acad-object)
		              )
		            )
		            'Block
		  )
		  'InsertBlock
		  (polar (car data)
                         (+ (if (minusp (last data)) pi 0.0) (Cadr data))
                         len)
		         bname		
		  1 1 1 0) 
		)
            )
          )
  (princ)
  )

HTH

Re: Need LISP routine to automatically place "number"-blocks on convey

Anonymous — Fri, 14 Feb 2020 10:21:26 GMT

Never mind the "Position2", the block to be inserted is only called "UnitNumber".

I have another issue now - I want the LISP to also add the block to three different blocks that is not being defined by the "###x###", but still have the Length parameter. They are also conveyors, but their names are simply "AUFK-xxx", "BIxxA-KN2" and "REV-xxxx"