topic Re: (LISP)How do we create points on a line? in Visual LISP, AutoLISP and General Customization Forum

(LISP)How do we create points on a line?

mik501_ — Fri, 03 Nov 2023 01:40:34 GMT

Hi. Can we select a line to create a point of length on a different line? Each day I have to create three points on one line, one at a time. Can I do it at once, multiple lines?

Thank you.

Re: (LISP)How do we create points on a line?

CADaSchtroumpf — Thu, 15 Dec 2022 08:29:47 GMT

Hi,

For exemple this:

(defun c:THREE_PT_ON_LINES ( / ss d1 d2 dxf_ent dxf_10 dxf_11 ang) (princ "\nSelect lines") (cond ((setq ss (ssget '((0 . "LINE")))) (initget 7) (setq d1 (getdist "\nFirst distance?: ")) (initget 7) (setq d2 (getdist "\nSecond distance?: ")) (repeat (setq n (sslength ss)) (setq dxf_ent (entget (ssname ss (setq n (1- n)))) dxf_10 (cdr (assoc 10 dxf_ent)) dxf_11 (cdr (assoc 11 dxf_ent)) ang (angle dxf_10 dxf_11) ) (entmake (list (cons 0 "POINT") (cons 10 dxf_10) ) ) (entmake (list (cons 0 "POINT") (cons 10 (polar dxf_10 ang d1)) ) ) (entmake (list (cons 0 "POINT") (cons 10 (polar dxf_10 ang d2)) ) ) ) ) ) (prin1) )

Re: (LISP)How do we create points on a line?

mik501_ — Thu, 15 Dec 2022 08:47:20 GMT

Hi. It works great. thank you very very much.

Re: (LISP)How do we create points on a line?

Kent1Cooper — Thu, 15 Dec 2022 17:17:53 GMT

Your sample drawing has one of the Points at the start of each Line, but your description doesn't limit it to that. Here's another way, including User specification of all 3 distances, with zero offered as default for the first one. And it checks each Line for whether it's at least as long as the third distance before placing any Points on it, and notifies you if not.

(vl-load-com); if needed (defun c:3PL (/ d1 d2 d3 ss n lin) (initget 4); no negative [zero and Enter permitted for first one] (setq d1 (cond ((getdist "\nFirst distance <0>: ")) (0))) (initget 7); no Enter, no zero, no negative (setq d2 (getdist "\nSecond distance: ")) (initget 7) (setq d3 (getdist "\nThird distance: ")) (prompt "\nTo place 3 Points at those distances on Lines,") (if (setq ss (ssget '((0 . "LINE")))) (repeat (setq n (sslength ss)) (setq lin (ssname ss (setq n (1- n)))) (if (>= (vlax-curve-getEndParam lin) d3) (command "_.point" "_non" (vlax-curve-getPointAtDist lin d1) "_.point" "_non" (vlax-curve-getPointAtDist lin d2) "_.point" "_non" (vlax-curve-getPointAtDist lin d3) ); command (prompt "\nLine is not long enough for all 3 Points.") ); if ); repeat ); if (prin1) )

It could use the usual enhancements [Layer control for the Points if desired, Undo begin/end wrapping, *error* handling if it changes anything that should be changed back, etc.], and could be adjusted easily to work with other object types [Arcs, Polylines, etc.]. And it could do other things, such as remember all 3 of your distances and offer them as defaults on subsequent use, instead of offering only zero and only for the first distance, or to consider the start of every Line to be in a particular direction regardless of its actual drawn direction, etc.

Re: (LISP)How do we create points on a line?

mik501_ — Sat, 17 Dec 2022 04:50:37 GMT

Very Thank you kentcooper .