topic Re: LISP Routine - Insert Block by Defining Attribute Values & Custom Parameters in Visual LISP, AutoLISP and General Customization Forum

LISP Routine - Insert Block by Defining Attribute Values & Custom Parameters

emreakyazici — Wed, 14 Jul 2021 16:49:55 GMT

Hello everyone, I have a couple of blocks that I use quite frequently, therefore I want to create a LISP command that inserts block by defining att values and custom parameters (position x1, y1, angle1 etc.) as constants.

As you can see in figure1, for example, I want to insert my BLOCK1 with (numbers are just for example, of course)=>

Rotation=0

Scale=1

Base Point= @(0, -10)

Repeat= YES

Custom:

Angle1=0, Angle2:0,

Position1X= 9, Position1Y : 3

Position2X= 0, Position2Y : 53.5

Position3X=20, Position3Y : 20

Position4X=10, Position4Y : 10

Attributes:

TAG10=VALUE10

TAG9=VALUE9

TAG8=VALUE8

TAG7=VALUE7

TAG6=VALUE6

TAG5=VALUE5

TAG4=VALUE4

TAG3=VALUE3

TAG2=VALUE2

TAG1=VALUE1

as constants. Of course, after one example, I'll define them for each of my block and case.

I want to define these attributes and custom parameters for a single block insertion, not want to change all BLOCK1 attributes and custom parameters. Right now, I'm only use these kinds of simple commands:

(defun c:INS123() (command "-insert" "BLOCK1" "B" "0, -10" "S" "1" "R" "180" "RE" "Y"))

If you can help me, that would be amazing. Thanks for your attention.

Re: LISP Routine - Insert Block by Defining Attribute Values & Custom Parameters

emreakyazici — Thu, 15 Jul 2021 12:12:59 GMT

any help? 😞

Re: LISP Routine - Insert Block by Defining Attribute Values & Custom Parameters

ВeekeeCZ — Thu, 15 Jul 2021 13:12:28 GMT

A good start would be posting your block1 as dwg.

Re: LISP Routine - Insert Block by Defining Attribute Values & Custom Parameters

emreakyazici — Thu, 15 Jul 2021 15:52:27 GMT

Oh, sorry. Here you are

Re: LISP Routine - Insert Block by Defining Attribute Values & Custom Parameters

ВeekeeCZ — Thu, 15 Jul 2021 21:13:08 GMT

Fill in the rest of the values.

Use a spacebar to repeat.

(vl-load-com)

(defun c:INS123 ( / o dynprops atvalues)

  (command-s "_.-insert" "BLOCK1" "_b" "0,-10" "_s" 1 "_r" 180 pause)

  (setq dynprops '(
		   ("Position4 X" . 10)			; all dyn-values are numbers - without ""
		   ("Position4 Y" . 10)
		   )
	
	atvalues '(
		   ("TAG4" . "10")                  	; case-sensitive !!
		   ("TAG7" . "SIL-BENI-new")		; all atts are "strings" - with ""
		   ))
	

  (setq o (vlax-ename->vla-object (entlast)))
  (LM:setdynprops o dynprops)
  (LM:vl-setattributevalues o atvalues)
  (princ)
)

;; Set Dynamic Block Properties  -  Lee Mac
;; Modifies values of Dynamic Block properties using a supplied association list.
;; blk - [vla] VLA Dynamic Block Reference object
;; lst - [lst] Association list of (( . ) ... )
;; Returns: nil

