topic Betreff: Someone tell me what the problem is (pelo amor de deus kkkk) in Visual LISP, AutoLISP and General Customization Forum

Someone tell me what the problem is (pelo amor de deus kkkk)

Anonymous — Wed, 19 Feb 2020 14:01:53 GMT

I have two files, first is a test that is a small part of the second. The second is the complete file.
when I run the program on the test it works very well.
When squeegee in general does not work !!! why? why? why?
when I run only the section that doesn't work in the general file it works !! why? why? why?

I did it step by step: It doesn't work!
Isolated the polylines in the loop: It doesn't work!
I turned off the precision tools: It doesn't work!
I modified the subfunctions: It doesn't work!
Reduce the sspts filter: It doesn't work!

I'm almost breaking my monitor lol lol
I attached a sreencast : '(

(defun c:ETC (/ selection *error* file selection clrcabo namebox coords points ecr nomeposte)
; *Error* <- Ainda a ser ajustado
    (defun *error* ( errmsg )
        (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break"))
            (princ (strcat "\nError: " errmsg))
        )
        (close file)
        (vl-file-delete (strcat(getvar 'dwgprefix)(vl-filename-base(getvar 'dwgname)) " CB.csv"))
        (princ)
    )
;End *error* 

    (if
        (and
            (setq selection (RJP:Setlist (ssget  '((0 . "*LWPOLYLINE") (-4 . "!=") (62 . 251)))))
            (setq file (open (strcat (getvar 'dwgprefix) (vl-filename-base (getvar 'dwgname)) " CB.csv") "w"))
        )
        (progn
            (write-line "NOME TRECHO;TIPO DE CABO;ORDEM" file)
            (foreach X selection
                (setq entdata (entget  x))
                (setq clrcabo (vla-get-color (setq plineobj (vlax-ename->vla-object X))))
                (setq namebox (JR:NameExcerpts plineobj))
                (setq coords (vl-remove-if 'not (mapcar  (function (lambda ( p ) (if (= 10 (car p))(:Addzerolist 0.00 2 (cdr p))))) entdata)))
                (setq points nil  ecr nil nomeposte nil)
                
                (setq jns ;variavel fantasma para foreach
                    (mapcar
                        '(lambda ( n )
                            (if (setq sspts (ssget "_C" (mapcar '+ n '(1.2 2)) (mapcar '- n '(1.2 2)) '((0 . "INSERT") (2 . "`*U*") (8 . "D_Poste"))))
                                (progn
                                    (setq objpts (vlax-ename->vla-object (ssname sspts 0)))
                                    (setq nomeposte (list (LM:vl-getattributevalue objpts "NUM")))
                                    (setq ecr (LM:lst->str (setq points (append points nomeposte)) ","))
                                )
                                (setq ecr "")
                            )
                        )
                        coords
                    )
                )                
                (write-line (strcat (LM:lst->str namebox " /") ";" (rtos clrcabo)  ;|(JR:DatabaseMaterial clrcabo)|;  ";" ecr) file)
            )
            (close file)
            (startapp "notepad" (strcat (getvar 'dwgprefix) (vl-filename-base (getvar 'dwgname)) " CB.csv"))
        )
        (prompt "\nOoops algo deu errado!!!")
    )
)

;; Get Attribute Values  -  Lee Mac
;; Returns an association list of attributes present in the supplied block.
;; blk - [ent] Block (Insert) Entity Name
;; Returns: [lst] Association list of ((<tag> . <value>) ... )

(defun LM:vl-getattributevalue ( blk tag )
  (setq tag (strcase tag))
  (vl-some '(lambda ( att ) (if (= tag (strcase (vla-get-tagstring att))) (vla-get-textstring att))) (vlax-invoke blk 'getattributes))
)
;; Set Attribute Values  -  Lee Mac
;; Sets attributes with tags found in the association list to their associated values.
;; blk - [ent] Block (Insert) Entity Name
;; lst - [lst] Association list of ((<tag> . <value>) ... )
;; Returns: nil

(defun LM:vl-setattributevalue ( blk tag val )
  (setq tag (strcase tag))
  (vl-some '(lambda ( att )(if (= tag (strcase (vla-get-tagstring att))) (progn (vla-put-textstring att val) val)))(vlax-invoke blk 'getattributes))
)

;; List to String  -  Lee Mac
;; Concatenates each string in a supplied list, separated by a given delimiter
;; lst - [lst] List of strings to concatenate
;; del - [str] Delimiter string to separate each item
(defun LM:lst->str ( lst del )
    (if (cdr lst)
        (strcat (car lst) del (LM:lst->str (cdr lst) del))
        (car lst)
    )
)
;; RJP - Usar funções da biblioteca para tarefas repetitivas ... também pode validar a seleção
;; JR  - Fiz alteração no nome da função
(defun RJP:Setlist ( s )
  (if (= 'pickset (type s))
    (vl-remove-if 'listp (mapcar 'cadr (ssnamex s)))
    )
)
    

;; :Addzerolist 
;; Adciona zero no final de lista de coordenadas
(defun :Addzerolist ( item ind lst )
    (if (or (zerop ind) (null lst))
        (cons item lst)
        (cons (car lst) (:Addzerolist item (1- ind) (cdr lst)))
    )
)
;; JR:NameExcerpts - Junior Nogueira
;; Cria duas variaveis com o noos inicial e final do trecho e uma lista com as duas
;; se não existir cria apenas uma das pontas
(defun JR:NameExcerpts ( ocx )
    (setq starpt (list (vlax-curve-getStartPoint ocx)) endpt (list (vlax-curve-getEndPoint ocx)))
    (setq starendpt (append starpt endpt))
    (setq nameexcerpts
        (mapcar 
            '(lambda ( x )
                (if (setq cx (ssget "_C" (mapcar '+ x '(5 5)) (mapcar '- x '(5 5)) '((0 . "INSERT")(66 . 1)(2 . "`*U*,Caixa00[1-6]")(8 . "P_Caixa00[1-6]"))))
                    (progn
                        (setq objcx (vlax-ename->vla-object (ssname cx 0)))
                        (setq stringexcerpts (LM:vl-getattributevalue objcx "NOM"))
                    )
                    (setq stringexcerpts "")
                )
            )
            starendpt
        )
    )
    (mapcar 'set '(ssCxStart ssCxend) nameexcerpts)
)

baf66b9e-de4c-4ede-819b-10394751b4fd,640,710

Re: Someone tell me what the problem is (pelo amor de deus kkkk)

ВeekeeCZ — Wed, 19 Feb 2020 14:13:54 GMT

No screencast, no test file attached.

I can see that you use (ssget "_C")... but I don't see any ZOOM management. I would expect at least ZOOM extents. See Lee's caution HERE:

Caution: Only objects visible in the drawing area at the time of selection will be selected by this method. Consider temporarily zooming to the selection window before performing the selection, and then zoom previous to restore the original screen position.

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

cadffm — Wed, 19 Feb 2020 14:22:42 GMT

Hi,

1. I am missing the two DWG files...

2. I am missing the description what "doesn't work" really means

3. I am missing a well effective-name handling*

4. I am missing a well view-control handling for your ssget "_c" part*

* you should have since weeks ago.

>"why? why? why?"

You don't want to hear the answer 🙂

In short: It isn't programmed bulletproof.

Re: Someone tell me what the problem is (pelo amor de deus kkkk)

Anonymous — Wed, 19 Feb 2020 15:00:49 GMT

@BeekeeCZ

Excuses! Attached Screencas and .dwgs

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

Anonymous — Wed, 19 Feb 2020 15:08:50 GMT

1. I am missing the two DWG files ...

I just attached!

2. I am missing the description what "doesn't work" really means
- My .csv when done in the general file it generates many duplicate points and cannot be repeated.

3. I am missing a well effective-name handling *
I don't think that's the problem because I'm dealing with more than one block. but I can do it without any problems !!

4. I am missing a well view-control handling for your ssget "_c" part *
Do not understand: /

>"why? why? why?"

You don't want to hear the answer 🙂

In short: It isn't programmed bulletproof.

Yes I want ! lol.
the more i try to program the more stupid i look lol

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

ВeekeeCZ — Wed, 19 Feb 2020 15:33:37 GMT

wait...

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

Anonymous — Wed, 19 Feb 2020 15:53:34 GMT

You have the same result as me !! many exported values are doubled.

I thought of adding >> They are function <<

(setq nomeposte (LM:Unique (list (LM:vl-getattributevalue objpts "NUM"))))

with that I avoid duplicate values in the list, but it is not a good solution, as I don't know if my points are correct.

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

ВeekeeCZ — Wed, 19 Feb 2020 15:49:18 GMT

OK. Unless you give us/me a massive detail description of what's right and what's not, I give up.

Pick one complicated detail of your drawing, make a schema or whatever is necessary.

Sorry. Not going to read your code and guess what was your intentions.

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

Anonymous — Wed, 19 Feb 2020 16:08:38 GMT

OK!! Excuse me.

let's go . If I choose * a complicated design detail *, the code will work !!! : '(

my problem is in the values (name of points) duplicated in .csv. (red items in the image)

this problem occurs in the general file, in the test file it works.

I can add >> this function <<

(setq nomeposte (LM:Unique (list (LM:vl-getattributevalue objpts "NUM"))))

But I don't know if my points are correct.

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

ВeekeeCZ — Wed, 19 Feb 2020 16:41:22 GMT

Again, not enough. Pick one bad block, tell which one, and explain what the numbers should be are where they coming from?!

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

Anonymous — Wed, 19 Feb 2020 17:07:02 GMT

🙄 something like ?

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

ВeekeeCZ — Wed, 19 Feb 2020 17:36:57 GMT

Better!

But why those numbers? Are they somehow close, next in line...

And describe your algorithms how you pair those numbers together.

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

Anonymous — Wed, 19 Feb 2020 18:03:00 GMT

I take all the coordinates of the vertices of the polyline and store them in a list ->
I take the first coordinate from the list (which is one end)
,select using (ssget "_C") the nearest block (5m) ->
after creating a list with the attribute value "NUM" ->
I repeat this at all vertices of my polyline.

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

ВeekeeCZ — Wed, 19 Feb 2020 18:29:18 GMT

Check this file and verify if there is anything wrong. Some polylines would be probably missing.

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

Anonymous — Wed, 19 Feb 2020 18:39:17 GMT

Apparently, there are no more duplicate values!

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

ВeekeeCZ — Wed, 19 Feb 2020 19:00:07 GMT

Good! The good news is that your code is without flaws.

The bad news is that it's not feasible to make it reliably work on the entire file.

The issue is known - it's (ssget "_c"). And the solution is obvious - get rid of (ssget "_c").

So basically your approach has to be the other way around. Whether now you make a window around a polyline to select all close blocks, the better approach would be to collect all block insertion points (pnt . ename) and filter them by proximity to the polyline.

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

Anonymous — Wed, 19 Feb 2020 19:09:45 GMT

With that my result will be better ??
Can I get the snippet report like that?
is there an example code for me to understand what you mean?

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

ВeekeeCZ — Wed, 19 Feb 2020 21:15:47 GMT

Hopefully.

No, I don't have any.

It would be something like... just to show you direction.

(vl-remove-if-not '(lambda (x) (< (vlax-curve-getclosestpointat pl (car x) ) 5.))) lst)

where lst would be list of all blocks that matters with properties and atts that matters.

It's really essential to know these things. So try, learn, try, learn... you need to be able to write that any time of day.

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

Anonymous — Thu, 20 Feb 2020 11:05:29 GMT

@ВeekeeCZ Thanks!!! I will do what it says !! but honestly, I think I will have the same result: /

Betreff: Someone tell me what the problem is (pelo amor de deus kkkk)

CADaSchtroumpf — Thu, 20 Feb 2020 12:55:07 GMT

A start with this for ignor

((lambda ( / ss_blk-dyn n ent lst_pt-ins-dyn ss_blk-att lst_pt-ins-att ss_pl lst_pt-vtx ss_blk)
  (setq ss_blk-dyn (ssget "_X" '((0 . "INSERT") (2 . "`*U*") (8 . "D_Poste"))) lst_pt-ins-dyn nil lst_pt-ins-att nil lst_pt-vtx nil)
  (cond
    (ss_blk-dyn
      (repeat (setq n (sslength ss_blk-dyn))
        (setq
          ent (ssname ss_blk-dyn (setq n (1- n)))
          lst_pt-ins-dyn (cons (cons (cdr (assoc 10 (entget ent))) ent) lst_pt-ins-dyn)
        )
      )
      (setq ss_blk-att (ssget "_X" '((0 . "INSERT") (66 . 1) (2 . "`*U*,Caixa00[1-6]") (8 . "P_Caixa00[1-6]"))))
      (cond
        (ss_blk-att
          (repeat (setq n (sslength ss_blk-att))
            (setq
              ent (ssname ss_blk-att (setq n (1- n)))
              lst_pt-ins-att (cons (cons (cdr (assoc 10 (entget ent))) ent) lst_pt-ins-att)
            )
          )
          (setq ss_pl (ssget '((0 . "LWPOLYLINE") (-4 . "!=") (62 . 251))) ss_blk (ssadd))
          (cond
            (ss_pl
              (repeat (setq n (sslength ss_pl))
                (setq
                  ent (ssname ss_pl (setq n (1- n)))
                  lst_pt-vtx (append (mapcar 'cdr (vl-remove-if '(lambda (x) (/= (car x) 10)) (entget ent))) lst_pt-vtx)
                )
              )
              (foreach el lst_pt-vtx
                (mapcar
                  '(lambda (x)
                    (if (<= (distance (car x) el) 2.75)
                      (setq ss_blk (ssadd (cdr x) ss_blk))
                    )
                  )
                  (append lst_pt-ins-dyn lst_pt-ins-att)
                )
              )
              (sssetfirst nil ss_blk)
            )
          )
        )
      )
    )
  )
))

e sssget with crossing who have problem.

You can use select "ss_blk" for extract your data.