topic Re: LISP Commands: Mixed Bag of Questions in Visual LISP, AutoLISP and General Customization Forum

LISP Commands: Mixed Bag of Questions

ashetonv — Sun, 21 Aug 2022 21:29:30 GMT

I am new to LISP commands and haven't been able to find any good tutorials yet, so I have a lot of questions and don't want to overload the forums. (Recommendations on where to learn would be much appreciated, most tutorials seem to be older than CAD 2015 from what I have seen). Would attach what I have, but I don't think I even know enough for it to really help.

1) How do you initiate a command, allow for the user to create a selection set, and then continue on with the LISP?

For example, I am attempting to nested copy objects from an xref with 0 displacement and then instantly convert the copied objects to the current layer.

2) How do you open a command to be continuously used?

For example, I want a shortcut for filleting multiple objects with radius 0 but allow the user to select objects as normal and close out the command as if typically filleting. However, if I put in the same commands into a lisp, it automatically closes the command after inputting the proper settings. **Would be great if this was able to be modified to keep the last used non-zero fillet radius so that this is fully separate command.**

3) Is it possible to modify property fields when selecting objects whether it be with an automatic value or user input? For example, selecting text objects (MTEXTS and MLEADERS) and making them annotative, background masked, and text framed? Alternatively, allow a user to select a pipe and modify pipe slope (hold start) and then take an input value?

4) How to make command read starts and ends of polylines? Essentially looking to make two polylines become a closed object by drawing two polylines between the starts and ends of a two selected polylines and then joining the four polylines. Would later be implemented so that one object could be offset and then apply the same process to the original and the offset object. Recognize there are other ways to do it with the latter process, but looking to have two separate commands.

5) I have no idea how to go about this one, so I will just describe it and see ideas: I want a command where I am able to choose a label style and a surface, and then select polylines and have a spot elevation placed at each vertex in the same dragged state position. While this typically would be done on nested objects, I am totally fine with having to create the polylines prior to running this command.

5) Are you able to make commands to operate the layer properties manager? Like freezing all of the layers in a layer filter? Or make a layer filter of all the layers of objects in current selection (this would also be great to be able to erase a filter and reset it since it seems difficult to append a layer to an already made filter).

I know this is all over the place, but I don't think I even know what to google yet with how new I am to all of this. Any help is much appreciated!!!

Re: LISP Commands: Mixed Bag of Questions

ВeekeeCZ — Mon, 22 Aug 2022 06:51:43 GMT

@ashetonv wrote:

...

2) How do you open a command to be continuously used?

For example, I want a shortcut for filleting multiple objects with radius 0 but allow the user to select objects as normal and close out the command as if typically filleting. However, if I put in the same commands into a lisp, it automatically closes the command after inputting the proper settings. **Would be great if this was able to be modified to keep the last used non-zero fillet radius so that this is fully separate command.**

...

AutoLisp FILLET version, like many other commands, differs from the current AutoCAD's version. It's older. So the command is ended after the Radius option is specified. Nowadays you can use the (initcommandversion) predecessor command to force AutoLisp to use the current (or other) version.

BTW have you ever heard that you can simply hold the SHIFT key??

To mimic the FILLET behavior with R=0:

