topic Re: DCL - logic in Visual LISP, AutoLISP and General Customization Forum

DCL - logic

sigmmadesigner — Tue, 13 May 2025 07:48:17 GMT

Hello everyone! I'm studying the logic of this DCL, so that 2 routines work in the same DCL. However, the logic part returns only one of the routines regardless of the button I select.

I thank everyone who can contribute.

My greetings to everyone.

(defun c:TEST_DCL(/ dcl_id dclfile f)

(vl-load-com)
(setvar "OSMODE" 0)

;; Cria o DCL temporário
(setq dclfile (vl-filename-mktemp "MENU.dcl"))
(setq f (open dclfile "w"))
(foreach line
'(
"MENU : dialog { label = \"MENU\";"
" : column {"
" : boxed_radio_column { label = \"Tipo de Faixa\";"
" : radio_button { label = \"GOOD MORNING\" ; key = \"rb_fp\" ; }"
" : radio_button { label = \"GOODNIGHT\" ; key = \"rb_fxe\" ; }"
" }"
" : row {"
" : button { label = \"OK\" ; key = \"ok\" ; fixed_width = true; width = 15; alignment = centered; is_default = true; }"
" : button { label = \"Cancel\" ; key = \"cancel\" ; fixed_width = true; width = 15; alignment = centered; is_cancel = true; }"
" }"
" }"
"}"
)
(write-line line f)
)
(close f)

;; Carrega o DCL
(setq dcl_id (load_dialog dclfile))
(if (not (new_dialog "MENU" dcl_id))
(progn
(alert "Error DCL.")
(vl-file-delete dclfile)
(exit)
)
)

;; Valor padrão
(set_tile "rb_fp" "1")

;; Botões
(action_tile "ok" "(done_dialog 1)")
(action_tile "cancel" "(done_dialog 0)")

;; Exibe o diálogo
(if (= (start_dialog) 1)
(progn
(unload_dialog dcl_id)
(vl-file-delete dclfile)

;; Verifica qual opção foi marcada
(if (= (get_tile "rb_fp") "1")
(c:F1) ; GOOD MORNING
(c:F2) ; GOODNIGHT
)

(princ "\nOperation completed successfully.\n")
)
(progn
(unload_dialog dcl_id)
(vl-file-delete dclfile)
(princ "\n cancelled oparation\n")
)
)

(princ)
)

(defun c:F1 ()
(alert "GOOD MORNING")
)

(defun c:F2 ()
(alert "GOODNIGHT")
)

Re: DCL - logic

_gile — Tue, 13 May 2025 08:51:39 GMT

Hi,

One way could be storing the value of "rb_fp" tile in a local variable (rb_fp) and the value return by start_dialog in another one (status), close the dialog and do what you want according to these variables values.

