topic Re: Alphanumeric sort in Visual LISP, AutoLISP and General Customization Forum

Alphanumeric sort

drew_dewit — Tue, 14 Sep 2021 18:30:40 GMT

I am looking to sort the following list ("U20" "U10" "U110" "U11" "T1" "V1") to first be sorted alphabetically then numerically so that it ends up being ("T1" "U10" "U11" "U20" "U110" "V1") this is the funtion I am currently using

(defun sort (l)
(defun sortFunc (m n)
(< (car m) (car n))
)
(vl-sort l 'sortFunc)
)

This works fine till you get to a 3 digit number then it tries to do ("T1" "U10" "U11" "U110" "U20" "V1").

Any suggestions?

Re: Alphanumeric sort

pbejse — Tue, 14 Sep 2021 18:59:44 GMT

@drew_dewit wrote:

I am looking to sort the following list ("U20" "U10" "U110" "U11" "T1" "V1") to first be sorted alphabetically then

Any suggestions?

Suggestion: You need to split them so you can effectively sort the numeric values.

Let us know if you need help with that.

Re: Alphanumeric sort

drew_dewit — Tue, 14 Sep 2021 19:05:45 GMT

That would be, I figured that was the route to go but don't have a good grasp on the best way to do that.

Re: Alphanumeric sort

hak_vz — Tue, 14 Sep 2021 19:10:46 GMT

As @pbejse suggests

(setq lst '("U20" "U10" "U110" "U11" "T1" "V1")) (foreach e lst(setq ret (cons (list (substr e 1 1)(atoi(substr e 2)))ret)))

New list ret is then

(("V" 1) ("T" 1) ("U" 11) ("U" 110) ("U" 10) ("U" 20))

Re: Alphanumeric sort

Kent1Cooper — Tue, 14 Sep 2021 19:46:07 GMT

If they always start with a single letter followed by only numbers representing integers, this seems to work:

(defun SortAI (lst); = Sort Alphabetically, and within that by Integer value (vl-sort (vl-sort lst '(lambda (a b) (< (atoi (substr a 2)) (atoi (substr b 2))))) '(lambda (c d) (< (substr c 1 1) (substr d 1 1))) ) )

It sorts by the numbers "inside," ignoring the letters and using numerical rather than alphabetical values for the numbers, then "outside" sorts that result by the initial letters, and those entries that share an initial letter stay, among themselves, in the order from the numerically-sorted result.

(setq lst '("U20" "U10" "U110" "U11" "T1" "V1"))

(SortAI lst)
("T1" "U10" "U11" "U20" "U110" "V1")

(setq lst '("F123" "T4" "A23" "Q3450" "F13" "A8" "T1"))

(SortAI lst)

("A8" "A23" "F13" "F123" "Q3450" "T1" "T4")

Re: Alphanumeric sort

pbejse — Tue, 14 Sep 2021 19:34:22 GMT

@drew_dewit wrote:

That would be, I figured that was the route to go but don't have a good grasp on the best way to do that.

One example

(defun _n (str / s) (setq s (vl-string-right-trim "0123456789" str)) (list s (atoi (substr str (1+ (strlen s))))) )

_$ (_n "U101")
("U" 101)
_$ (_n "UBN101")
("UBN" 101)

(Defun sortFunc (l) (Vl-sort l'(lambda (n m) (setq n (_n n) m (_n m)) (cond ((< (Car n) (car m))) ((eq (Car n) (car m)) (< (Cadr n) (cadr m))) ) ) ) )

_$ (setq lst '("U20" "U10" "U110" "U11" "T1" "V1"))
("U20" "U10" "U110" "U11" "T1" "V1")
_$ (Acad_strlsort lst)
("T1" "U10" "U11" "U110" "U20" "V1")
_$ (sortFunc lst)
("T1" "U10" "U11" "U20" "U110" "V1")

_$ (setq lst '("U20" "U10" "U110" "U11" "T1" "V1" "HE110" "HE250" "HE2"))
("U20" "U10" "U110" "U11" "T1" "V1" "HE110" "HE250" "HE2")
_$ (Acad_strlsort lst)
("HE110" "HE2" "HE250" "T1" "U10" "U11" "U110" "U20" "V1")
_$ (sortFunc lst)
("HE2" "HE110" "HE250" "T1" "U10" "U11" "U20" "U110" "V1")

HTH

Re: Alphanumeric sort

drew_dewit — Wed, 15 Sep 2021 15:59:26 GMT

Thanks guys,

@Kent1Cooper

So this function works

(defun SortAI (lst); = Sort Alphabetically, and within that by Integer value
  (vl-sort
    (vl-sort lst '(lambda (a b) (< (atoi (substr a 2)) (atoi (substr b 2)))))
    '(lambda (c d) (< (substr c 1 1) (substr d 1 1)))
  )
)

However I was wrong in how the list is presented to the function. Its actually a list of lists. So it looks like (("A10" Description" "Rev")("B100" "Description" "Rev" ...)

How can i modify this to sort by the first element of the sub lists. I imagine I can insert a CAR but I'm not sure the best way.

Re: Alphanumeric sort

Kent1Cooper — Wed, 15 Sep 2021 17:27:38 GMT

@drew_dewit wrote:

... I was wrong in how the list is presented to the function. Its actually a list of lists. So it looks like (("A10" Description" "Rev")("B100" "Description" "Rev" ...)

How can i modify this to sort by the first element of the sub lists. I imagine I can insert a CAR but I'm not sure the best way.

I hope this will do that [untested]:

(defun SortAI (lst); = Sort Alphabetically, and within that by Integer value [of first element]
(vl-sort
(vl-sort lst '(lambda (a b) (< (atoi (substr (car a) 2)) (atoi (substr (car b) 2)))))
'(lambda (c d) (< (substr (car c) 1 1) (substr (car d) 1 1)))
)
)

Re: Alphanumeric sort

pbejse — Thu, 16 Sep 2021 04:33:39 GMT

@drew_dewit wrote:
How can i modify this to sort by the first element of the sub lists. I imagine I can insert a CAR but I'm not sure the best way.

FWIW:

(defun _n (str / s)
(setq s (vl-string-right-trim "0123456789" str))
(list s (atoi (substr str (1+ (strlen s)))))
)

(Defun ThisFunc (l)
(Vl-sort l'(lambda (n m)
		(setq n (_n (Car n)) m (_n (Car m)))
			(cond
			  ((< (Car n) (car m)))
			  ((eq (Car n) (car m)) (< (Cadr n) (cadr m)))
			)
		)
	 )
)

(setq lst '(("A10" "Description" "Rev")("U20" "Description" "Rev")("B100" "Description" "Rev")
	    ("U10" "Description" "Rev")("HE110" "Description" "Rev")("U110" "Description" "Rev")
	    ("HE2" "Description" "Rev")))

(ThisFunc lst)

("A10" "Description" "Rev") ("B100" "Description" "Rev") ("HE2" "Description" "Rev")
("HE110" "Description" "Rev")("U10" "Description" "Rev") ("U20" "Description" "Rev")
("U110" "Description" "Rev")