(defun LM:setdynprops ( blk lst / itm )
    (setq lst (mapcar '(lambda ( x ) (cons (strcase (car x)) (cdr x))) lst))
    (foreach x (vlax-invoke blk 'getdynamicblockproperties)
        (if (setq itm (assoc (strcase (vla-get-propertyname x)) lst))
            (vla-put-value x (vlax-make-variant (cdr itm) (vlax-variant-type (vla-get-value x)))))))


;; Set Attribute Values  -  Lee Mac
;; Sets attributes with tags found in the association list to their associated values.
;; blk - [vla] VLA Block Reference Object
;; lst - [lst] Association list of (( . ) ... )
;; Returns: nil

(defun LM:vl-setattributevalues ( blk lst / itm )
    (foreach att (vlax-invoke blk 'getattributes)
        (if (setq itm (assoc (vla-get-tagstring att) lst))
            (vla-put-textstring att (cdr itm)))))

Re: LISP Routine - Insert Block by Defining Attribute Values & Custom Parameters

Sea-Haven — Sat, 17 Jul 2021 01:40:13 GMT

A couple of comments you can get tagnames of the block, like wise you can get dynamic properties name, so can pop a DCL straight after inserting block giving you the oppurtunity to enter values. This is a global type answer for any block.

Or can ask 1st then insert and update. I use multi getvals.lsp. You can set default values, I have used this to set visibilty states.

Happy to provide more info.

Re: LISP Routine - Insert Block by Defining Attribute Values & Custom Parameters

emreakyazici — Sat, 17 Jul 2021 17:21:21 GMT

Oh thank you. It's almost perfect, but I had a problem on dynprops, I should set dynprop angle but I'm only able to define as radiants. I need to do it in degrees.

And my second problem is, my position4 controls, position3 and position2. Therefore, I tried to define Pos4 first, then pos2 and pos3. Normally I do that and get normal results, pos2 and pos3 does not affect pos4 but pos4 affects pos3 and pos2. But it was not the expected result (code1 vs. figure1.)

;Code1: ("Position4 X" . 30) ("Position4 Y" . 30) ("Position2 X" . 1) ("Position2 Y" . 2) ("Position3 X" . 3) ("Position3 Y" . 4)

Re: LISP Routine - Insert Block by Defining Attribute Values & Custom Parameters

emreakyazici — Sat, 17 Jul 2021 17:24:00 GMT

My aim is defining all the dyns and atts before each block that I'm planning to use, and assign them to shortcuts and put them with prepared atts precisely. Therefore, an input process for each block would decrease my efficiency. Thank you.

Re: LISP Routine - Insert Block by Defining Attribute Values & Custom Parameters

Sea-Haven — Sun, 18 Jul 2021 05:06:35 GMT

RTD and DTR very old radian <--> degrees defuns every person who does lisp should know about these. Hence did not post find them.

Re: LISP Routine - Insert Block by Defining Attribute Values & Custom Parameters

emreakyazici — Sun, 18 Jul 2021 20:13:02 GMT

I tried but couldn't find anything that solves my problem. I tried to setq Ang1 ((5* pi (/ 180.0) and redefine the line as ("Angle1" . Ang1) but that didn't help. On the other hand, if you don't classify the other question as easy as everybody knows, can you help me about that? Since the angle is last custom dynprop, change of angle ruins my other position inputs. How can I solve that? Thank you.

Re: LISP Routine - Insert Block by Defining Attribute Values & Custom Parameters

Sea-Haven — Mon, 19 Jul 2021 00:18:13 GMT

The two defuns

;The dtr function converts degrees to radians ;The rtd function converts radians to degrees (defun dtr (a) (* pi (/ a 180.0)) ) ; (defun rtd (a) (/ (* a 180.0) pi) )

Thats a typo setq Ang1 ((5* pi (/ 180.0) see dtr above (setq ang1 (dtr ang))

Re: LISP Routine - Insert Block by Defining Attribute Values & Custom Parameters

emreakyazici — Mon, 19 Jul 2021 00:46:40 GMT

Thanks for your help but I still get the error below from command bar.

(defun c:41 ( / o dynprops atvalues) (defun dtr (a) (* pi (/ a 180.0)) ) (setq ang1 (dtr 20.0)) (command-s "_.-insert" "BLOCKNAME1" "_b" "0,-10" "_s" 1 "_r" 0) (setq dynprops '( ("Angle1" . ang1) ... ...

; error: lisp value has no coercion to VARIANT with this type: ANG1

Re: LISP Routine - Insert Block by Defining Attribute Values & Custom Parameters

ВeekeeCZ — Mon, 19 Jul 2021 07:53:36 GMT

Dear @emreakyazici

just to be clear. Your block is such a mess that I can't even tell how it suppose to work. Sorry, I am not going to spend hours investigating whether the code is bad (probably not) or your block definition (very likely).

Re: LISP Routine - Insert Block by Defining Attribute Values & Custom Parameters

emreakyazici — Mon, 19 Jul 2021 18:20:10 GMT

I redefined and changed the layers, name of blocks/tags/values in order to not break confidentiality, didn't spent lots of time. Besides this angle situation and order of props, your code is excellent and I'm grateful to you. If I annoyed you, I'm sorry.

Re: LISP Routine - Insert Block by Defining Attribute Values & Custom Parameters

Sea-Haven — Tue, 20 Jul 2021 01:54:52 GMT

The error is not in DTR but your put dynamic properties, look at Lee-mac dynamic properties.lsp

(LM:setdynpropvalue (vlax-ename->vla-object (entlast)) "DoorWidth" x) (LM:setdynpropvalue (vlax-ename->vla-object (entlast)) "DoorHeight" y)