topic Re: lisp tool for exporting coordinates (nr, x, y, z) tot txt by selecting multiple polylines in Visual LISP, AutoLISP and General Customization Forum

lisp tool for exporting coordinates (nr, x, y, z) tot txt by selecting multiple polylines

Anonymous — Fri, 10 Dec 2021 11:31:14 GMT

Is there a LISP-tool that exports coordinates from selected multiple polylines to a txt-file (number, x, y, z).

The numbers need to be unique.

Lets say i have 3 adjacent rectangles, after selecting them the program generates a txt file with the data but the numbers need to be unique, so in stead of 12 numbers you get 8 numbers in this case.

a possibilty to choose the delimiter (space, tab, comma,...) and the number of digits behind the decimal point.

the decimal point needs to be a '." instead of a ","

thanks

Re: lisp tool for exporting coordinates (nr, x, y, z) tot txt by selecting multiple polylines

АлексЮстасу — Fri, 10 Dec 2021 12:32:16 GMT

Try Plt by Lee Mac for starters.

Re: lisp tool for exporting coordinates (nr, x, y, z) tot txt by selecting multiple polylines

Anonymous — Fri, 10 Dec 2021 13:42:15 GMT

Thank you,

I asume that "plt" is the command you type in Autocad, but what is the programname.

I can't find it on his website.

Thanks again.

Re: lisp tool for exporting coordinates (nr, x, y, z) tot txt by selecting multiple polylines

АлексЮстасу — Fri, 10 Dec 2021 14:58:32 GMT

Excuse me!
I was wrong - PtM, http://www.lee-mac.com/ptmanager.html

I think you will find many options by searching.
You can look in the AppStore.
For example, there is a very powerful Geo_Export /Geo_Import by BearDyugin, 30 days free.
(I think there are many others, and this one I just know - Russian author).

Re: lisp tool for exporting coordinates (nr, x, y, z) tot txt by selecting multiple polylines

ВeekeeCZ — Sat, 11 Dec 2021 16:04:18 GMT

@Anonymous

Here's something quick. Driven by textsize or luprec sysvars.

HTH

(vl-load-com)

(defun c:Pl2CSV ( / *error* f LM:UniqueFuzz x s n l i h)
  
  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break,end"))
      (princ (strcat "\nError: " errmsg)))
    (if f (close f))
    (princ))
  
  ;; Unique with Fuzz  -  Lee Mac  
  (defun LM:UniqueFuzz ( l f ) (if l (cons (car l) (LM:UniqueFuzz (vl-remove-if '(lambda (x) (equal x (car l) f)) (cdr l)) f))))
  
  (if (and (setq s (ssget '((0 . "LWPOLYLINE"))))
	   (setq n (cond ((getint "\nStart number <1>: ")) (1)))
	   (setq n (1- n))
	   (setq l (vl-remove-if 'listp (mapcar 'cadr (ssnamex s))))
	   (setq l (apply 'append
			  (mapcar '(lambda (x) (mapcar '(lambda (y) (reverse (cons (cdr (assoc 38 (entget x))) (reverse (cdr y)))))
						       (vl-remove-if-not '(lambda (c) (= 10 (car c))) (entget x))))
				  l)))
	   (setq l (LM:UniqueFuzz l 1e-6))
	   (setq f (open (strcat (getvar 'DWGPREFIX) (vl-string-right-trim ".dwg" (getvar 'DWGNAME)) "-PlExport.csv") "a"))
	   (write-line "n,x,y,z" f)
	   (setq i -1)
	   (setq h (getvar 'textsize))
	   )
    (foreach p l
      (setq n (1+ n))
      (entmakex (list '(0 . "TEXT") (cons 10 p) (cons 40 h) (cons 1 (itoa n))))
      (setq x (strcat (itoa n) ","
		      (rtos (car p) 2) ","
		      (rtos (cadr p) 2) ","
		      (rtos (last p) 2)))
      (write-line x f)))
  (*error* "end")
  )

Edit: updated to fix elevations.

Re: lisp tool for exporting coordinates (nr, x, y, z) tot txt by selecting multiple polylines

Anonymous — Sat, 11 Dec 2021 08:43:43 GMT

This is almost perfect.

Altough there is a problem with the z-coord: the z-coord is the same as the y-coord.

Is there a possibility to choose between space or tab as delimiter?

Many thanks