(defun c:TEST_DCL (/ dcl_id dclfile f rb_fp status) (vl-load-com) (setvar "OSMODE" 0) ;; Cria o DCL temporário (setq dclfile (vl-filename-mktemp "MENU.dcl")) (setq f (open dclfile "w")) (foreach line '( "MENU : dialog { label = \"MENU\";" " : column {" " : boxed_radio_column { label = \"Tipo de Faixa\";" " : radio_button { label = \"GOOD MORNING\" ; key = \"rb_fp\" ; }" " : radio_button { label = \"GOODNIGHT\" ; key = \"rb_fxe\" ; }" " }" " : row {" " : button { label = \"OK\" ; key = \"ok\" ; fixed_width = true; width = 15; alignment = centered; is_default = true; }" " : button { label = \"Cancel\" ; key = \"cancel\" ; fixed_width = true; width = 15; alignment = centered; is_cancel = true; }" " }" " }" "}" ) (write-line line f) ) (close f) ;; Carrega o DCL (setq dcl_id (load_dialog dclfile)) (if (not (new_dialog "MENU" dcl_id)) (progn (alert "Error DCL.") (vl-file-delete dclfile) (exit) ) ) ;; Valor padrão (set_tile "rb_fp" "1") ;; Botões (action_tile "ok" "(setq rb_fp (get_tile \"rb_fp\")) (done_dialog 1)") (action_tile "cancel" "(done_dialog 0)") (setq status (start_dialog)) (unload_dialog dcl_id) (vl-file-delete dclfile) (if (= status 1) (progn (if (= rb_fp "1") (c:F1) ; GOOD MORNING (c:F2) ; GOODNIGHT ) (princ "\nOperation completed successfully.\n") ) (princ "\n cancelled oparation\n") ) (princ) )

Re: DCL - logic

paullimapa — Tue, 13 May 2025 17:07:15 GMT

when dealing with radio buttons especially when there's more than two I prefer to do the following:

1. set default radio button setting:

; setup default variable (setq rb_option "rb_fp") ; setup default radio button selection (set_tile rb_option "1")

2. set actions for each radio button:

(foreach itm '("rb_fp" "rb_fxe") ; apply action to each item in list showing all radio button keys (action_tile itm "(setq rb_option $key)") ; set variable to radio button key selected )

3. after dialog is dismissed by pressing OK then setup test condition:

;; Verifica qual opção foi marcada (cond ((= rb_option "rb_fp") (c:F1) ; GOOD MORNING ) ((= rb_option "rb_fxe") (c:F2) ; GOODNIGHT ) )

Re: DCL - logic

scot-65 — Tue, 13 May 2025 21:45:08 GMT

1. Please assign a KEY to the radio button container: "TipoDeFaxia"

2. Next, Let's concentrate on this line:

;; Botões
(action_tile "ok" "(done_dialog 1)")

The user has made his selection and is ready to continue.

At this time we will gather the state of ALL tiles in the dialog (and save as a LIST as needed).

(action_tile "ok" "(TEST_GET)(done_dialog 1)")

Where TEST_GET is a call to a subroutine to gather and store the dialog state.

(defun TEST_GET ()

(setq a (get_tile "TipoDeFaixa"))

);end TEST_GET

Please note I have structured this way as it can be expandable.

For radio buttons, communicate with the container and not the children inside the container.

Now that you have exited the dialog, the (local) variable "a" contains all the information needed to begin the execution part of your program.

As Gile has stated, tiles MUST BE INITIALIZED.

As an example, a TOGGLE has 3 values: "0", "1" and nil.

A program will fail when written to accept "0" and "1" only where the tile is not initialized.

~~(set_tile "rb_fp" "1")~~

For radio buttons, assign the container one of the children:

(set_tile "TipoDeFaxia" "rb_fp")

Bonus Material:

Between new_dialog and start_dialog add these comments (divisions) to your template:

;** INITIALIZE **

;** SET TILE **

;** MODE TILE **

;** ACTION TILE **

Hope this helps.

Re: DCL - logic

sigmmadesigner — Tue, 13 May 2025 22:41:19 GMT

((defun c:TEST_DCL (/ dcl_id dclfile f)
(vl-load-com)
(setvar "OSMODE" 0)

;; Carrega o DCL e verifica se foi carregado corretamente
(setq dcl_id (load_dialog dclfile))
(if (not (new_dialog "MENU" dcl_id))
(progn
(alert "Erro ao carregar o diálogo.")
(vl-file-delete dclfile)
(exit)
)
)

;; Define o botão de rádio padrão: GOOD MORNING
(set_tile "rb_fp" "1")

;; Define ações para os botões OK e Cancel
(action_tile "ok" "(done_dialog 1)")
(action_tile "cancel" "(done_dialog 0)")

;; Inicia o diálogo e processa o resultado
(if (= (start_dialog) 1)
(progn
;; Verifica a opção selecionada: se "rb_fp" estiver ativo, chama c:F1; caso contrário, chama c:F2.
(if (equal (get_tile "rb_fp") "1")
(c:F1) ; GOOD MORNING
(c:F2) ; GOODNIGHT
)
(princ "\nOperation completed successfully.\n")
)
(princ "\nOperação cancelada.\n")
)

;; Libera o diálogo e remove o arquivo temporário
(unload_dialog dcl_id)
(vl-file-delete dclfile)
(princ)
)

(defun c:F1 ()
(alert "GOOD MORNING")
)

(defun c:F2 ()
(alert "GOODNIGHT")
)

Re: DCL - logic

Sea-Haven — Wed, 14 May 2025 02:03:14 GMT

This is a library version of a Radio buttons Dcl can be used in any code returns button selected, look at sample code in top of the attached. Your welcome to use.