(defun c:filletzero ( / o)

  (setq o (getvar 'filletrad))
  (setvar 'filletrad 0.)
  (initcommandversion)
  (command-s "_.fillet")
  (setvar 'filletrad o)
  (princ)
  )

Or enhanced continuous version:

(defun c:fzero ( / o)

  (setq o (getvar 'filletrad))
  (setvar 'filletrad 0.)
  (while (progn
	   (initcommandversion)
	   (command "_.fillet" pause)
	   (> (getvar 'cmdactive) 0))
    (while (> (getvar 'cmdactive) 0) (command pause)))
  (setvar 'filletrad o)
  (princ)
  )

Re: LISP Commands: Mixed Bag of Questions

ВeekeeCZ — Mon, 22 Aug 2022 06:54:41 GMT

@ashetonv wrote:

... 5) I have no idea how to go about this one, so I will just describe it and see ideas: I want a command where I am able to choose a label style and a surface, and then select polylines and have a spot elevation placed at each vertex in the same dragged state position. While this typically would be done on nested objects, I am totally fine with having to create the polylines prior to running this command.

...

Re-post this to The C3D Customization Forum HERE

Re: LISP Commands: Mixed Bag of Questions

ВeekeeCZ — Mon, 22 Aug 2022 07:09:30 GMT

@ashetonv wrote:

.... 5) Are you able to make commands to operate the layer properties manager? Like freezing all of the layers in a layer filter? Or make a layer filter of all the layers of objects in current selection (this would also be great to be able to erase a filter and reset it since it seems difficult to append a layer to an already made filter).

...

Theoretically, anything is possible. Just not so simple...

Here is the code to create a filter by pre-selected objects. Or the current layer if no layer is preselected.

(defun c:CurrentSelectionFilter (/ *error* eco s i l lst)

  (defun *error* (errmsg)
    (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break,end"))
      (princ (strcat "\nError: " errmsg)))
    (if eco (setvar 'cmdecho eco))
    (princ))
  
  (setq eco (getvar 'cmdecho))
    (setvar 'CMDECHO 0)
  (if (setq s (ssget "_I"))
    (repeat (setq i (sslength s))
      (setq l (cdr (assoc 8 (entget (ssname s (setq i (1- i)))))))
      (if (not (vl-position l lst)) (setq lst (cons l lst))))
    (setq lst (list (getvar 'clayer))))
  (command "_.-LAYER" "_Filter" "_Delete" "Current Selection")
  (if (< 0 (getvar 'CMDACTIVE)) (command))
  (command "_.-LAYER" "_Filter" "_New" "_Group" "All" (apply 'strcat (mapcar '(lambda (l) (strcat l ",")) lst)) "Current Selection" "")
  (initdia) (command "_.LAYER")
  (*error* "end")
)

Re: LISP Commands: Mixed Bag of Questions

ВeekeeCZ — Tue, 23 Aug 2022 13:49:09 GMT

@ashetonv wrote:

...

1) How do you initiate a command, allow for the user to create a selection set, and then continue on with the LISP?

For example, I am attempting to nested copy objects from an xref with 0 displacement and then instantly convert the copied objects to the current layer.

...

I can imagine this workflow automated:

* pick an XREF

* REFEDIT

* make a selection

* COPYTOLAYER objects with 0 displacement

* remove all new objects from the Active Working Set.

* close the reference without saving.

Automated this way:

(defun C:NCopyM (/ ss) ; = NCOPY Multiple objects

  (command "_.-REFEDIT" pause "_Ok" "_All" "_No")
  (if (setq ss (ssget "_:L"))
    (command "_.-COPYTOLAYER" ss "" (getvar 'clayer) "_X"
	     "_.REFSET" "_R" ss ""))
  (command "_.REFCLOSE" "_SAVE")
  (princ)
)

Re: LISP Commands: Mixed Bag of Questions

ВeekeeCZ — Mon, 22 Aug 2022 07:19:38 GMT

@ashetonv wrote:

...

4) How to make command read starts and ends of polylines? Essentially looking to make two polylines become a closed object by drawing two polylines between the starts and ends of a two selected polylines and then joining the four polylines. Would later be implemented so that one object could be offset and then apply the same process to the original and the offset object. Recognize there are other ways to do it with the latter process, but looking to have two separate commands.

...

Look at vlax-curve-* functions HERE

Re: LISP Commands: Mixed Bag of Questions

ВeekeeCZ — Mon, 22 Aug 2022 07:24:39 GMT

AD 3. Sure you can edit all the properties.
Look at
(dumpallproperties (car (entsel)))
(setpropertyvalue...)
(getpropertyvalue...)

A PIPE is a C3D thing, you need to get there for help.

Re: LISP Commands: Mixed Bag of Questions

Sea-Haven — Tue, 23 Aug 2022 05:08:17 GMT

Join ends different mix of objects required, join 2 lines and join 2 plines, join line & pline.

Have 1st will look at add other combinations.

Re: LISP Commands: Mixed Bag of Questions

Sea-Haven — Tue, 23 Aug 2022 05:13:19 GMT

I have some shortcut stuff for CIV3d like setting surface styles, uses a toolbar select contour interval, none or slope arrow. Plus other Civ3d stuff rotate pt, Label pt etc just ask if interested via Private mail.

Re: LISP Commands: Mixed Bag of Questions

ashetonv — Thu, 15 Sep 2022 01:58:44 GMT

I am amazed I never knew that you could hold shift, nor did several of my coworkers. No idea how we missed that. Nonetheless, this command is exactly what I was looking for, so thank you so much!

Re: LISP Commands: Mixed Bag of Questions

Sea-Haven — Fri, 23 Sep 2022 04:52:21 GMT

Item 4 join and close multiple plines, need a sample dwg.

I have close 2d & 3d polylines a Field survey thing pick 4 points and get 3 lines. An example a drainage pit.

Re: LISP Commands: Mixed Bag of Questions

Kent1Cooper — Fri, 23 Sep 2022 13:21:52 GMT

2) Here's what I use for that, which is like Message 2 with the addition of ensuring that the initial Fillet radius gets reset if something goes wrong:

;; FilletZero.lsp [command name = FZ] ;; Calls up Fillet mUltiple at 0 radius; when done, restores prior radius. ;; Concept from Cadalyst CAD Tips #1365 "Fillet with Zero Radius", by ;; William M. Bright [1997], which does only one Fillet operation. ;; Re-written to repeat as long as desired, and to add error handling, by ;; Kent Cooper, February 2012. (defun C:FZ (/ *error* fr); = Fillet Zero-radius (defun *error* (errmsg) (if (not (wcmatch errmsg "Function cancelled,quit / exit abort,console break")) (princ (strcat "\nError: " errmsg)) ); if (setvar 'filletrad fr) (princ) ); defun - *error* (setq fr (getvar 'filletrad)) (setvar 'filletrad 0) (command "_.fillet" "_mUltiple") (while (> (getvar 'cmdactive) 0) (command pause)) (setvar 'filletrad fr) (princ) ); defun

4) It's easy to pull start and endpoints of Polylines, using (vlax-curve-get...Point) functions. But there are complications -- would it need to differentiate between the possibility of starts' and ends' relationship being in either direction?

Re: LISP Commands: Mixed Bag of Questions

Kent1Cooper — Fri, 23 Sep 2022 13:46:40 GMT

@Kent1Cooper wrote:

....

4) It's easy to pull start and endpoints of Polylines, using (vlax-curve-get...Point) functions. But there are complications -- would it need to differentiate between the possibility of starts' and ends' relationship being in either direction?

Come to think of it, I do have something that can deal with that difference -- LadderC.lsp, >here<. Use that and select two Polylines [or other acceptable things], and ask it to divide them into one segment, and it will draw the red lines at left above, regardless of the comparative directions in which the selected objects were drawn.

It would be a relatively easy modification to build in the one-segment approach and have it join all those parts together afterward, if that sounds like what you want to do.

Re: LISP Commands: Mixed Bag of Questions

john.uhden — Sat, 24 Sep 2022 00:03:58 GMT

@Kent1Cooper wrote "But there are complications -- would it need to differentiate between the possibility of starts' and ends' relationship being in either direction?"

Now he's catching on. 😀