topic Re: show line direction in Visual LISP, AutoLISP and General Customization Forum

show line direction

Anonymous — Sat, 24 Oct 2020 17:24:50 GMT

Hi everyone,

can you help with a lisp that shows the direction of selected lines,

like this lisp for polyline:

https://autocadtips1.com/2014/06/24/autolisp-polyline-direction-preview/#:~:text=You%20simply%20run%20the%20command,the%20direction%20of%20the%20polyline.

and also ask for lines to change direction if needed.

It would be very helpfull.

Thank you

Eyal.

Re: show line direction

hak_vz — Sat, 24 Oct 2020 18:25:54 GMT

Here you have two functions linedirections and clearcircles.

First creates circles of radius 5 at the end point.

Second erase all circles.

To reverse direction of a line use built in command REVERSE

(defun c:linedirections nil (linedirections)) (defun c:clearcircles nil(clearcircles)) (defun linedirections ( / ss pt i) (princ "\nSelect lines objects to show it end point >") (setq ss (ssget '((0 . "LINE")))) (setvar 'cmdecho 0) (setq ssd (ssadd) i 0) (if ss (repeat (sslength ss) (setq pt (cdr (assoc 11 (entget (ssname ss i))))) (command "circle" pt 5 ) (setq ssd (ssadd (entlast) ssd)) (setq i (+ i 1)) ) ) (setvar 'cmdecho 1) (princ) ) (defun clearcircles () (command "erase" ssd "")(princ))

Re: show line direction

Moshe-A — Sat, 24 Oct 2020 20:22:08 GMT

Eyal,

Check this one, it allows you to control the arrows direction.

The next code line defines the base arrow size which is the 1/4 the average distance of all selected lines.

you can set a bigger arrow by changing 0.25 to a higher value.

(setq ARROW_SIZE (* 0.25 (/ (apply '+ (gen_dist)) (vl-list-length (gen_dist)))))

Remember that the green arrows are drawn only on the AutoCAD graphic screen and be vanished with redraw (or any other zoom commands)

enjoy

Moshe

(defun c:lid (/ initialize askdir gen_dist direction ; local functions ss ARROW_SIZE elist p0 p1 p2 p3 p4 p5 p6 p7 p8) (defun initialize () (if (eq (getvar "users5") "") (setq defdir (setvar "users5" "Forward")) (setq defdir (getvar "users5")) ) ); initialize (defun askdir (def / ask) (initget "Forward Backward") (if (not (setq ask (getkword (strcat "\nForward/Backward arrowhead <" (substr def 1 1) ">: ")))) (setq ask def) (setq def ask) ) ); askdir (defun gen_dist () (mapcar '(lambda (ename / elist) (setq elist (entget ename)) (distance (cdr (assoc '10 elist)) (cdr (assoc '11 elist))) ); lambda (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss))) ); mapcar ); gen_dist (defun direction (ang) (if (eq arrdir "Forward") ang (+ ang pi) ) ); direction ; here start c:LID (initialize) (if (and (setvar "users5" (setq arrdir (askdir defdir))) (setq ss (ssget '((0 . "line")))) ) (progn (setq ARROW_SIZE (* 0.25 (/ (apply '+ (gen_dist)) (vl-list-length (gen_dist))))) (foreach ename (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss))) (setq elist (entget ename)) (setq p0 (cdr (assoc '10 elist))) (setq p1 (cdr (assoc '11 elist))) (setq p2 (polar p0 (angle p0 p1) (/ (distance p0 p1) 2))) (setq p3 (polar p2 (direction (angle p1 p0)) (* 0.50 ARROW_SIZE))) (setq p4 (polar p2 (direction (angle p0 p1)) (* 0.50 ARROW_SIZE))) (setq p5 (polar p3 (direction (direction (+ (angle p0 p1) (/ pi 2)))) (* 0.30 ARROW_SIZE))) (setq p6 (polar p4 (direction (direction (+ (angle p0 p1) (/ pi 2)))) (* 0.30 ARROW_SIZE))) (setq p7 (polar p6 (- (angle p6 p5) (/ pi 6)) (* 0.25 ARROW_SIZE))) (setq p8 (polar p6 (+ (angle p6 p5) (/ pi 6)) (* 0.25 ARROW_SIZE))) (grvecs (list 3 p5 p6 3 p7 p6 3 p6 p8)) ); foreach ); progn ); if (princ) ); c:LID

Re: show line direction

hak_vz — Sat, 24 Oct 2020 21:35:19 GMT

@Anonymous

Here is a bit updated code, now you just have to use command linedirections.

To delete circles run command again without selecting anything.

Circles are created with radius 15% of average line length.

(defun c:linedirections nil (linedirections)) (defun linedirections ( / ss pt i tot) (if ssd (command "erase" "multiple" ssd "")) (princ "\nSelect lines objects to show it end point >") (setq ss (ssget '((0 . "LINE"))) ssd (ssadd) i 0 tot 0) (setvar 'cmdecho 0) (if ss (progn (repeat (sslength ss)(setq tot (+ tot (vlax-get (vlax-ename->vla-object (ssname ss i)) 'Length)) i (+ i 1))) (setq tot (* 0.05 (/ tot (sslength ss))) i 0) (repeat (sslength ss) (setq pt (vlax-get (vlax-ename->vla-object (ssname ss i)) 'EndPoint)) (command "circle" pt tot) (setq ssd (ssadd (entlast) ssd)) (setq i (+ i 1)) ) ) ) (setvar 'cmdecho 1) (princ "\nDone") (princ) )

Re: show line direction

john.uhden — Sat, 24 Oct 2020 22:23:44 GMT

@Moshe-A :

grvecs is so cool. Years ago I built a LABEL_IT routine for labeling bearings and distances and curve data using grread and what I call glyphs to show endpoints (plural), direction, etc. as you just moved your pointer over a curve object even if nested in a block or xref. I had both a glyph and an unglyph function.

Re: show line direction

Moshe-A — Sun, 25 Oct 2020 05:09:29 GMT

@john.uhden

thank you

Re: show line direction

Moshe-A — Sun, 25 Oct 2020 05:26:08 GMT

Eyal,

This version also supports ucs (rotate about Z axis).

Good morning

Moshe

(defun c:lid (/ initialize askdir gen_dist direction wcs->ucs ; local functions defdir arrdir ss ARROW_SIZE elist p0 p1 p2 p3 p4 p5 p6 p7 p8) (defun initialize () (if (eq (getvar "users5") "") (setq defdir (setvar "users5" "Forward")) (setq defdir (getvar "users5")) ) ); initialize (defun askdir (def / ask) (initget "Forward Backward") (if (not (setq ask (getkword (strcat "\nForward/Backward arrowhead <" def ">: ")))) (setq ask def) (setq def ask) ) ); askdir (defun gen_dist () (mapcar '(lambda (ename / elist) (setq elist (entget ename)) (distance (cdr (assoc '10 elist)) (cdr (assoc '11 elist))) ); lambda (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss))) ); mapcar ); gen_dist (defun direction (ang) (if (eq arrdir "Forward") ang (+ ang pi) ) ); direction (defun wcs->ucs (pt) (trans pt 0 1) ) ; here start c:LID (initialize) (if (and (setvar "users5" (setq arrdir (askdir defdir))) (setq ss (ssget '((0 . "line")))) ) (progn (setq ARROW_SIZE (* (/ 1.0 4.0) (/ (apply '+ (gen_dist)) (vl-list-length (gen_dist))))) (foreach ename (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss))) (setq elist (entget ename)) (setq p0 (cdr (assoc '10 elist))) (setq p1 (cdr (assoc '11 elist))) (setq p2 (polar p0 (angle p0 p1) (/ (distance p0 p1) 2))) (setq p3 (polar p2 (direction (angle p1 p0)) (* 0.50 ARROW_SIZE))) (setq p4 (polar p2 (direction (angle p0 p1)) (* 0.50 ARROW_SIZE))) (setq p5 (polar p3 (direction (direction (+ (angle p0 p1) (/ pi 2)))) (* 0.30 ARROW_SIZE))) (setq p6 (polar p4 (direction (direction (+ (angle p0 p1) (/ pi 2)))) (* 0.30 ARROW_SIZE))) (setq p7 (polar p6 (- (angle p6 p5) (/ pi 6)) (* 0.25 ARROW_SIZE))) (setq p8 (polar p6 (+ (angle p6 p5) (/ pi 6)) (* 0.25 ARROW_SIZE))) (grvecs (list 3 (wcs->ucs p5) (wcs->ucs p6) 3 (wcs->ucs p7) (wcs->ucs p6) 3 (wcs->ucs p6) (wcs->ucs p8))) ); foreach ); progn ); if (princ) ); c:LID

Re: show line direction

Anonymous — Sun, 25 Oct 2020 06:31:36 GMT

Hi @Moshe-A ,

It is great! it shows the arrow direction.

Can you please add one more thing to it?

that after the lisp will ask to show the direction or to change the direction:

1. it will allow selecting the entities, and it will show the arrows as you did.

2. it will allow selecting the entities that need to be changed and reverse their direction.

That will be wonderful.

Thank you!

Re: show line direction

hak_vz — Sun, 25 Oct 2020 07:24:49 GMT

@Anonymous

@Anonymous wrote:
Hi @Moshe-A ,

It is great! it shows the arrow direction.
Can you please add one more thing to it?
that after the lisp will ask to show the direction or to change the direction:
1. it will allow selecting the entities, and it will show the arrows as you did.
2. it will allow selecting the entities that need to be changed and reverse their direction.

That will be wonderful.
Thank you!

With @Moshe-A code, After you show line directions use command reverse. As long as you don't change view (zoom in out or move) arrows will be displayed.

Re: show line direction

john.uhden — Sun, 25 Oct 2020 13:38:16 GMT

@hak_vz :

That's the beauty of using grread for all input. In a continuous while loop, even just moving the mouse will allow the code to pick up any changes in viewsize and viewctr to redraw glyphs accordingly. Plus, you get control over the Esc key so that your code can stop one action but continue with another.

Re: show line direction

hak_vz — Sun, 25 Oct 2020 16:29:16 GMT

@john.uhden I agree. Gr... functions offer a lot of new options, but in some situations simple solutions with global selection set variable that resets on function start also good option. I could have included reverse option added inside my code but didn't. Function of the code is to show direction i.e end point of line object, and after that user can do what ever he wants from exploiting that information (delete, change property or something else)

Re: show line direction

Moshe-A — Sun, 25 Oct 2020 19:14:27 GMT

Eyal,

Now you are going out of the frame from the initial request cause i'm not sure if you understand the meaning of writing only to AutoCAD graphics screen? (that's how your sample lisp works) i came to this conclusion from your new request...

You want the first time to draw the arrows normally (forward) than pause and let you flip direction plus let you to select only the lines that need to be arrow flip direction and in order to do that the program must REDRAW\REGEN

AutoCAD screen which will clear all existing arrows and the flip result will arrow only the latest lines.

Is this what you had in mind in the first place?

(cause keeping the arrows permanently is another program)

Moshe

Re: show line direction

john.uhden — Sun, 25 Oct 2020 20:57:00 GMT

@hak_vz :

I'm sorry. I had no intent to imply fault to any of you brainiacs. I admire you all. I was just trying to point out that AutoLisp has some really nifty functions that make using it more fun as well as productive. Grread is special to me because it can capture every key stroke and pointer activity. It makes for a lot more code, but AutoCAD seems to react to it quite quickly. Please continue to share your valuable wisdom as you do seemingly a multitude of times per week.

Re: show line direction

john.uhden — Sun, 25 Oct 2020 21:05:35 GMT

@Anonymous_A:
I see a note in my old program that a (redraw) is delayed. Instead I found
it better to perform grvecs through the same points with color 0.

Re: show line direction

Moshe-A — Mon, 26 Oct 2020 10:18:58 GMT

wow @john.uhden

That seems to be briliant solution (slipped my mind) but i'm still waiting for the @Anonymous to respond cause i'm not sure he wants the (grvecs). thought may be to replace the arrows to blocks and connect each line to it's block with xdata?!

thank you

Moshe

Re: show line direction

Anonymous — Mon, 26 Oct 2020 10:33:26 GMT

Hi @Moshe-A and @john.uhden ,

Thank you for your brilliant suggestions, the lisp @Moshe-A sent is almost what I wanted, I will try to explain myself better:

I want - when calling the lisp

1. it will ask - show or change line direction.

2. if I click for a show - it will allow selecting the lines and will show exactly as @Moshe-A did, arrows on the lines that show their direction.

3. if I click for change - it allows to select the lines that I want to change their direction and it will flip ( like the reverse command, but I want to use only the lisp and not the command.

Thank you.

Eyal

Re: show line direction

Moshe-A — Mon, 26 Oct 2020 11:54:05 GMT

Dear Eyal,

2 times (msg #2 and msg #12) you ignored my question about Writing to AutoCAD Graphics screen.

@Anonymous wrote:
Hi @Moshe-A and @john.uhden ,

Thank you for your brilliant suggestions, the lisp @Moshe-A sent is almost what I wanted, I will try to explain myself better:
I want - when calling the lisp
1. it will ask - show or change line direction.
if this is the first invocation of lisp (still no arrows exist) and you select change, what arrow it will change?

2. if I click for a show - it will allow selecting the lines and will show exactly as @Moshe-A did, arrows on the lines that show their direction.

3. if I click for change - it allows to select the lines that I want to change their direction and it will flip ( like the reverse command, but I want to use only the lisp and not the command.
just to make it clear for, me here is my senario:
say you have 10 segments of lines and you invoke LID for the first time and select all 10, the arrows are positioned in place - OK?! now LID is paused for Show/Change and you choose change and you select only 5 of lines for flip direction - OK?!

What do expect for the arrows of the lines you did not selected to show? stay unchanged or.....?

Moshe

Re: show line direction

Anonymous — Mon, 26 Oct 2020 12:50:31 GMT

Hi @Moshe-A ,

"What do expect for the arrows of the lines you did not selected to show? stay unchanged or.....?"

Once I've changed some of the lines, it will give the same question- "show the arrows of direction or change line direction, if I want to change more or if I want to change it again.

Better explanation:

I call the Lid lisp, then it will ask to select lines,

I will select the lines that I want to check, and It will show the arrows on the lines that show their direction, and ask to change or stop action.

if I pick change I can select the lines that need to flip direction and it will flip them.

if the stop is selected so the arrows will be erased and the operation will stop.

the arrows should be shown to be able to see the direction for all the processes.

I think now I clear myself better.

Eyal

Re: show line direction

Moshe-A — Mon, 26 Oct 2020 12:58:30 GMT

Eyal

email me now mos@dhcom.co.il

put you phone number

moshe

Re: show line direction

Moshe-A — Mon, 26 Oct 2020 18:38:40 GMT

@Anonymous ,

OK - hope this is final 😱

the prompt has two options: Show and Reverse. when reverse, the arrow flip to the other size of the line but the arrow is on the right Azimuth so 'bear' me 😀

enjoy

Moshe

(defun c:lid (/ combine_selection line_reverse main_exe ; local functions ss0 ss1 action) (defun combine_selection (/ i) (setq i -1) (repeat (sslength ss1) (setq ename (ssname ss1 (setq i (1+ i)))) (if (not (ssmemb ename ss0)) (ssadd ename ss0) ) ); repeat ); combine_selection (defun line_reverse (ss / elist p0 p1) (foreach ename (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss))) (setq elist (entget ename)) (setq p0 (cdr (assoc '10 elist)) p1 (cdr (assoc '11 elist))) (setq elist (subst (cons '10 p1) (assoc '10 elist) elist)) (setq elist (subst (cons '11 p0) (assoc '11 elist) elist)) (entmod elist) ); foreach ); line_reverse (defun main_exe (ss / gen_dist wcs->ucs ; local functions arrow_size ename elist p0 p1 p2 p3 p4 p5 p6 p7 p8) (defun gen_dist () (mapcar '(lambda (ename / elist) (setq elist (entget ename)) (distance (cdr (assoc '10 elist)) (cdr (assoc '11 elist))) ); lambda (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss0))) ); mapcar ); gen_dist (defun wcs->ucs (pt) (trans pt 0 1) ) (setq arrow_size (* (/ 1.0 4.0) (/ (apply '+ (gen_dist)) (vl-list-length (gen_dist))))) (foreach ename (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss))) (setq elist (entget ename)) (setq p0 (cdr (assoc '10 elist))) (setq p1 (cdr (assoc '11 elist))) (if (> (* (distance p0 p1) 0.75) (* 2 0.4 arrow_size)) (progn (setq p2 (polar p0 (angle p0 p1) (/ (distance p0 p1) 2))) (setq p3 (polar p2 (angle p1 p0) (* 0.40 arrow_size))) (setq p4 (polar p2 (angle p0 p1) (* 0.40 arrow_size))) (setq p5 (polar p3 (+ (angle p0 p1) (/ pi 2)) (* 0.30 arrow_size))) (setq p6 (polar p4 (+ (angle p0 p1) (/ pi 2)) (* 0.30 arrow_size))) (setq p7 (polar p6 (- (angle p6 p5) (/ pi 6)) (* 0.25 arrow_size))) (setq p8 (polar p6 (+ (angle p6 p5) (/ pi 6)) (* 0.25 arrow_size))) (grvecs (list 3 (wcs->ucs p5) (wcs->ucs p6) 3 (wcs->ucs p7) (wcs->ucs p6) 3 (wcs->ucs p6) (wcs->ucs p8))) ); progn ); if ); foreach ); main_exe ; here start c:LID (setq ss0 (ssadd)) (while (and (not (initget "Show Reverse")) (setq action (getkword "\nShow/Reverse: ")) (setq ss1 (ssget '((0 . "line")))) ) (redraw) (cond ((eq action "Show") (combine_selection) (main_exe ss0) ); case ((eq action "Reverse") (line_reverse ss1) (combine_selection) (main_exe ss0) ); case ); cond ); while (princ) ); c:LID